let f be Real_Sequence; :: thesis: ( f is absolutely_summable implies |.(Sum f).| <= Sum (abs f) )
defpred S₁[ Nat] means (abs (Partial_Sums f)) . $1 <= (Partial_Sums (abs f)) . $1;

A1: now :: thesis: for n being Nat st S₁[n] holds
S₁[n + 1]

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume S₁[n] ; :: thesis: S₁[n + 1]
then |.((Partial_Sums f) . n).| <= (Partial_Sums (abs f)) . n by SEQ_1:12;
then ( |.(((Partial_Sums f) . n) + (f . (n + 1))).| <= |.((Partial_Sums f) . n).| + |.(f . (n + 1)).| & |.((Partial_Sums f) . n).| + |.(f . (n + 1)).| <= ((Partial_Sums (abs f)) . n) + |.(f . (n + 1)).| ) by COMPLEX1:56, XREAL_1:6;
then |.(((Partial_Sums f) . n) + (f . (n + 1))).| <= ((Partial_Sums (abs f)) . n) + |.(f . (n + 1)).| by XXREAL_0:2;
then |.((Partial_Sums f) . (n + 1)).| <= ((Partial_Sums (abs f)) . n) + |.(f . (n + 1)).| by SERIES_1:def 1;
then (abs (Partial_Sums f)) . (n + 1) <= ((Partial_Sums (abs f)) . n) + |.(f . (n + 1)).| by SEQ_1:12;
then (abs (Partial_Sums f)) . (n + 1) <= ((Partial_Sums (abs f)) . n) + ((abs f) . (n + 1)) by SEQ_1:12;
hence S₁[n + 1] by SERIES_1:def 1; :: thesis: verum

end;

(abs (Partial_Sums f)) . 0 = |.((Partial_Sums f) . 0).| by SEQ_1:12
.= |.(f . 0).| by SERIES_1:def 1
.= (abs f) . 0 by SEQ_1:12 ;
then A2: S₁[ 0 ] by SERIES_1:def 1;
A3: for n being Nat holds S₁[n] from NAT_1:sch 2(A2, A1);
assume A4: f is absolutely_summable ; :: thesis: |.(Sum f).| <= Sum (abs f)
then abs f is summable by SERIES_1:def 4;
then A5: Partial_Sums (abs f) is convergent by SERIES_1:def 2;
f is summable by A4;
then A6: Partial_Sums f is convergent by SERIES_1:def 2;
then lim (abs (Partial_Sums f)) <= lim (Partial_Sums (abs f)) by A5, A3, SEQ_2:18;
then |.(lim (Partial_Sums f)).| <= lim (Partial_Sums (abs f)) by A6, SEQ_4:14;
then |.(lim (Partial_Sums f)).| <= Sum (abs f) by SERIES_1:def 3;
hence |.(Sum f).| <= Sum (abs f) by SERIES_1:def 3; :: thesis: verum