let GF be Field; :: thesis: for V being VectSp of GF
for A, B being finite Subset of V
for v being Vector of V st v in Lin (A \/ B) & not v in Lin B holds
ex w being Vector of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
let V be VectSp of GF; :: thesis: for A, B being finite Subset of V
for v being Vector of V st v in Lin (A \/ B) & not v in Lin B holds
ex w being Vector of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
let A, B be finite Subset of V; :: thesis: for v being Vector of V st v in Lin (A \/ B) & not v in Lin B holds
ex w being Vector of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
let v be Vector of V; :: thesis: ( v in Lin (A \/ B) & not v in Lin B implies ex w being Vector of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) ) )
assume that
A1: v in Lin (A \/ B) and
A2: not v in Lin B ; :: thesis: ex w being Vector of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
consider L being Linear_Combination of A \/ B such that
A3: v = Sum L by A1, VECTSP_7:7;
v in {v} by TARSKI:def 1;
then v in Lin {v} by VECTSP_7:8;
then consider Lv being Linear_Combination of {v} such that
A4: v = Sum Lv by VECTSP_7:7;
A5: Carrier L c= A \/ B by VECTSP_6:def 4;

now :: thesis: ex w being Vector of V st
( w in A & not L . w = 0. GF )

assume A6: for w being Vector of V st w in A holds
L . w = 0. GF ; :: thesis: contradiction

now :: thesis: for x being object st x in Carrier L holds
not x in A

let x be object ; :: thesis: ( x in Carrier L implies not x in A )
assume that
A7: x in Carrier L and
A8: x in A ; :: thesis: contradiction
ex u being Vector of V st
( x = u & L . u <> 0. GF ) by A7, VECTSP_6:1;
hence contradiction by A6, A8; :: thesis: verum

end;

then Carrier L misses A by XBOOLE_0:3;
then Carrier L c= B by A5, XBOOLE_1:73;
then L is Linear_Combination of B by VECTSP_6:def 4;
hence contradiction by A2, A3, VECTSP_7:7; :: thesis: verum

end;

then consider w being Vector of V such that
A9: w in A and
A10: L . w <> 0. GF ;
set a = L . w;
take w ; :: thesis: ( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
consider F being FinSequence of the carrier of V such that
A11: F is one-to-one and
A12: rng F = Carrier L and
A13: Sum L = Sum (L (#) F) by VECTSP_6:def 6;
A14: w in Carrier L by A10, VECTSP_6:1;
then reconsider Fw1 = F -| w as FinSequence of the carrier of V by A12, FINSEQ_4:41;
reconsider Fw2 = F |-- w as FinSequence of the carrier of V by A12, A14, FINSEQ_4:50;
A15: rng Fw1 misses rng Fw2 by A11, A12, A14, FINSEQ_4:57;
set Fw = Fw1 ^ Fw2;
F just_once_values w by A11, A12, A14, FINSEQ_4:8;
then A16: Fw1 ^ Fw2 = F - {w} by FINSEQ_4:54;
then A17: rng (Fw1 ^ Fw2) = (Carrier L) \ {w} by A12, FINSEQ_3:65;
F = ((F -| w) ^ <*w*>) ^ (F |-- w) by A12, A14, FINSEQ_4:51;
then F = Fw1 ^ (<*w*> ^ Fw2) by FINSEQ_1:32;
then L (#) F = (L (#) Fw1) ^ (L (#) (<*w*> ^ Fw2)) by VECTSP_6:13
.= (L (#) Fw1) ^ ((L (#) <*w*>) ^ (L (#) Fw2)) by VECTSP_6:13
.= ((L (#) Fw1) ^ (L (#) <*w*>)) ^ (L (#) Fw2) by FINSEQ_1:32
.= ((L (#) Fw1) ^ <*((L . w) * w)*>) ^ (L (#) Fw2) by VECTSP_6:10 ;
then A18: Sum (L (#) F) = Sum ((L (#) Fw1) ^ (<*((L . w) * w)*> ^ (L (#) Fw2))) by FINSEQ_1:32
.= (Sum (L (#) Fw1)) + (Sum (<*((L . w) * w)*> ^ (L (#) Fw2))) by RLVECT_1:41
.= (Sum (L (#) Fw1)) + ((Sum <*((L . w) * w)*>) + (Sum (L (#) Fw2))) by RLVECT_1:41
.= (Sum (L (#) Fw1)) + ((Sum (L (#) Fw2)) + ((L . w) * w)) by RLVECT_1:44
.= ((Sum (L (#) Fw1)) + (Sum (L (#) Fw2))) + ((L . w) * w) by RLVECT_1:def 3
.= (Sum ((L (#) Fw1) ^ (L (#) Fw2))) + ((L . w) * w) by RLVECT_1:41
.= (Sum (L (#) (Fw1 ^ Fw2))) + ((L . w) * w) by VECTSP_6:13 ;
consider K being Linear_Combination of V such that
A19: Carrier K = (rng (Fw1 ^ Fw2)) /\ (Carrier L) and
A20: L (#) (Fw1 ^ Fw2) = K (#) (Fw1 ^ Fw2) by Th4;
rng (Fw1 ^ Fw2) = (rng F) \ {w} by A16, FINSEQ_3:65;
then A21: Carrier K = rng (Fw1 ^ Fw2) by A12, A19, XBOOLE_1:28;
A22: (Carrier L) \ {w} c= (A \/ B) \ {w} by A5, XBOOLE_1:33;
then reconsider K = K as Linear_Combination of (A \/ B) \ {w} by A17, A21, VECTSP_6:def 4;
set LC = ((L . w) ") * ((- K) + Lv);
Carrier ((- K) + Lv) c= (Carrier (- K)) \/ (Carrier Lv) by VECTSP_6:23;
then A23: Carrier ((- K) + Lv) c= (Carrier K) \/ (Carrier Lv) by VECTSP_6:38;
Carrier Lv c= {v} by VECTSP_6:def 4;
then (Carrier K) \/ (Carrier Lv) c= ((A \/ B) \ {w}) \/ {v} by A17, A21, A22, XBOOLE_1:13;
then ( Carrier (((L . w) ") * ((- K) + Lv)) c= Carrier ((- K) + Lv) & Carrier ((- K) + Lv) c= ((A \/ B) \ {w}) \/ {v} ) by A23, VECTSP_6:28;
then Carrier (((L . w) ") * ((- K) + Lv)) c= ((A \/ B) \ {w}) \/ {v} ;
then A24: ((L . w) ") * ((- K) + Lv) is Linear_Combination of ((A \/ B) \ {w}) \/ {v} by VECTSP_6:def 4;
( Fw1 is one-to-one & Fw2 is one-to-one ) by A11, A12, A14, FINSEQ_4:52, FINSEQ_4:53;
then Fw1 ^ Fw2 is one-to-one by A15, FINSEQ_3:91;
then Sum (K (#) (Fw1 ^ Fw2)) = Sum K by A21, VECTSP_6:def 6;
then ((L . w) ") * v = (((L . w) ") * (Sum K)) + (((L . w) ") * ((L . w) * w)) by A3, A13, A18, A20, VECTSP_1:def 14
.= (((L . w) ") * (Sum K)) + w by A10, VECTSP_1:20 ;
then w = (((L . w) ") * v) - (((L . w) ") * (Sum K)) by VECTSP_2:2
.= ((L . w) ") * (v - (Sum K)) by VECTSP_1:23
.= ((L . w) ") * ((- (Sum K)) + v) by RLVECT_1:def 11 ;
then w = ((L . w) ") * ((Sum (- K)) + (Sum Lv)) by A4, VECTSP_6:46
.= ((L . w) ") * (Sum ((- K) + Lv)) by VECTSP_6:44
.= Sum (((L . w) ") * ((- K) + Lv)) by VECTSP_6:45 ;
hence ( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) ) by A9, A24, VECTSP_7:7; :: thesis: verum