let R be RelStr ; :: thesis: for X being Subset of R holds
( X is well_founded iff subrelstr X is well_founded )

let X be Subset of R; :: thesis: ( X is well_founded iff subrelstr X is well_founded )
set S = subrelstr X;
set I = the InternalRel of R;
set I2 = the InternalRel of R |_2 X;
A1: the carrier of (subrelstr X) = X by YELLOW_0:def 15;
then A2: the InternalRel of (subrelstr X) = the InternalRel of R |_2 X by YELLOW_0:def 14;
hereby :: thesis: ( subrelstr X is well_founded implies X is well_founded )
assume A3: X is well_founded ; :: thesis: subrelstr X is well_founded
for Y being set st Y c= X & Y <> {} holds
ex a being object st
( a in Y & ( the InternalRel of R |_2 X) -Seg a misses Y )
proof
let Y be set ; :: thesis: ( Y c= X & Y <> {} implies ex a being object st
( a in Y & ( the InternalRel of R |_2 X) -Seg a misses Y ) )

assume A4: ( Y c= X & Y <> {} ) ; :: thesis: ex a being object st
( a in Y & ( the InternalRel of R |_2 X) -Seg a misses Y )

consider a being object such that
A5: ( a in Y & the InternalRel of R -Seg a misses Y ) by A4, A3, WELLFND1:def 3, WELLORD1:def 3;
( the InternalRel of R |_2 X) -Seg a misses Y by A5, XBOOLE_1:63, WELLORD1:14;
hence ex a being object st
( a in Y & ( the InternalRel of R |_2 X) -Seg a misses Y ) by A5; :: thesis: verum
end;
hence subrelstr X is well_founded by A2, A1, WELLFND1:def 2, WELLORD1:def 3; :: thesis: verum
end;
assume A6: subrelstr X is well_founded ; :: thesis: X is well_founded
for Y being set st Y c= X & Y <> {} holds
ex a being object st
( a in Y & the InternalRel of R -Seg a misses Y )
proof
let Y be set ; :: thesis: ( Y c= X & Y <> {} implies ex a being object st
( a in Y & the InternalRel of R -Seg a misses Y ) )

assume A7: ( Y c= X & Y <> {} ) ; :: thesis: ex a being object st
( a in Y & the InternalRel of R -Seg a misses Y )

consider a being object such that
A8: ( a in Y & ( the InternalRel of R |_2 X) -Seg a misses Y ) by A7, A6, A2, A1, WELLFND1:def 2, WELLORD1:def 3;
take a ; :: thesis: ( a in Y & the InternalRel of R -Seg a misses Y )
thus a in Y by A8; :: thesis: the InternalRel of R -Seg a misses Y
assume the InternalRel of R -Seg a meets Y ; :: thesis: contradiction
then consider b being object such that
A9: ( b in the InternalRel of R -Seg a & b in Y ) by XBOOLE_0:3;
A10: ( b <> a & [b,a] in the InternalRel of R ) by A9, WELLORD1:1;
[b,a] in [:X,X:] by A8, A7, A9, ZFMISC_1:87;
then [b,a] in the InternalRel of R /\ [:X,X:] by A10, XBOOLE_0:def 4;
then [b,a] in the InternalRel of R |_2 X by WELLORD1:def 6;
then b in ( the InternalRel of R |_2 X) -Seg a by A10, WELLORD1:1;
hence contradiction by A8, A9, XBOOLE_0:3; :: thesis: verum
end;
hence X is well_founded by WELLFND1:def 3, WELLORD1:def 3; :: thesis: verum