let seq, seq9 be Real_Sequence; :: thesis: ( seq is convergent & seq9 is convergent implies lim (seq + seq9) = (lim seq) + (lim seq9) )
assume that
A1: seq is convergent and
A2: seq9 is convergent ; :: thesis: lim (seq + seq9) = (lim seq) + (lim seq9)

now :: thesis: for p being Real st 0 < p holds
ex k being set st
for m being Nat st k <= m holds
|.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p

let p be Real; :: thesis: ( 0 < p implies ex k being set st
for m being Nat st k <= m holds
|.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p )
assume 0 < p ; :: thesis: ex k being set st
for m being Nat st k <= m holds
|.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p
then A3: 0 < p / 2 ;
then consider n1 being Nat such that
A4: for m being Nat st n1 <= m holds
|.((seq . m) - (lim seq)).| < p / 2 by A1, Def6;
consider n2 being Nat such that
A5: for m being Nat st n2 <= m holds
|.((seq9 . m) - (lim seq9)).| < p / 2 by A2, A3, Def6;
take k = n1 + n2; :: thesis: for m being Nat st k <= m holds
|.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p
let m be Nat; :: thesis: ( k <= m implies |.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p )
assume A6: k <= m ; :: thesis: |.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p
n1 <= n1 + n2 by NAT_1:12;
then n1 <= m by A6, XXREAL_0:2;
then A7: |.((seq . m) - (lim seq)).| < p / 2 by A4;
n2 <= k by NAT_1:12;
then n2 <= m by A6, XXREAL_0:2;
then |.((seq9 . m) - (lim seq9)).| < p / 2 by A5;
then A8: |.((seq . m) - (lim seq)).| + |.((seq9 . m) - (lim seq9)).| < (p / 2) + (p / 2) by A7, XREAL_1:8;
A9: |.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| = |.(((seq . m) + (seq9 . m)) - ((lim seq) + (lim seq9))).| by SEQ_1:7
.= |.(((seq . m) - (lim seq)) + ((seq9 . m) - (lim seq9))).| ;
|.(((seq . m) - (lim seq)) + ((seq9 . m) - (lim seq9))).| <= |.((seq . m) - (lim seq)).| + |.((seq9 . m) - (lim seq9)).| by COMPLEX1:56;
hence |.(((seq + seq9) . m) - ((lim seq) + (lim seq9))).| < p by A8, A9, XXREAL_0:2; :: thesis: verum

end;

hence lim (seq + seq9) = (lim seq) + (lim seq9) by A1, A2, Def6; :: thesis: verum