let F, G be Field; :: thesis: for V being VectSp of F
for W being VectSp of G
for f1, f2 being Function of V,W
for x, h being Element of V
for n being Nat holds ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x)
let V be VectSp of F; :: thesis: for W being VectSp of G
for f1, f2 being Function of V,W
for x, h being Element of V
for n being Nat holds ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x)
let W be VectSp of G; :: thesis: for f1, f2 being Function of V,W
for x, h being Element of V
for n being Nat holds ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x)
let f1, f2 be Function of V,W; :: thesis: for x, h being Element of V
for n being Nat holds ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x)
let x, h be Element of V; :: thesis: for n being Nat holds ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x)
let n be Nat; :: thesis: ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x)
defpred S₁[ Nat] means for x being Element of V holds ((bdif ((f1 - f2),h)) . ($1 + 1)) /. x = (((bdif (f1,h)) . ($1 + 1)) /. x) - (((bdif (f2,h)) . ($1 + 1)) /. x);
A1: S₁[ 0 ]

proof

let x be Element of V; :: thesis: ((bdif ((f1 - f2),h)) . (0 + 1)) /. x = (((bdif (f1,h)) . (0 + 1)) /. x) - (((bdif (f2,h)) . (0 + 1)) /. x)
x in the carrier of V ;
then ( x in dom f1 & x in dom f2 ) by FUNCT_2:def 1;
then x in (dom f1) /\ (dom f2) by XBOOLE_0:def 4;
then A2: x in dom (f1 - f2) by VFUNCT_1:def 2;
x - h in the carrier of V ;
then ( x - h in dom f1 & x - h in dom f2 ) by FUNCT_2:def 1;
then x - h in (dom f1) /\ (dom f2) by XBOOLE_0:def 4;
then A3: x - h in dom (f1 - f2) by VFUNCT_1:def 2;
((bdif ((f1 - f2),h)) . (0 + 1)) /. x = (bD (((bdif ((f1 - f2),h)) . 0),h)) /. x by Def7
.= (bD ((f1 - f2),h)) /. x by Def7
.= ((f1 - f2) /. x) - ((f1 - f2) /. (x - h)) by Th4
.= ((f1 /. x) - (f2 /. x)) - ((f1 - f2) /. (x - h)) by A2, VFUNCT_1:def 2
.= ((f1 /. x) - (f2 /. x)) - ((f1 /. (x - h)) - (f2 /. (x - h))) by A3, VFUNCT_1:def 2
.= (((f1 /. x) - (f2 /. x)) - (f1 /. (x - h))) + (f2 /. (x - h)) by RLVECT_1:29
.= ((f1 /. x) - ((f1 /. (x - h)) + (f2 /. x))) + (f2 /. (x - h)) by RLVECT_1:27
.= (((f1 /. x) - (f1 /. (x - h))) - (f2 /. x)) + (f2 /. (x - h)) by RLVECT_1:27
.= ((f1 /. x) - (f1 /. (x - h))) - ((f2 /. x) - (f2 /. (x - h))) by RLVECT_1:29
.= ((bD (f1,h)) /. x) - ((f2 /. x) - (f2 /. (x - h))) by Th4
.= ((bD (f1,h)) /. x) - ((bD (f2,h)) /. x) by Th4
.= ((bD (((bdif (f1,h)) . 0),h)) /. x) - ((bD (f2,h)) /. x) by Def7
.= ((bD (((bdif (f1,h)) . 0),h)) /. x) - ((bD (((bdif (f2,h)) . 0),h)) /. x) by Def7
.= (((bdif (f1,h)) . (0 + 1)) /. x) - ((bD (((bdif (f2,h)) . 0),h)) /. x) by Def7
.= (((bdif (f1,h)) . (0 + 1)) /. x) - (((bdif (f2,h)) . (0 + 1)) /. x) by Def7 ;
hence ((bdif ((f1 - f2),h)) . (0 + 1)) /. x = (((bdif (f1,h)) . (0 + 1)) /. x) - (((bdif (f2,h)) . (0 + 1)) /. x) ; :: thesis: verum

end;

A4: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A5: for x being Element of V holds ((bdif ((f1 - f2),h)) . (k + 1)) /. x = (((bdif (f1,h)) . (k + 1)) /. x) - (((bdif (f2,h)) . (k + 1)) /. x) ; :: thesis: S₁[k + 1]
let x be Element of V; :: thesis: ((bdif ((f1 - f2),h)) . ((k + 1) + 1)) /. x = (((bdif (f1,h)) . ((k + 1) + 1)) /. x) - (((bdif (f2,h)) . ((k + 1) + 1)) /. x)
A6: ( ((bdif ((f1 - f2),h)) . (k + 1)) /. x = (((bdif (f1,h)) . (k + 1)) /. x) - (((bdif (f2,h)) . (k + 1)) /. x) & ((bdif ((f1 - f2),h)) . (k + 1)) /. (x - h) = (((bdif (f1,h)) . (k + 1)) /. (x - h)) - (((bdif (f2,h)) . (k + 1)) /. (x - h)) ) by A5;
A7: (bdif ((f1 - f2),h)) . (k + 1) is Function of V,W by Th12;
A8: (bdif (f2,h)) . (k + 1) is Function of V,W by Th12;
A9: (bdif (f1,h)) . (k + 1) is Function of V,W by Th12;
((bdif ((f1 - f2),h)) . ((k + 1) + 1)) /. x = (bD (((bdif ((f1 - f2),h)) . (k + 1)),h)) /. x by Def7
.= (((bdif ((f1 - f2),h)) . (k + 1)) /. x) - (((bdif ((f1 - f2),h)) . (k + 1)) /. (x - h)) by A7, Th4
.= (((((bdif (f1,h)) . (k + 1)) /. x) - (((bdif (f2,h)) . (k + 1)) /. x)) - (((bdif (f1,h)) . (k + 1)) /. (x - h))) + (((bdif (f2,h)) . (k + 1)) /. (x - h)) by RLVECT_1:29, A6
.= ((((bdif (f1,h)) . (k + 1)) /. x) - ((((bdif (f1,h)) . (k + 1)) /. (x - h)) + (((bdif (f2,h)) . (k + 1)) /. x))) + (((bdif (f2,h)) . (k + 1)) /. (x - h)) by RLVECT_1:27
.= (((((bdif (f1,h)) . (k + 1)) /. x) - (((bdif (f1,h)) . (k + 1)) /. (x - h))) - (((bdif (f2,h)) . (k + 1)) /. x)) + (((bdif (f2,h)) . (k + 1)) /. (x - h)) by RLVECT_1:27
.= ((((bdif (f1,h)) . (k + 1)) /. x) - (((bdif (f1,h)) . (k + 1)) /. (x - h))) - ((((bdif (f2,h)) . (k + 1)) /. x) - (((bdif (f2,h)) . (k + 1)) /. (x - h))) by RLVECT_1:29
.= ((bD (((bdif (f1,h)) . (k + 1)),h)) /. x) - ((((bdif (f2,h)) . (k + 1)) /. x) - (((bdif (f2,h)) . (k + 1)) /. (x - h))) by A9, Th4
.= ((bD (((bdif (f1,h)) . (k + 1)),h)) /. x) - ((bD (((bdif (f2,h)) . (k + 1)),h)) /. x) by A8, Th4
.= (((bdif (f1,h)) . ((k + 1) + 1)) /. x) - ((bD (((bdif (f2,h)) . (k + 1)),h)) /. x) by Def7
.= (((bdif (f1,h)) . ((k + 1) + 1)) /. x) - (((bdif (f2,h)) . ((k + 1) + 1)) /. x) by Def7 ;
hence ((bdif ((f1 - f2),h)) . ((k + 1) + 1)) /. x = (((bdif (f1,h)) . ((k + 1) + 1)) /. x) - (((bdif (f2,h)) . ((k + 1) + 1)) /. x) ; :: thesis: verum

end;

for n being Nat holds S₁[n] from NAT_1:sch 2(A1, A4);
hence ((bdif ((f1 - f2),h)) . (n + 1)) /. x = (((bdif (f1,h)) . (n + 1)) /. x) - (((bdif (f2,h)) . (n + 1)) /. x) ; :: thesis: verum