let R1, R2 be real-valued FinSequence; :: thesis: ( R1,R2 are_fiberwise_equipotent implies Product R1 = Product R2 )
defpred S₁[ Nat] means for f, g being FinSequence of REAL st f,g are_fiberwise_equipotent & len f = $1 holds
Product f = Product g;
assume A1: R1,R2 are_fiberwise_equipotent ; :: thesis: Product R1 = Product R2
A2: len R1 = len R1 ;
A3: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume A4: S₁[n] ; :: thesis: S₁[n + 1]
let f, g be FinSequence of REAL ; :: thesis: ( f,g are_fiberwise_equipotent & len f = n + 1 implies Product f = Product g )
assume that
A5: f,g are_fiberwise_equipotent and
A6: len f = n + 1 ; :: thesis: Product f = Product g
set a = f . (n + 1);
A7: rng f = rng g by A5, CLASSES1:75;
0 + 1 <= n + 1 by NAT_1:13;
then n + 1 in dom f by A6, FINSEQ_3:25;
then f . (n + 1) in rng g by A7, FUNCT_1:def 3;
then consider m being Nat such that
A8: m in dom g and
A9: g . m = f . (n + 1) by FINSEQ_2:10;
set gg = g /^ m;
set gm = g | m;
A11: 1 <= m by A8, FINSEQ_3:25;
max (0,(m - 1)) = m - 1 by FINSEQ_2:4, A8, FINSEQ_3:25;
then reconsider m1 = m - 1 as Element of NAT by FINSEQ_2:5;
m = m1 + 1 ;
then A13: Seg m1 c= Seg m by FINSEQ_1:5, NAT_1:11;
m in Seg m by A11;
then WW: f . (n + 1) = (g | m) . (m1 + 1) by A8, A9, RFINSEQ:6;
m <= len g by A8, FINSEQ_3:25;
then len (g | m) = m by FINSEQ_1:59;
then A14: g | m = ((g | m) | m1) ^ <*(f . (n + 1))*> by WW, RFINSEQ:7;
set fn = f | n;
A15: g = (g | m) ^ (g /^ m) by RFINSEQ:8;
A16: (g | m) | m1 = g | ((Seg m) /\ (Seg m1)) by RELAT_1:71
.= g | m1 by A13, XBOOLE_1:28 ;
A17: f = (f | n) ^ <*(f . (n + 1))*> by A6, RFINSEQ:7;

now :: thesis: for x being object holds card (Coim ((f | n),x)) = card (Coim (((g | m1) ^ (g /^ m)),x))

let x be object ; :: thesis: card (Coim ((f | n),x)) = card (Coim (((g | m1) ^ (g /^ m)),x))
card (Coim (f,x)) = card (Coim (g,x)) by A5;
then (card ((f | n) " {x})) + (card (<*(f . (n + 1))*> " {x})) = card ((((g | m1) ^ <*(f . (n + 1))*>) ^ (g /^ m)) " {x}) by A15, A14, A16, A17, FINSEQ_3:57
.= (card (((g | m1) ^ <*(f . (n + 1))*>) " {x})) + (card ((g /^ m) " {x})) by FINSEQ_3:57
.= ((card ((g | m1) " {x})) + (card (<*(f . (n + 1))*> " {x}))) + (card ((g /^ m) " {x})) by FINSEQ_3:57
.= ((card ((g | m1) " {x})) + (card ((g /^ m) " {x}))) + (card (<*(f . (n + 1))*> " {x}))
.= (card (((g | m1) ^ (g /^ m)) " {x})) + (card (<*(f . (n + 1))*> " {x})) by FINSEQ_3:57 ;
hence card (Coim ((f | n),x)) = card (Coim (((g | m1) ^ (g /^ m)),x)) ; :: thesis: verum

end;

then A18: f | n,(g | m1) ^ (g /^ m) are_fiberwise_equipotent ;
len (f | n) = n by A6, FINSEQ_1:59, NAT_1:11;
then Product (f | n) = Product ((g | m1) ^ (g /^ m)) by A4, A18;
hence Product f = (Product ((g | m1) ^ (g /^ m))) * (Product <*(f . (n + 1))*>) by A17, RVSUM_1:97
.= ((Product (g | m1)) * (Product (g /^ m))) * (Product <*(f . (n + 1))*>) by RVSUM_1:97
.= ((Product (g | m1)) * (Product <*(f . (n + 1))*>)) * (Product (g /^ m))
.= (Product (g | m)) * (Product (g /^ m)) by A14, A16, RVSUM_1:97
.= Product g by A15, RVSUM_1:97 ;
:: thesis: verum

end;

A19: S₁[ 0 ]

proof

let f, g be FinSequence of REAL ; :: thesis: ( f,g are_fiberwise_equipotent & len f = 0 implies Product f = Product g )
assume a: ( f,g are_fiberwise_equipotent & len f = 0 ) ; :: thesis: Product f = Product g
then A20: ( len g = 0 & f = <*> REAL ) by RFINSEQ:3;
g = <*> REAL by RFINSEQ:3, a;
hence Product f = Product g by A20; :: thesis: verum

end;

A4: for n being Nat holds S₁[n] from NAT_1:sch 2(A19, A3);
( R1 is FinSequence of REAL & R2 is FinSequence of REAL ) by RVSUM_1:145;
hence Product R1 = Product R2 by A1, A2, A4; :: thesis: verum