let R be Ring; :: thesis: for V being LeftMod of R
for W1, W2, W3 being Submodule of V st W1 is Submodule of W2 holds
the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3))
let V be LeftMod of R; :: thesis: for W1, W2, W3 being Submodule of V st W1 is Submodule of W2 holds
the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3))
let W1, W2, W3 be Submodule of V; :: thesis: ( W1 is Submodule of W2 implies the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3)) )
reconsider V2 = the carrier of W2 as Subset of V by VECTSP_4:def 2;
A1: V2 is linearly-closed by VECTSP_4:33;
assume W1 is Submodule of W2 ; :: thesis: the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3))
then A2: the carrier of W1 c= the carrier of W2 by VECTSP_4:def 2;
thus the carrier of (W2 + (W1 /\ W3)) c= the carrier of ((W1 + W2) /\ (W2 + W3)) by Lm14; :: according to XBOOLE_0:def 10 :: thesis: the carrier of ((W1 + W2) /\ (W2 + W3)) c= the carrier of (W2 + (W1 /\ W3))
let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in the carrier of ((W1 + W2) /\ (W2 + W3)) or x in the carrier of (W2 + (W1 /\ W3)) )
assume x in the carrier of ((W1 + W2) /\ (W2 + W3)) ; :: thesis: x in the carrier of (W2 + (W1 /\ W3))
then x in the carrier of (W1 + W2) /\ the carrier of (W2 + W3) by VECTSP_5:def 2;
then x in the carrier of (W1 + W2) by XBOOLE_0:def 4;
then x in { (u1 + u2) where u2, u1 is Vector of V : ( u1 in W1 & u2 in W2 ) } by VECTSP_5:def 1;
then consider u2, u1 being Vector of V such that
A3: x = u1 + u2 and
A4: ( u1 in W1 & u2 in W2 ) ;
u1 + u2 in V2 by A2, A1, A4;
then A5: u1 + u2 in W2 ;
( 0. V in W1 /\ W3 & (u1 + u2) + (0. V) = u1 + u2 ) by Th33, RLVECT_1:4;
then x in { (u + v) where v, u is Vector of V : ( u in W2 & v in W1 /\ W3 ) } by A3, A5;
hence x in the carrier of (W2 + (W1 /\ W3)) by VECTSP_5:def 1; :: thesis: verum