let V1 be free finite-rank Z_Module; :: thesis: for a being Element of V1
for F being FinSequence of V1
for G being FinSequence of INT.Ring st len F = len G & ( for k being Nat
for v being Element of INT.Ring st k in dom F & v = G . k holds
F . k = v * a ) holds
Sum F = (Sum G) * a
let a be Element of V1; :: thesis: for F being FinSequence of V1
for G being FinSequence of INT.Ring st len F = len G & ( for k being Nat
for v being Element of INT.Ring st k in dom F & v = G . k holds
F . k = v * a ) holds
Sum F = (Sum G) * a
let F be FinSequence of V1; :: thesis: for G being FinSequence of INT.Ring st len F = len G & ( for k being Nat
for v being Element of INT.Ring st k in dom F & v = G . k holds
F . k = v * a ) holds
Sum F = (Sum G) * a
let G be FinSequence of INT.Ring; :: thesis: ( len F = len G & ( for k being Nat
for v being Element of INT.Ring st k in dom F & v = G . k holds
F . k = v * a ) implies Sum F = (Sum G) * a )
defpred S₁[ Nat] means for H being FinSequence of V1
for I being FinSequence of INT.Ring st len H = len I & len H = $1 & ( for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ) holds
Sum H = (Sum I) * a;
A1: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume A2: for H being FinSequence of V1
for I being FinSequence of INT.Ring st len H = len I & len H = n & ( for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ) holds
Sum H = (Sum I) * a ; :: thesis: S₁[n + 1]
let H be FinSequence of V1; :: thesis: for I being FinSequence of INT.Ring st len H = len I & len H = n + 1 & ( for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ) holds
Sum H = (Sum I) * a
let I be FinSequence of INT.Ring; :: thesis: ( len H = len I & len H = n + 1 & ( for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ) implies Sum H = (Sum I) * a )
assume that
A3: len H = len I and
A4: len H = n + 1 and
A5: for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ; :: thesis: Sum H = (Sum I) * a
reconsider q = I | (Seg n) as FinSequence of INT.Ring by FINSEQ_1:18;
reconsider p = H | (Seg n) as FinSequence of V1 by FINSEQ_1:18;
A6: n <= n + 1 by NAT_1:12;
then A7: len p = n by A4, FINSEQ_1:17;
A8: dom p = Seg n by A4, A6, FINSEQ_1:17;
A9: len q = n by A3, A4, A6, FINSEQ_1:17;
A10: dom q = Seg n by A3, A4, A6, FINSEQ_1:17;

A11: now :: thesis: for k being Nat
for v being Element of INT.Ring st k in dom p & v = q . k holds
p . k = v * a

len p <= len H by A4, A6, FINSEQ_1:17;
then A12: dom p c= dom H by FINSEQ_3:30;
let k be Nat; :: thesis: for v being Element of INT.Ring st k in dom p & v = q . k holds
p . k = v * a
let v be Element of INT.Ring; :: thesis: ( k in dom p & v = q . k implies p . k = v * a )
assume that
A13: k in dom p and
A14: v = q . k ; :: thesis: p . k = v * a
I . k = q . k by A8, A10, A13, FUNCT_1:47;
then H . k = v * a by A5, A13, A14, A12;
hence p . k = v * a by A13, FUNCT_1:47; :: thesis: verum

end;

reconsider n = n as Element of NAT by ORDINAL1:def 12;
n + 1 in Seg (n + 1) by FINSEQ_1:4;
then A15: n + 1 in dom H by A4, FINSEQ_1:def 3;
then reconsider v1 = H . (n + 1) as Element of V1 by FINSEQ_2:11;
reconsider v2 = I . (n + 1) as Element of INT.Ring by INT_1:def 2;
A16: v1 = v2 * a by A5, A15;
A17: I = q ^ <*v2*> by FINSEQ_3:55, A3, A4;
thus Sum H = (Sum p) + v1 by A4, A7, A8, RLVECT_1:38
.= ((Sum q) * a) + (v2 * a) by A2, A7, A9, A11, A16
.= ((Sum q) + v2) * a by VECTSP_1:def 15
.= (Sum I) * a by A17, FVSUM_1:71 ; :: thesis: verum

end;

A17: S₁[ 0 ]

proof

let H be FinSequence of V1; :: thesis: for I being FinSequence of INT.Ring st len H = len I & len H = 0 & ( for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ) holds
Sum H = (Sum I) * a
let I be FinSequence of INT.Ring; :: thesis: ( len H = len I & len H = 0 & ( for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ) implies Sum H = (Sum I) * a )
assume that
A18: len H = len I and
A19: len H = 0 and
for k being Nat
for v being Element of INT.Ring st k in dom H & v = I . k holds
H . k = v * a ; :: thesis: Sum H = (Sum I) * a
H = <*> the carrier of V1 by A19;
then A20: Sum H = 0. V1 by RLVECT_1:43;
I = <*> the carrier of INT.Ring by A18, A19;
then Sum I = 0. INT.Ring by RLVECT_1:43;
then (Sum I) * a = 0. V1 by VECTSP_1:14;
hence Sum H = (Sum I) * a by A20; :: thesis: verum

end;

for n being Nat holds S₁[n] from NAT_1:sch 2(A17, A1);
hence ( len F = len G & ( for k being Nat
for v being Element of INT.Ring st k in dom F & v = G . k holds
F . k = v * a ) implies Sum F = (Sum G) * a ) ; :: thesis: verum