let w, z be Complex; :: thesis: for n being Nat holds (Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n
let n be Nat; :: thesis: (Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n
A1: (Partial_Sums ((z + w) ExpSeq)) . 0 = ((z + w) ExpSeq) . 0 by SERIES_1:def 1
.= 1 by Th10 ;
defpred S₁[ Nat] means (Partial_Sums ((z + w) ExpSeq)) . $1 = (Partial_Sums (Alfa ($1,z,w))) . $1;
A2: 0 -' 0 = 0 by XREAL_1:232;
(Partial_Sums (Alfa (0,z,w))) . 0 = (Alfa (0,z,w)) . 0 by SERIES_1:def 1
.= ((z ExpSeq) . 0) * ((Partial_Sums (w ExpSeq)) . 0) by A2, Def11
.= ((z ExpSeq) . 0) * ((w ExpSeq) . 0) by SERIES_1:def 1
.= 1r * ((w ExpSeq) . 0) by Th10
.= 1 by Th10 ;
then A3: S₁[ 0 ] by A1;
A4: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A5: (Partial_Sums ((z + w) ExpSeq)) . k = (Partial_Sums (Alfa (k,z,w))) . k ; :: thesis: S₁[k + 1]
A6: (Partial_Sums (Alfa ((k + 1),z,w))) . (k + 1) = ((Partial_Sums (Alfa ((k + 1),z,w))) . k) + ((Alfa ((k + 1),z,w)) . (k + 1)) by SERIES_1:def 1
.= (((Partial_Sums (Alfa (k,z,w))) . k) + ((Partial_Sums (Expan_e ((k + 1),z,w))) . k)) + ((Alfa ((k + 1),z,w)) . (k + 1)) by Th12
.= ((Partial_Sums ((z + w) ExpSeq)) . k) + (((Partial_Sums (Expan_e ((k + 1),z,w))) . k) + ((Alfa ((k + 1),z,w)) . (k + 1))) by A5 ;
(k + 1) -' (k + 1) = 0 by XREAL_1:232;
then (Alfa ((k + 1),z,w)) . (k + 1) = ((z ExpSeq) . (k + 1)) * ((Partial_Sums (w ExpSeq)) . 0) by Def11
.= ((z ExpSeq) . (k + 1)) * ((w ExpSeq) . 0) by SERIES_1:def 1
.= ((z ExpSeq) . (k + 1)) * 1 by Th10
.= (Expan_e ((k + 1),z,w)) . (k + 1) by Th13 ;
then ((Partial_Sums (Expan_e ((k + 1),z,w))) . k) + ((Alfa ((k + 1),z,w)) . (k + 1)) = (Partial_Sums (Expan_e ((k + 1),z,w))) . (k + 1) by SERIES_1:def 1
.= ((z + w) |^ (k + 1)) / ((k + 1) !) by Th8 ;
then (Partial_Sums (Alfa ((k + 1),z,w))) . (k + 1) = ((Partial_Sums ((z + w) ExpSeq)) . k) + (((z + w) ExpSeq) . (k + 1)) by A6, Def4
.= (Partial_Sums ((z + w) ExpSeq)) . (k + 1) by SERIES_1:def 1 ;
hence (Partial_Sums ((z + w) ExpSeq)) . (k + 1) = (Partial_Sums (Alfa ((k + 1),z,w))) . (k + 1) ; :: thesis: verum

end;

for n being Nat holds S₁[n] from NAT_1:sch 2(A3, A4);
hence (Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n ; :: thesis: verum