let s be Real_Sequence; :: thesis: ( ( for n being Nat holds s . n = 1 / (n * (n + 1)) ) implies for n being Nat holds (Partial_Sums s) . n = 1 - (1 / (n + 1)) )
defpred S₁[ Nat] means (Partial_Sums s) . $1 = 1 - (1 / ($1 + 1));
assume A1: for n being Nat holds s . n = 1 / (n * (n + 1)) ; :: thesis: for n being Nat holds (Partial_Sums s) . n = 1 - (1 / (n + 1))
A2: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
A3: n + 1 <> 0 by NAT_1:5;
assume (Partial_Sums s) . n = 1 - (1 / (n + 1)) ; :: thesis: S₁[n + 1]
then (Partial_Sums s) . (n + 1) = (1 - (1 / (n + 1))) + (s . (n + 1)) by SERIES_1:def 1
.= (1 - (1 / (n + 1))) + (1 / ((n + 1) * ((n + 1) + 1))) by A1
.= 1 - ((1 / (n + 1)) - (1 / ((n + 1) * (n + 2))))
.= 1 - ((1 * (1 / (n + 1))) - ((1 / (n + 1)) * (1 / (n + 2)))) by XCMPLX_1:102
.= 1 - ((1 / (n + 1)) * (1 - (1 / (n + 2))))
.= 1 - ((1 / (n + 1)) * (((1 * (n + 2)) - 1) / (n + 2))) by Lm7
.= 1 - (((1 / (n + 1)) * (n + 1)) / (n + 2)) by XCMPLX_1:74
.= 1 - (1 / (n + 2)) by A3, XCMPLX_1:87 ;
hence S₁[n + 1] ; :: thesis: verum

end;

(Partial_Sums s) . 0 = s . 0 by SERIES_1:def 1
.= 1 / (0 * (0 + 1)) by A1
.= 1 - (1 / 1) by XCMPLX_1:49 ;
then A4: S₁[ 0 ] ;
for n being Nat holds S₁[n] from NAT_1:sch 2(A4, A2);
hence for n being Nat holds (Partial_Sums s) . n = 1 - (1 / (n + 1)) ; :: thesis: verum