let seq, seq1 be Real_Sequence; :: thesis: ( seq is convergent & ex k being Nat st
for n being Nat st k <= n holds
seq1 . n = seq . n implies seq1 is convergent )
assume that
A1: seq is convergent and
A2: ex k being Nat st
for n being Nat st k <= n holds
seq1 . n = seq . n ; :: thesis: seq1 is convergent
consider g1 being Real such that
A3: for p being Real st 0 < p holds
ex n being Nat st
for m being Nat st n <= m holds
|.((seq . m) - g1).| < p by A1;
consider k being Nat such that
A4: for n being Nat st k <= n holds
seq1 . n = seq . n by A2;
take g = g1; :: according to SEQ_2:def 6 :: thesis: for b₁ being object holds
( b₁ <= 0 or ex b₂ being set st
for b₃ being set holds
( not b₂ <= b₃ or not b₁ <= |.((seq1 . b₃) - g).| ) )
let p be Real; :: thesis: ( p <= 0 or ex b₁ being set st
for b₂ being set holds
( not b₁ <= b₂ or not p <= |.((seq1 . b₂) - g).| ) )
assume 0 < p ; :: thesis: ex b₁ being set st
for b₂ being set holds
( not b₁ <= b₂ or not p <= |.((seq1 . b₂) - g).| )
then consider n1 being Nat such that
A5: for m being Nat st n1 <= m holds
|.((seq . m) - g1).| < p by A3;

A6: now :: thesis: ( n1 <= k implies ex n being Nat st
for m being Nat st n <= m holds
|.((seq1 . m) - g).| < p )

assume A7: n1 <= k ; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
|.((seq1 . m) - g).| < p
take n = k; :: thesis: for m being Nat st n <= m holds
|.((seq1 . m) - g).| < p
let m be Nat; :: thesis: ( n <= m implies |.((seq1 . m) - g).| < p )
assume A8: n <= m ; :: thesis: |.((seq1 . m) - g).| < p
then n1 <= m by A7, XXREAL_0:2;
then |.((seq . m) - g1).| < p by A5;
hence |.((seq1 . m) - g).| < p by A4, A8; :: thesis: verum

end;

now :: thesis: ( k <= n1 implies ex n being Nat st
for m being Nat st n <= m holds
|.((seq1 . m) - g).| < p )

assume A9: k <= n1 ; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
|.((seq1 . m) - g).| < p
take n = n1; :: thesis: for m being Nat st n <= m holds
|.((seq1 . m) - g).| < p
let m be Nat; :: thesis: ( n <= m implies |.((seq1 . m) - g).| < p )
assume A10: n <= m ; :: thesis: |.((seq1 . m) - g).| < p
then seq1 . m = seq . m by A4, A9, XXREAL_0:2;
hence |.((seq1 . m) - g).| < p by A5, A10; :: thesis: verum

end;

hence ex b₁ being set st
for b₂ being set holds
( not b₁ <= b₂ or not p <= |.((seq1 . b₂) - g).| ) by A6; :: thesis: verum