let n be Nat; :: thesis: for s, s1, s2 being Real_Sequence st s = s1 (#) s2 & ( for n being Nat holds
( s1 . n < 0 & s2 . n < 0 ) ) holds
(Partial_Sums s) . n <= ((Partial_Sums s1) . n) * ((Partial_Sums s2) . n)
let s, s1, s2 be Real_Sequence; :: thesis: ( s = s1 (#) s2 & ( for n being Nat holds
( s1 . n < 0 & s2 . n < 0 ) ) implies (Partial_Sums s) . n <= ((Partial_Sums s1) . n) * ((Partial_Sums s2) . n) )
assume that
A1: s = s1 (#) s2 and
A2: for n being Nat holds
( s1 . n < 0 & s2 . n < 0 ) ; :: thesis: (Partial_Sums s) . n <= ((Partial_Sums s1) . n) * ((Partial_Sums s2) . n)
defpred S₁[ Nat] means (Partial_Sums s) . $1 <= ((Partial_Sums s1) . $1) * ((Partial_Sums s2) . $1);
A3: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
set j = (Partial_Sums s) . n;
set u = (Partial_Sums s1) . n;
set v = (Partial_Sums s2) . n;
set w = s1 . (n + 1);
set h = s2 . (n + 1);
A4: ((Partial_Sums s1) . (n + 1)) * ((Partial_Sums s2) . (n + 1)) = (((Partial_Sums s1) . n) + (s1 . (n + 1))) * ((Partial_Sums s2) . (n + 1)) by SERIES_1:def 1
.= (((Partial_Sums s1) . n) + (s1 . (n + 1))) * (((Partial_Sums s2) . n) + (s2 . (n + 1))) by SERIES_1:def 1
.= (((((Partial_Sums s1) . n) * ((Partial_Sums s2) . n)) + (((Partial_Sums s1) . n) * (s2 . (n + 1)))) + ((s1 . (n + 1)) * ((Partial_Sums s2) . n))) + ((s1 . (n + 1)) * (s2 . (n + 1))) ;
assume (Partial_Sums s) . n <= ((Partial_Sums s1) . n) * ((Partial_Sums s2) . n) ; :: thesis: S₁[n + 1]
then A5: ((Partial_Sums s) . n) + ((s1 . (n + 1)) * (s2 . (n + 1))) <= (((Partial_Sums s1) . n) * ((Partial_Sums s2) . n)) + ((s1 . (n + 1)) * (s2 . (n + 1))) by XREAL_1:6;
A6: ( s1 . (n + 1) < 0 & s2 . (n + 1) < 0 ) by A2;
( (Partial_Sums s1) . n < 0 & (Partial_Sums s2) . n < 0 ) by A2, Th35;
then A7: (((Partial_Sums s1) . n) * ((Partial_Sums s2) . n)) + ((s1 . (n + 1)) * (s2 . (n + 1))) <= ((((Partial_Sums s1) . n) * ((Partial_Sums s2) . n)) + ((s1 . (n + 1)) * (s2 . (n + 1)))) + ((((Partial_Sums s1) . n) * (s2 . (n + 1))) + ((s1 . (n + 1)) * ((Partial_Sums s2) . n))) by A6, XREAL_1:31;
(Partial_Sums s) . (n + 1) = ((Partial_Sums s) . n) + (s . (n + 1)) by SERIES_1:def 1
.= ((Partial_Sums s) . n) + ((s1 . (n + 1)) * (s2 . (n + 1))) by A1, SEQ_1:8 ;
hence S₁[n + 1] by A4, A5, A7, XXREAL_0:2; :: thesis: verum

end;

A8: ((Partial_Sums s1) . 0) * ((Partial_Sums s2) . 0) = (s1 . 0) * ((Partial_Sums s2) . 0) by SERIES_1:def 1
.= (s1 . 0) * (s2 . 0) by SERIES_1:def 1 ;
(Partial_Sums s) . 0 = s . 0 by SERIES_1:def 1
.= (s1 . 0) * (s2 . 0) by A1, SEQ_1:8 ;
then A9: S₁[ 0 ] by A8;
for n being Nat holds S₁[n] from NAT_1:sch 2(A9, A3);
hence (Partial_Sums s) . n <= ((Partial_Sums s1) . n) * ((Partial_Sums s2) . n) ; :: thesis: verum