let GF be Ring; :: thesis: for V being LeftMod of GF
for A, B being Subset of V holds Lin (A \/ B) = (Lin A) + (Lin B)
let V be LeftMod of GF; :: thesis: for A, B being Subset of V holds Lin (A \/ B) = (Lin A) + (Lin B)
let A, B be Subset of V; :: thesis: Lin (A \/ B) = (Lin A) + (Lin B)

now :: thesis: for v being Vector of V st v in Lin (A \/ B) holds
v in (Lin A) + (Lin B)

deffunc H₁( object ) -> Element of the carrier of GF = 0. GF;
let v be Vector of V; :: thesis: ( v in Lin (A \/ B) implies v in (Lin A) + (Lin B) )
assume v in Lin (A \/ B) ; :: thesis: v in (Lin A) + (Lin B)
then consider l being Linear_Combination of A \/ B such that
A1: v = Sum l by Th7;
deffunc H₂( object ) -> set = l . $1;
set D = (Carrier l) \ A;
set C = (Carrier l) /\ A;
defpred S₁[ object ] means $1 in (Carrier l) /\ A;

A2: now :: thesis: for x being object st x in the carrier of V holds
( ( S₁[x] implies H₂(x) in the carrier of GF ) & ( not S₁[x] implies H₁(x) in the carrier of GF ) )

let x be object ; :: thesis: ( x in the carrier of V implies ( ( S₁[x] implies H₂(x) in the carrier of GF ) & ( not S₁[x] implies H₁(x) in the carrier of GF ) ) )
assume x in the carrier of V ; :: thesis: ( ( S₁[x] implies H₂(x) in the carrier of GF ) & ( not S₁[x] implies H₁(x) in the carrier of GF ) )
then reconsider v = x as Vector of V ;
for f being Function of V,GF holds f . v in the carrier of GF ;
hence ( S₁[x] implies H₂(x) in the carrier of GF ) ; :: thesis: ( not S₁[x] implies H₁(x) in the carrier of GF )
assume not S₁[x] ; :: thesis: H₁(x) in the carrier of GF
thus H₁(x) in the carrier of GF ; :: thesis: verum

end;

reconsider C = (Carrier l) /\ A as finite Subset of V ;
defpred S₂[ object ] means $1 in (Carrier l) \ A;
reconsider D = (Carrier l) \ A as finite Subset of V ;
A3: D c= B

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in D or x in B )
assume x in D ; :: thesis: x in B
then A4: ( x in Carrier l & not x in A ) by XBOOLE_0:def 5;
Carrier l c= A \/ B by VECTSP_6:def 4;
hence x in B by A4, XBOOLE_0:def 3; :: thesis: verum

end;

consider f being Function of V,GF such that
A5: for x being object st x in the carrier of V holds
( ( S₁[x] implies f . x = H₂(x) ) & ( not S₁[x] implies f . x = H₁(x) ) ) from FUNCT_2:sch 5(A2);
reconsider f = f as Element of Funcs ( the carrier of V, the carrier of GF) by FUNCT_2:8;
for u being Vector of V st not u in C holds
f . u = 0. GF by A5;
then reconsider f = f as Linear_Combination of V by VECTSP_6:def 1;
A6: Carrier f c= C

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier f or x in C )
assume x in Carrier f ; :: thesis: x in C
then A7: ex u being Vector of V st
( x = u & f . u <> 0. GF ) ;
assume not x in C ; :: thesis: contradiction
hence contradiction by A5, A7; :: thesis: verum

end;

C c= A by XBOOLE_1:17;
then Carrier f c= A by A6;
then reconsider f = f as Linear_Combination of A by VECTSP_6:def 4;
deffunc H₃( object ) -> set = l . $1;

A8: now :: thesis: for x being object st x in the carrier of V holds
( ( S₂[x] implies H₃(x) in the carrier of GF ) & ( not S₂[x] implies H₁(x) in the carrier of GF ) )

let x be object ; :: thesis: ( x in the carrier of V implies ( ( S₂[x] implies H₃(x) in the carrier of GF ) & ( not S₂[x] implies H₁(x) in the carrier of GF ) ) )
assume x in the carrier of V ; :: thesis: ( ( S₂[x] implies H₃(x) in the carrier of GF ) & ( not S₂[x] implies H₁(x) in the carrier of GF ) )
then reconsider v = x as Vector of V ;
for g being Function of V,GF holds g . v in the carrier of GF ;
hence ( S₂[x] implies H₃(x) in the carrier of GF ) ; :: thesis: ( not S₂[x] implies H₁(x) in the carrier of GF )
assume not S₂[x] ; :: thesis: H₁(x) in the carrier of GF
thus H₁(x) in the carrier of GF ; :: thesis: verum

end;

consider g being Function of the carrier of V, the carrier of GF such that
A9: for x being object st x in the carrier of V holds
( ( S₂[x] implies g . x = H₃(x) ) & ( not S₂[x] implies g . x = H₁(x) ) ) from FUNCT_2:sch 5(A8);
reconsider g = g as Element of Funcs ( the carrier of V, the carrier of GF) by FUNCT_2:8;
for u being Vector of V st not u in D holds
g . u = 0. GF by A9;
then reconsider g = g as Linear_Combination of V by VECTSP_6:def 1;
Carrier g c= D

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier g or x in D )
assume x in Carrier g ; :: thesis: x in D
then A10: ex u being Vector of V st
( x = u & g . u <> 0. GF ) ;
assume not x in D ; :: thesis: contradiction
hence contradiction by A9, A10; :: thesis: verum

end;

then Carrier g c= B by A3;
then reconsider g = g as Linear_Combination of B by VECTSP_6:def 4;
l = f + g

proof

let v be Vector of V; :: according to VECTSP_6:def 7 :: thesis: l . v = (f + g) . v

now :: thesis: (f + g) . v = l . v

per cases ( v in C or not v in C ) ;

suppose A11: v in C ; :: thesis: (f + g) . v = l . v

A12: now :: thesis: not v in D

assume v in D ; :: thesis: contradiction
then not v in A by XBOOLE_0:def 5;
hence contradiction by A11, XBOOLE_0:def 4; :: thesis: verum

end;

thus (f + g) . v = (f . v) + (g . v) by VECTSP_6:22
.= (l . v) + (g . v) by A5, A11
.= (l . v) + (0. GF) by A9, A12
.= l . v by RLVECT_1:4 ; :: thesis: verum

end;

suppose A13: not v in C ; :: thesis: l . v = (f + g) . v

now :: thesis: (f + g) . v = l . v

per cases ( v in Carrier l or not v in Carrier l ) ;

suppose A14: v in Carrier l ; :: thesis: (f + g) . v = l . v

A15: now :: thesis: v in D

assume not v in D ; :: thesis: contradiction
then ( not v in Carrier l or v in A ) by XBOOLE_0:def 5;
hence contradiction by A13, A14, XBOOLE_0:def 4; :: thesis: verum

end;

thus (f + g) . v = (f . v) + (g . v) by VECTSP_6:22
.= (g . v) + (0. GF) by A5, A13
.= g . v by RLVECT_1:4
.= l . v by A9, A15 ; :: thesis: verum

end;

suppose A16: not v in Carrier l ; :: thesis: (f + g) . v = l . v

then A17: not v in D by XBOOLE_0:def 5;
A18: not v in C by A16, XBOOLE_0:def 4;
thus (f + g) . v = (f . v) + (g . v) by VECTSP_6:22
.= (0. GF) + (g . v) by A5, A18
.= (0. GF) + (0. GF) by A9, A17
.= 0. GF by RLVECT_1:4
.= l . v by A16 ; :: thesis: verum

end;

end;

end;

hence l . v = (f + g) . v ; :: thesis: verum

end;

end;

end;

hence l . v = (f + g) . v ; :: thesis: verum

end;

then A19: v = (Sum f) + (Sum g) by A1, VECTSP_6:44;
( Sum f in Lin A & Sum g in Lin B ) by Th7;
hence v in (Lin A) + (Lin B) by A19, VECTSP_5:1; :: thesis: verum

end;

then A20: Lin (A \/ B) is Subspace of (Lin A) + (Lin B) by VECTSP_4:28;
( Lin A is Subspace of Lin (A \/ B) & Lin B is Subspace of Lin (A \/ B) ) by Th13, XBOOLE_1:7;
then (Lin A) + (Lin B) is Subspace of Lin (A \/ B) by VECTSP_5:34;
hence Lin (A \/ B) = (Lin A) + (Lin B) by A20, VECTSP_4:25; :: thesis: verum