let M be non empty set ; :: thesis: for V being ComplexNormSpace
for f1, f2 being PartFunc of M,V
for f3 being PartFunc of M,COMPLEX holds f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
let V be ComplexNormSpace; :: thesis: for f1, f2 being PartFunc of M,V
for f3 being PartFunc of M,COMPLEX holds f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
let f1, f2 be PartFunc of M,V; :: thesis: for f3 being PartFunc of M,COMPLEX holds f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
let f3 be PartFunc of M,COMPLEX; :: thesis: f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
A1: dom (f3 (#) (f1 + f2)) = (dom f3) /\ (dom (f1 + f2)) by Def1
.= (dom f3) /\ ((dom f1) /\ (dom f2)) by VFUNCT_1:def 1
.= (((dom f3) /\ (dom f3)) /\ (dom f1)) /\ (dom f2) by XBOOLE_1:16
.= (((dom f3) /\ (dom f1)) /\ (dom f3)) /\ (dom f2) by XBOOLE_1:16
.= ((dom f3) /\ (dom f1)) /\ ((dom f3) /\ (dom f2)) by XBOOLE_1:16
.= (dom (f3 (#) f1)) /\ ((dom f3) /\ (dom f2)) by Def1
.= (dom (f3 (#) f1)) /\ (dom (f3 (#) f2)) by Def1
.= dom ((f3 (#) f1) + (f3 (#) f2)) by VFUNCT_1:def 1 ;

now :: thesis: for x being Element of M st x in dom (f3 (#) (f1 + f2)) holds
(f3 (#) (f1 + f2)) /. x = ((f3 (#) f1) + (f3 (#) f2)) /. x

let x be Element of M; :: thesis: ( x in dom (f3 (#) (f1 + f2)) implies (f3 (#) (f1 + f2)) /. x = ((f3 (#) f1) + (f3 (#) f2)) /. x )
assume A2: x in dom (f3 (#) (f1 + f2)) ; :: thesis: (f3 (#) (f1 + f2)) /. x = ((f3 (#) f1) + (f3 (#) f2)) /. x
then x in (dom f3) /\ (dom (f1 + f2)) by Def1;
then A3: x in dom (f1 + f2) by XBOOLE_0:def 4;
A4: x in (dom (f3 (#) f1)) /\ (dom (f3 (#) f2)) by A1, A2, VFUNCT_1:def 1;
then A5: x in dom (f3 (#) f1) by XBOOLE_0:def 4;
A6: x in dom (f3 (#) f2) by A4, XBOOLE_0:def 4;
thus (f3 (#) (f1 + f2)) /. x = (f3 /. x) * ((f1 + f2) /. x) by A2, Def1
.= (f3 /. x) * ((f1 /. x) + (f2 /. x)) by A3, VFUNCT_1:def 1
.= ((f3 /. x) * (f1 /. x)) + ((f3 /. x) * (f2 /. x)) by CLVECT_1:def 2
.= ((f3 (#) f1) /. x) + ((f3 /. x) * (f2 /. x)) by A5, Def1
.= ((f3 (#) f1) /. x) + ((f3 (#) f2) /. x) by A6, Def1
.= ((f3 (#) f1) + (f3 (#) f2)) /. x by A1, A2, VFUNCT_1:def 1 ; :: thesis: verum

end;

hence f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2) by A1, PARTFUN2:1; :: thesis: verum