defpred S₁[ set , set ] means for n, m being Element of NAT st $1 = n & $2 = m holds
( n < m & P₁[F₁() . m] & ( for k being Element of NAT st n < k & P₁[F₁() . k] holds
m <= k ) );
defpred S₂[ set , set , set ] means S₁[$2,$3];
defpred S₃[ set ] means P₁[F₁() . $1];
ex m1 being Element of NAT st
( 0 <= m1 & P₁[F₁() . m1] ) by A1;
then A2: ex m being Nat st S₃[m] ;
consider M being Nat such that
A3: ( S₃[M] & ( for n being Nat st S₃[n] holds
M <= n ) ) from NAT_1:sch 5(A2);
reconsider M9 = M as Element of NAT by ORDINAL1:def 12;

A4: now :: thesis: for n being Element of NAT ex m being Element of NAT st
( n < m & P₁[F₁() . m] )

let n be Element of NAT ; :: thesis: ex m being Element of NAT st
( n < m & P₁[F₁() . m] )
consider m being Element of NAT such that
A5: ( n + 1 <= m & P₁[F₁() . m] ) by A1;
take m = m; :: thesis: ( n < m & P₁[F₁() . m] )
thus ( n < m & P₁[F₁() . m] ) by A5, NAT_1:13; :: thesis: verum

end;

A6: for n being Nat
for x being Element of NAT ex y being Element of NAT st S₂[n,x,y]

proof

let n be Nat; :: thesis: for x being Element of NAT ex y being Element of NAT st S₂[n,x,y]
let x be Element of NAT ; :: thesis: ex y being Element of NAT st S₂[n,x,y]
defpred S₄[ Nat] means ( x < $1 & P₁[F₁() . $1] );
ex m being Element of NAT st S₄[m] by A4;
then A7: ex m being Nat st S₄[m] ;
consider l being Nat such that
A8: ( S₄[l] & ( for k being Nat st S₄[k] holds
l <= k ) ) from NAT_1:sch 5(A7);
reconsider l = l as Element of NAT by ORDINAL1:def 12;
take l ; :: thesis: S₂[n,x,l]
thus S₂[n,x,l] by A8; :: thesis: verum

end;

consider F being sequence of NAT such that
A9: ( F . 0 = M9 & ( for n being Nat holds S₂[n,F . n,F . (n + 1)] ) ) from RECDEF_1:sch 2(A6);
( dom F = NAT & rng F c= REAL ) by FUNCT_2:def 1, NUMBERS:19;
then reconsider F = F as natural-valued Real_Sequence by FUNCT_2:def 1, RELSET_1:4;
for n being Nat holds F . n < F . (n + 1) by A9;
then reconsider F = F as increasing sequence of NAT by SEQM_3:def 6;
A10: for n being Element of NAT st P₁[F₁() . n] holds
ex m being Element of NAT st F . m = n

proof

defpred S₄[ set ] means ( P₁[F₁() . $1] & ( for m being Element of NAT holds F . m <> $1 ) );
assume ex n being Element of NAT st S₄[n] ; :: thesis: contradiction
then A11: ex n being Nat st S₄[n] ;
consider M1 being Nat such that
A12: ( S₄[M1] & ( for n being Nat st S₄[n] holds
M1 <= n ) ) from NAT_1:sch 5(A11);
defpred S₅[ Nat] means ( $1 < M1 & P₁[F₁() . $1] & ex m being Element of NAT st F . m = $1 );
A13: ex n being Nat st S₅[n]

proof

take M ; :: thesis: S₅[M]
( M <= M1 & M <> M1 ) by A3, A9, A12;
hence M < M1 by XXREAL_0:1; :: thesis: ( P₁[F₁() . M] & ex m being Element of NAT st F . m = M )
thus P₁[F₁() . M] by A3; :: thesis: ex m being Element of NAT st F . m = M
take 0 ; :: thesis: F . 0 = M
thus F . 0 = M by A9; :: thesis: verum

end;

A14: for n being Nat st S₅[n] holds
n <= M1 ;
consider X being Nat such that
A15: ( S₅[X] & ( for n being Nat st S₅[n] holds
n <= X ) ) from NAT_1:sch 6(A14, A13);
A16: for k being Element of NAT st X < k & k < M1 holds
not P₁[F₁() . k]

proof

given k being Element of NAT such that A17: X < k and
A18: ( k < M1 & P₁[F₁() . k] ) ; :: thesis: contradiction

now :: thesis: contradiction

per cases ( ex m being Element of NAT st F . m = k or for m being Element of NAT holds F . m <> k ) ;

suppose ex m being Element of NAT st F . m = k ; :: thesis: contradiction

hence contradiction by A15, A17, A18; :: thesis: verum

end;

suppose for m being Element of NAT holds F . m <> k ; :: thesis: contradiction

hence contradiction by A12, A18; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum

end;

consider m being Element of NAT such that
A19: F . m = X by A15;
A20: ( X < F . (m + 1) & P₁[F₁() . (F . (m + 1))] ) by A9, A19;
M1 in NAT by ORDINAL1:def 12;
then A21: F . (m + 1) <= M1 by A9, A12, A15, A19;

now :: thesis: not F . (m + 1) <> M1

assume F . (m + 1) <> M1 ; :: thesis: contradiction
then F . (m + 1) < M1 by A21, XXREAL_0:1;
hence contradiction by A16, A20; :: thesis: verum

end;

hence contradiction by A12; :: thesis: verum

end;

take q = F₁() * F; :: thesis: ( q is subsequence of F₁() & ( for n being Nat holds P₁[q . n] ) & ( for n being Element of NAT st ( for r being Real st r = F₁() . n holds
P₁[r] ) holds
ex m being Element of NAT st F₁() . n = q . m ) )
defpred S₄[ set ] means P₁[q . $1];
A22: for k being Nat st S₄[k] holds
S₄[k + 1]

proof

let k be Nat; :: thesis: ( S₄[k] implies S₄[k + 1] )
assume P₁[q . k] ; :: thesis: S₄[k + 1]
S₁[F . k,F . (k + 1)] by A9;
then P₁[F₁() . (F . (k + 1))] ;
hence S₄[k + 1] by FUNCT_2:15; :: thesis: verum

end;

thus q is subsequence of F₁() ; :: thesis: ( ( for n being Nat holds P₁[q . n] ) & ( for n being Element of NAT st ( for r being Real st r = F₁() . n holds
P₁[r] ) holds
ex m being Element of NAT st F₁() . n = q . m ) )
A23: S₄[ 0 ] by A3, A9, FUNCT_2:15;
thus for n being Nat holds S₄[n] from NAT_1:sch 2(A23, A22); :: thesis: for n being Element of NAT st ( for r being Real st r = F₁() . n holds
P₁[r] ) holds
ex m being Element of NAT st F₁() . n = q . m
let n be Element of NAT ; :: thesis: ( ( for r being Real st r = F₁() . n holds
P₁[r] ) implies ex m being Element of NAT st F₁() . n = q . m )
assume for r being Real st r = F₁() . n holds
P₁[r] ; :: thesis: ex m being Element of NAT st F₁() . n = q . m
then consider m being Element of NAT such that
A24: F . m = n by A10;
take m ; :: thesis: F₁() . n = q . m
thus F₁() . n = q . m by A24, FUNCT_2:15; :: thesis: verum