let k be Nat; :: thesis: for seq being Real_Sequence st seq ^\ k is convergent holds
seq is convergent
let seq be Real_Sequence; :: thesis: ( seq ^\ k is convergent implies seq is convergent )
assume seq ^\ k is convergent ; :: thesis: seq is convergent
then consider g1 being Real such that
A1: for p being Real st 0 < p holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((seq ^\ k) . m) - g1).| < p ;
take g1 ; :: according to SEQ_2:def 6 :: thesis: for b₁ being object holds
( b₁ <= 0 or ex b₂ being set st
for b₃ being set holds
( not b₂ <= b₃ or not b₁ <= |.((seq . b₃) - g1).| ) )
let p be Real; :: thesis: ( p <= 0 or ex b₁ being set st
for b₂ being set holds
( not b₁ <= b₂ or not p <= |.((seq . b₂) - g1).| ) )
assume 0 < p ; :: thesis: ex b₁ being set st
for b₂ being set holds
( not b₁ <= b₂ or not p <= |.((seq . b₂) - g1).| )
then consider n1 being Nat such that
A2: for m being Nat st n1 <= m holds
|.(((seq ^\ k) . m) - g1).| < p by A1;
take n = n1 + k; :: thesis: for b₁ being set holds
( not n <= b₁ or not p <= |.((seq . b₁) - g1).| )
let m be Nat; :: thesis: ( not n <= m or not p <= |.((seq . m) - g1).| )
assume A3: n <= m ; :: thesis: not p <= |.((seq . m) - g1).|
then consider l being Nat such that
A4: m = (n1 + k) + l by NAT_1:10;
reconsider l = l as Element of NAT by ORDINAL1:def 12;
m - k = ((n1 + l) + k) + (- k) by A4;
then consider m1 being Element of NAT such that
A5: m1 = m - k ;

now :: thesis: n1 <= m1

assume not n1 <= m1 ; :: thesis: contradiction
then m1 + k < n1 + k by XREAL_1:6;
hence contradiction by A3, A5; :: thesis: verum

end;

then A6: |.(((seq ^\ k) . m1) - g1).| < p by A2;
m1 + k = m by A5;
hence not p <= |.((seq . m) - g1).| by A6, NAT_1:def 3; :: thesis: verum