let V be RealUnitarySpace; :: thesis: for W being Subspace of V
for K being Linear_Combination of W ex L being Linear_Combination of V st
( Carrier K = Carrier L & Sum K = Sum L )
let W be Subspace of V; :: thesis: for K being Linear_Combination of W ex L being Linear_Combination of V st
( Carrier K = Carrier L & Sum K = Sum L )
let K be Linear_Combination of W; :: thesis: ex L being Linear_Combination of V st
( Carrier K = Carrier L & Sum K = Sum L )
defpred S₁[ object , object ] means ( ( $1 in W & $2 = K . $1 ) or ( not $1 in W & $2 = 0 ) );
reconsider K9 = K as Function of the carrier of W,REAL ;
A1: the carrier of W c= the carrier of V by RUSUB_1:def 1;
then reconsider C = Carrier K as finite Subset of V by XBOOLE_1:1;
A2: for x being object st x in the carrier of V holds
ex y being object st
( y in REAL & S₁[x,y] )

proof

let x be object ; :: thesis: ( x in the carrier of V implies ex y being object st
( y in REAL & S₁[x,y] ) )
assume x in the carrier of V ; :: thesis: ex y being object st
( y in REAL & S₁[x,y] )
then reconsider x = x as VECTOR of V ;

per cases ( x in W or not x in W ) ;

suppose A3: x in W ; :: thesis: ex y being object st
( y in REAL & S₁[x,y] )

then reconsider x = x as VECTOR of W by STRUCT_0:def 5;
S₁[x,K . x] by A3;
hence ex y being object st
( y in REAL & S₁[x,y] ) ; :: thesis: verum

end;

suppose A4: not x in W ; :: thesis: ex y being object st
( y in REAL & S₁[x,y] )

0 in REAL by XREAL_0:def 1;
hence ex y being object st
( y in REAL & S₁[x,y] ) by A4; :: thesis: verum

end;

end;

end;

ex L being Function of the carrier of V,REAL st
for x being object st x in the carrier of V holds
S₁[x,L . x] from FUNCT_2:sch 1(A2);
then consider L being Function of the carrier of V,REAL such that
A5: for x being object st x in the carrier of V holds
S₁[x,L . x] ;

A6: now :: thesis: for v being VECTOR of V st not v in C holds
L . v = 0

let v be VECTOR of V; :: thesis: ( not v in C implies L . v = 0 )
assume not v in C ; :: thesis: L . v = 0
then ( ( S₁[v,K . v] & not v in C & v in the carrier of W ) or S₁[v, 0 ] ) by STRUCT_0:def 5;
then ( ( S₁[v,K . v] & K . v = 0 ) or S₁[v, 0 ] ) ;
hence L . v = 0 by A5; :: thesis: verum

end;

L is Element of Funcs ( the carrier of V,REAL) by FUNCT_2:8;
then reconsider L = L as Linear_Combination of V by A6, RLVECT_2:def 3;
reconsider L9 = L | the carrier of W as Function of the carrier of W,REAL by A1, FUNCT_2:32;
take L ; :: thesis: ( Carrier K = Carrier L & Sum K = Sum L )

now :: thesis: for x being object st x in Carrier L holds
x in the carrier of W

let x be object ; :: thesis: ( x in Carrier L implies x in the carrier of W )
assume ( x in Carrier L & not x in the carrier of W ) ; :: thesis: contradiction
then ( ex v being VECTOR of V st
( x = v & L . v <> 0 ) & not x in W ) by STRUCT_0:def 5;
hence contradiction by A5; :: thesis: verum

end;

then A7: Carrier L c= the carrier of W ;

now :: thesis: for x being object st x in the carrier of W holds
K9 . x = L9 . x

let x be object ; :: thesis: ( x in the carrier of W implies K9 . x = L9 . x )
assume A8: x in the carrier of W ; :: thesis: K9 . x = L9 . x
then S₁[x,L . x] by A5, A1;
hence K9 . x = L9 . x by A8, FUNCT_1:49, STRUCT_0:def 5; :: thesis: verum

end;

then K9 = L9 by FUNCT_2:12;
hence ( Carrier K = Carrier L & Sum K = Sum L ) by A7, Th18; :: thesis: verum