let p be Real; :: thesis: ( exp_R is_differentiable_in p & diff (exp_R,p) = exp_R . p )
deffunc H₂( Real) -> Element of REAL = In ((($1 * (exp_R . p)) * (Re (Sum ($1 P_dt)))),REAL);
consider Cr being Function of REAL,REAL such that
A1: for th being Element of REAL holds Cr . th = H₂(th) from FUNCT_2:sch 4();
for hy1 being non-zero 0 -convergent Real_Sequence holds
( (hy1 ") (#) (Cr /* hy1) is convergent & lim ((hy1 ") (#) (Cr /* hy1)) = 0 )

proof

let hy1 be non-zero 0 -convergent Real_Sequence; :: thesis: ( (hy1 ") (#) (Cr /* hy1) is convergent & lim ((hy1 ") (#) (Cr /* hy1)) = 0 )
A2: for n being Nat holds ((hy1 ") (#) (Cr /* hy1)) . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt)))

proof

let n be Nat; :: thesis: ((hy1 ") (#) (Cr /* hy1)) . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt)))
A3: n in NAT by ORDINAL1:def 12;
A4: ((hy1 ") (#) (Cr /* hy1)) . n = ((hy1 ") . n) * ((Cr /* hy1) . n) by SEQ_1:8
.= ((hy1 . n) ") * ((Cr /* hy1) . n) by VALUED_1:10 ;
dom Cr = REAL by FUNCT_2:def 1;
then rng hy1 c= dom Cr ;
then A5: ((hy1 ") (#) (Cr /* hy1)) . n = ((hy1 . n) ") * (Cr . (hy1 . n)) by A4, FUNCT_2:108, A3
.= ((hy1 . n) ") * H₂(hy1 . n) by A1
.= (((hy1 . n) ") * (hy1 . n)) * ((exp_R . p) * (Re (Sum ((hy1 . n) P_dt)))) ;
hy1 . n <> 0 by SEQ_1:5;
then ((hy1 ") (#) (Cr /* hy1)) . n = 1 * ((exp_R . p) * (Re (Sum ((hy1 . n) P_dt)))) by A5, XCMPLX_0:def 7
.= (exp_R . p) * (Re (Sum ((hy1 . n) P_dt))) ;
hence ((hy1 ") (#) (Cr /* hy1)) . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt))) ; :: thesis: verum

end;

deffunc H₃( Real) -> set = (exp_R . p) * (Re (Sum ((hy1 . $1) P_dt)));
consider rseq being Real_Sequence such that
A6: for n being Nat holds rseq . n = H₃(n) from SEQ_1:sch 1();
deffunc H₄( Nat) -> set = (Sum ((hy1 . $1) P_dt)) * (exp_R . p);
consider cq1 being Complex_Sequence such that
A7: for n being Nat holds cq1 . n = H₄(n) from COMSEQ_1:sch 1();
A8: for q being Real st q > 0 holds
ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q

proof

let q be Real; :: thesis: ( q > 0 implies ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q )
assume A9: q > 0 ; :: thesis: ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q

proof

exp_R . p > 0 by Th53;
then consider r being Real such that
A10: r > 0 and
A11: for z being Complex st |.z.| < r holds
|.(Sum (z P_dt)).| < q / (exp_R . p) by A9, Th57;
( hy1 is convergent & lim hy1 = 0 ) ;
then consider k being Nat such that
A12: for m being Nat st k <= m holds
|.((hy1 . m) - 0).| < r by A10, SEQ_2:def 7;

A13: now :: thesis: for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q

let m be Nat; :: thesis: ( k <= m implies |.((cq1 . m) - 0c).| < q )
assume A14: k <= m ; :: thesis: |.((cq1 . m) - 0c).| < q
A15: |.((cq1 . m) - 0c).| = |.((Sum ((hy1 . m) P_dt)) * (exp_R . p)).| by A7
.= |.(Sum ((hy1 . m) P_dt)).| * |.(exp_R . p).| by COMPLEX1:65
.= |.(Sum ((hy1 . m) P_dt)).| * (sqrt (((Re (exp_R . p)) ^2) + ((Im (exp_R . p)) ^2))) ;
exp_R . p = (exp_R . p) + (0 * <i>) ;
then A16: ( Re (exp_R . p) = exp_R . p & Im (exp_R . p) = 0 ) by COMPLEX1:12;
A17: exp_R . p > 0 by Th53;
then A18: |.((cq1 . m) - 0c).| = |.(Sum ((hy1 . m) P_dt)).| * (exp_R . p) by A15, A16, SQUARE_1:22;
|.((hy1 . m) - 0).| < r by A12, A14;
then |.((cq1 . m) - 0c).| < (q / (exp_R . p)) * (exp_R . p) by A11, A17, A18, XREAL_1:68;
hence |.((cq1 . m) - 0c).| < q by A17, XCMPLX_1:87; :: thesis: verum

end;

take k ; :: thesis: for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
thus for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q by A13; :: thesis: verum

end;

hence ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q ; :: thesis: verum

end;

then A19: cq1 is convergent by COMSEQ_2:def 5;
then A20: lim cq1 = 0c by A8, COMSEQ_2:def 6;
A21: for n being Element of NAT holds (Re cq1) . n = rseq . n

proof

A22: for n being Nat holds (Re cq1) . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt)))

proof

let n be Nat; :: thesis: (Re cq1) . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt)))
(Re cq1) . n = Re (cq1 . n) by COMSEQ_3:def 5
.= Re ((Sum ((hy1 . n) P_dt)) * (exp_R . p)) by A7
.= (exp_R . p) * (Re (Sum ((hy1 . n) P_dt))) by Lm12 ;
hence (Re cq1) . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt))) ; :: thesis: verum

end;

let n be Nat; :: thesis: ( n is Element of NAT implies (Re cq1) . n = rseq . n )
rseq . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt))) by A6;
hence ( n is Element of NAT implies (Re cq1) . n = rseq . n ) by A22; :: thesis: verum

end;

for n being Element of NAT holds rseq . n = ((hy1 ") (#) (Cr /* hy1)) . n

proof

let n be Element of NAT ; :: thesis: rseq . n = ((hy1 ") (#) (Cr /* hy1)) . n
rseq . n = (exp_R . p) * (Re (Sum ((hy1 . n) P_dt))) by A6;
hence rseq . n = ((hy1 ") (#) (Cr /* hy1)) . n by A2; :: thesis: verum

end;

then rseq = (hy1 ") (#) (Cr /* hy1) ;
then (hy1 ") (#) (Cr /* hy1) = Re cq1 by A21;
hence ( (hy1 ") (#) (Cr /* hy1) is convergent & lim ((hy1 ") (#) (Cr /* hy1)) = 0 ) by A19, A20, COMPLEX1:4, COMSEQ_3:41; :: thesis: verum

end;

then reconsider PR = Cr as RestFunc by FDIFF_1:def 2;
deffunc H₃( Real) -> Element of REAL = In (($1 * (exp_R . p)),REAL);
consider CL being Function of REAL,REAL such that
A23: for th being Element of REAL holds CL . th = H₃(th) from FUNCT_2:sch 4();
A24: for d being Real holds CL . d = d * (exp_R . p)

proof

let d be Real; :: thesis: CL . d = d * (exp_R . p)
d in REAL by XREAL_0:def 1;
then CL . d = H₃(d) by A23;
hence CL . d = d * (exp_R . p) ; :: thesis: verum

end;

ex r being Real st
for q being Real holds CL . q = r * q

proof

take exp_R . p ; :: thesis: for q being Real holds CL . q = (exp_R . p) * q
thus for q being Real holds CL . q = (exp_R . p) * q by A24; :: thesis: verum

end;

then reconsider PL = CL as LinearFunc by FDIFF_1:def 3;
A25: ex N being Neighbourhood of p st
( N c= dom exp_R & ( for r being Real st r in N holds
(exp_R . r) - (exp_R . p) = (PL . (r - p)) + (PR . (r - p)) ) )

proof

A26: for r being Real st r in ].(p - 1),(p + 1).[ holds
(exp_R . r) - (exp_R . p) = (PL . (r - p)) + (PR . (r - p))

proof

let r be Real; :: thesis: ( r in ].(p - 1),(p + 1).[ implies (exp_R . r) - (exp_R . p) = (PL . (r - p)) + (PR . (r - p)) )
reconsider p = p as Real ;
A27: r - p in REAL by XREAL_0:def 1;
r = p + (r - p) ;
then (exp_R . r) - (exp_R . p) = ((r - p) * (exp_R . p)) + (((r - p) * (exp_R . p)) * (Re (Sum ((r - p) P_dt)))) by Th61
.= ((r - p) * (exp_R . p)) + H₂(r - p)
.= ((r - p) * (exp_R . p)) + (Cr . (r - p)) by A1, A27
.= (PL . (r - p)) + (PR . (r - p)) by A24 ;
hence ( r in ].(p - 1),(p + 1).[ implies (exp_R . r) - (exp_R . p) = (PL . (r - p)) + (PR . (r - p)) ) ; :: thesis: verum

end;

take ].(p - 1),(p + 1).[ ; :: thesis: ( ].(p - 1),(p + 1).[ is Neighbourhood of p & ].(p - 1),(p + 1).[ c= dom exp_R & ( for r being Real st r in ].(p - 1),(p + 1).[ holds
(exp_R . r) - (exp_R . p) = (PL . (r - p)) + (PR . (r - p)) ) )
thus ( ].(p - 1),(p + 1).[ is Neighbourhood of p & ].(p - 1),(p + 1).[ c= dom exp_R & ( for r being Real st r in ].(p - 1),(p + 1).[ holds
(exp_R . r) - (exp_R . p) = (PL . (r - p)) + (PR . (r - p)) ) ) by A26, Th46, RCOMP_1:def 6; :: thesis: verum

end;

then A28: exp_R is_differentiable_in p by FDIFF_1:def 4;
PL . 1 = 1 * (exp_R . p) by A24;
hence ( exp_R is_differentiable_in p & diff (exp_R,p) = exp_R . p ) by A25, A28, FDIFF_1:def 5; :: thesis: verum