let F, G be Field; :: thesis: for V being VectSp of F
for W being VectSp of G
for f being Function of V,W
for x, h being Element of V
for r being Element of G
for n being Nat holds ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
let V be VectSp of F; :: thesis: for W being VectSp of G
for f being Function of V,W
for x, h being Element of V
for r being Element of G
for n being Nat holds ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
let W be VectSp of G; :: thesis: for f being Function of V,W
for x, h being Element of V
for r being Element of G
for n being Nat holds ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
let f be Function of V,W; :: thesis: for x, h being Element of V
for r being Element of G
for n being Nat holds ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
let x, h be Element of V; :: thesis: for r being Element of G
for n being Nat holds ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
let r be Element of G; :: thesis: for n being Nat holds ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
let n be Nat; :: thesis: ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x)
defpred S₁[ Nat] means for x being Element of V holds ((bdif ((r (#) f),h)) . ($1 + 1)) /. x = r * (((bdif (f,h)) . ($1 + 1)) /. x);
A1: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A2: for x being Element of V holds ((bdif ((r (#) f),h)) . (k + 1)) /. x = r * (((bdif (f,h)) . (k + 1)) /. x) ; :: thesis: S₁[k + 1]
let x be Element of V; :: thesis: ((bdif ((r (#) f),h)) . ((k + 1) + 1)) /. x = r * (((bdif (f,h)) . ((k + 1) + 1)) /. x)
A3: ( ((bdif ((r (#) f),h)) . (k + 1)) /. x = r * (((bdif (f,h)) . (k + 1)) /. x) & ((bdif ((r (#) f),h)) . (k + 1)) /. (x - h) = r * (((bdif (f,h)) . (k + 1)) /. (x - h)) ) by A2;
A4: (bdif ((r (#) f),h)) . (k + 1) is Function of V,W by Th12;
A5: (bdif (f,h)) . (k + 1) is Function of V,W by Th12;
((bdif ((r (#) f),h)) . ((k + 1) + 1)) /. x = (bD (((bdif ((r (#) f),h)) . (k + 1)),h)) /. x by Def7
.= (((bdif ((r (#) f),h)) . (k + 1)) /. x) - (((bdif ((r (#) f),h)) . (k + 1)) /. (x - h)) by A4, Th4
.= r * ((((bdif (f,h)) . (k + 1)) /. x) - (((bdif (f,h)) . (k + 1)) /. (x - h))) by VECTSP_1:23, A3
.= r * ((bD (((bdif (f,h)) . (k + 1)),h)) /. x) by A5, Th4
.= r * (((bdif (f,h)) . ((k + 1) + 1)) /. x) by Def7 ;
hence ((bdif ((r (#) f),h)) . ((k + 1) + 1)) /. x = r * (((bdif (f,h)) . ((k + 1) + 1)) /. x) ; :: thesis: verum

end;

A6: S₁[ 0 ]

proof

let x be Element of V; :: thesis: ((bdif ((r (#) f),h)) . (0 + 1)) /. x = r * (((bdif (f,h)) . (0 + 1)) /. x)
x in the carrier of V ;
then A7: x in dom (r (#) f) by FUNCT_2:def 1;
x - h in the carrier of V ;
then A8: x - h in dom (r (#) f) by FUNCT_2:def 1;
((bdif ((r (#) f),h)) . (0 + 1)) /. x = (bD (((bdif ((r (#) f),h)) . 0),h)) /. x by Def7
.= (bD ((r (#) f),h)) /. x by Def7
.= ((r (#) f) /. x) - ((r (#) f) /. (x - h)) by Th4
.= ((r (#) f) /. x) - (r * (f /. (x - h))) by A8, Def4X
.= (r * (f /. x)) - (r * (f /. (x - h))) by A7, Def4X
.= r * ((f /. x) - (f /. (x - h))) by VECTSP_1:23
.= r * ((bD (f,h)) /. x) by Th4
.= r * ((bD (((bdif (f,h)) . 0),h)) /. x) by Def7
.= r * (((bdif (f,h)) . (0 + 1)) /. x) by Def7 ;
hence ((bdif ((r (#) f),h)) . (0 + 1)) /. x = r * (((bdif (f,h)) . (0 + 1)) /. x) ; :: thesis: verum

end;

for n being Nat holds S₁[n] from NAT_1:sch 2(A6, A1);
hence ((bdif ((r (#) f),h)) . (n + 1)) /. x = r * (((bdif (f,h)) . (n + 1)) /. x) ; :: thesis: verum