let n be Nat; :: thesis: for f being PartFunc of REAL,REAL st f is_C^1-Class_on ['0,1'] holds
Sum ('G' (f,n)) = integral ((- f),0,1)

let f be PartFunc of REAL,REAL; :: thesis: ( f is_C^1-Class_on ['0,1'] implies Sum ('G' (f,n)) = integral ((- f),0,1) )
set n1 = n + 1;
assume A1: f is_C^1-Class_on ['0,1'] ; :: thesis: Sum ('G' (f,n)) = integral ((- f),0,1)
A2: dom ('G' (f,n)) = Seg (n + 1) by Def13;
Sum ('G' (f,n)) = integral ((- f),0,1)
proof
defpred S1[ Nat] means ( $1 < n + 1 implies Sum (('G' (f,n)) | $1) = integral ((- f),0,($1 / (n + 1))) );
A3: for j being Nat st ( for m being Nat st m < j holds
S1[m] ) holds
S1[j]
proof
let j be Nat; :: thesis: ( ( for m being Nat st m < j holds
S1[m] ) implies S1[j] )

assume A4: for m being Nat st m < j holds
S1[m] ; :: thesis: S1[j]
( j < n + 1 implies Sum (('G' (f,n)) | j) = integral ((- f),0,(j / (n + 1))) )
proof
assume A5: j < n + 1 ; :: thesis: Sum (('G' (f,n)) | j) = integral ((- f),0,(j / (n + 1)))
per cases ( j > 0 or j = 0 ) ;
suppose j > 0 ; :: thesis: Sum (('G' (f,n)) | j) = integral ((- f),0,(j / (n + 1)))
then reconsider s = j - 1 as Nat ;
( s + 1 = (j - 1) + 1 & (j - 1) + 1 = j ) ;
then s < j by NAT_1:19;
then A9: ( s < n + 1 implies Sum (('G' (f,n)) | s) = integral ((- f),0,(s / (n + 1))) ) by A4;
A10: 1 <= s + 1 by NAT_1:14;
reconsider g = ('G' (f,n)) | s as FinSequence of F_Real ;
A11: rng ('G' (f,n)) c= the carrier of F_Real by FINSEQ_1:def 4;
A12: s + 1 in dom ('G' (f,n)) by A2, A5, A10;
then reconsider rs = ('G' (f,n)) . (s + 1) as Element of F_Real by A11, FUNCT_1:3;
A13: s < s + 1 by XREAL_1:29;
then A14: s < n + 1 by A5, XXREAL_0:2;
A15: ('G' (f,n)) . (s + 1) = integral ((- f),(((s + 1) -' 1) / (n + 1)),((s + 1) / (n + 1))) by A12, Def13
.= integral ((- f),(s / (n + 1)),((s + 1) / (n + 1))) ;
A16: (integral ((- f),0,(s / (n + 1)))) + (integral ((- f),(s / (n + 1)),((s + 1) / (n + 1)))) = integral ((- f),0,((s + 1) / (n + 1)))
proof
per cases ( s <> 0 or s = 0 ) ;
suppose A17: s <> 0 ; :: thesis: (integral ((- f),0,(s / (n + 1)))) + (integral ((- f),(s / (n + 1)),((s + 1) / (n + 1)))) = integral ((- f),0,((s + 1) / (n + 1)))
then s >= 1 by NAT_1:14;
then s in Seg (n + 1) by A14;
then A18: ( - f is_integrable_on ['0,(s / (n + 1))'] & (- f) | ['0,(s / (n + 1))'] is bounded & ['0,(s / (n + 1))'] c= dom (- f) ) by Lm13, A1;
A19: ( 0 < s / (n + 1) & s / (n + 1) < (s + 1) / (n + 1) ) by XREAL_1:29, XREAL_1:74, A17;
( 1 <= s + 1 & s + 1 < n + 1 ) by A5, NAT_1:14;
then A20: s + 1 in Seg (n + 1) ;
then A21: ['0,((s + 1) / (n + 1))'] c= dom (- f) by Lm13, A1;
( - f is_integrable_on ['(((s + 1) -' 1) / (n + 1)),((s + 1) / (n + 1))'] & (- f) | ['(((s + 1) -' 1) / (n + 1)),((s + 1) / (n + 1))'] is bounded & ['(((s + 1) -' 1) / (n + 1)),((s + 1) / (n + 1))'] c= dom (- f) ) by A20, Lm12, A1;
hence (integral ((- f),0,(s / (n + 1)))) + (integral ((- f),(s / (n + 1)),((s + 1) / (n + 1)))) = integral ((- f),0,((s + 1) / (n + 1))) by INTEGR24:1, A21, A18, A19; :: thesis: verum
end;
suppose A23: s = 0 ; :: thesis: (integral ((- f),0,(s / (n + 1)))) + (integral ((- f),(s / (n + 1)),((s + 1) / (n + 1)))) = integral ((- f),0,((s + 1) / (n + 1)))
integral ((- f),0,0) = 0 by Th9;
hence (integral ((- f),0,(s / (n + 1)))) + (integral ((- f),(s / (n + 1)),((s + 1) / (n + 1)))) = integral ((- f),0,((s + 1) / (n + 1))) by A23; :: thesis: verum
end;
end;
end;
Sum (('G' (f,n)) | (s + 1)) = Sum (g ^ <*rs*>) by A12, FINSEQ_5:10
.= (Sum g) + rs by FVSUM_1:71
.= integral ((- f),0,((s + 1) / (n + 1))) by A16, A15, A9, A13, A5, XXREAL_0:2 ;
hence Sum (('G' (f,n)) | j) = integral ((- f),0,(j / (n + 1))) ; :: thesis: verum
end;
suppose A25: j = 0 ; :: thesis: Sum (('G' (f,n)) | j) = integral ((- f),0,(j / (n + 1)))
Sum (('G' (f,n)) | 0) = Sum (<*> the carrier of F_Real)
.= 0. F_Real by RLVECT_1:43
.= 0 by VECTSP_1:def 5 ;
hence Sum (('G' (f,n)) | j) = integral ((- f),0,(j / (n + 1))) by Th9, A25; :: thesis: verum
end;
end;
end;
hence S1[j] ; :: thesis: verum
end;
A27: for j being Nat holds S1[j] from NAT_1:sch 4(A3);
reconsider i = (n + 1) -' 1 as Nat ;
A28: rng ('G' (f,n)) c= the carrier of F_Real by FINSEQ_1:def 4;
reconsider g = ('G' (f,n)) | i as FinSequence of F_Real ;
A29: ('G' (f,n)) . (i + 1) in rng ('G' (f,n)) by A2, FUNCT_1:3, FINSEQ_1:3;
reconsider r1 = ('G' (f,n)) . (i + 1) as Element of F_Real by A28, A29;
A30: ('G' (f,n)) . (n + 1) = integral ((- f),(((n + 1) -' 1) / (n + 1)),((n + 1) / (n + 1))) by Def13, A2, FINSEQ_1:3
.= integral ((- f),(((n + 1) -' 1) / (n + 1)),1) by XCMPLX_1:60 ;
A31: Sum (('G' (f,n)) | ((n + 1) - 1)) = integral ((- f),0,(((n + 1) - 1) / (n + 1))) by A27, XREAL_1:44;
Sum (('G' (f,n)) | (i + 1)) = Sum (g ^ <*r1*>) by A2, FINSEQ_1:3, FINSEQ_5:10
.= (Sum g) + r1 by FVSUM_1:71
.= integral ((- f),0,1) by A1, Lm21, A30, A31 ;
hence Sum ('G' (f,n)) = integral ((- f),0,1) by A2; :: thesis: verum
end;
hence Sum ('G' (f,n)) = integral ((- f),0,1) ; :: thesis: verum