let V be RealUnitarySpace; :: thesis: for A, B being Subset of V holds Lin (A \/ B) = (Lin A) + (Lin B)
let A, B be Subset of V; :: thesis: Lin (A \/ B) = (Lin A) + (Lin B)

now :: thesis: for v being VECTOR of V st v in Lin (A \/ B) holds
v in (Lin A) + (Lin B)

deffunc H₁( object ) -> Element of omega = 0 ;
let v be VECTOR of V; :: thesis: ( v in Lin (A \/ B) implies v in (Lin A) + (Lin B) )
assume v in Lin (A \/ B) ; :: thesis: v in (Lin A) + (Lin B)
then consider l being Linear_Combination of A \/ B such that
A1: v = Sum l by Th1;
deffunc H₂( object ) -> set = l . $1;
set D = (Carrier l) \ A;
set C = (Carrier l) /\ A;
defpred S₁[ object ] means $1 in (Carrier l) /\ A;
defpred S₂[ object ] means $1 in (Carrier l) \ A;

now :: thesis: for x being set st x in the carrier of V holds
( ( x in (Carrier l) /\ A implies l . x in REAL ) & ( not x in (Carrier l) /\ A implies 0 in REAL ) )

let x be set ; :: thesis: ( x in the carrier of V implies ( ( x in (Carrier l) /\ A implies l . x in REAL ) & ( not x in (Carrier l) /\ A implies 0 in REAL ) ) )
assume x in the carrier of V ; :: thesis: ( ( x in (Carrier l) /\ A implies l . x in REAL ) & ( not x in (Carrier l) /\ A implies 0 in REAL ) )
then reconsider v = x as VECTOR of V ;
for f being Function of the carrier of V,REAL holds f . v in REAL ;
hence ( x in (Carrier l) /\ A implies l . x in REAL ) ; :: thesis: ( not x in (Carrier l) /\ A implies 0 in REAL )
assume not x in (Carrier l) /\ A ; :: thesis: 0 in REAL
thus 0 in REAL by XREAL_0:def 1; :: thesis: verum

end;

then A2: for x being object st x in the carrier of V holds
( ( S₁[x] implies H₂(x) in REAL ) & ( not S₁[x] implies H₁(x) in REAL ) ) ;
consider f being Function of the carrier of V,REAL such that
A3: for x being object st x in the carrier of V holds
( ( S₁[x] implies f . x = H₂(x) ) & ( not S₁[x] implies f . x = H₁(x) ) ) from FUNCT_2:sch 5(A2);
reconsider C = (Carrier l) /\ A as finite Subset of V ;
reconsider f = f as Element of Funcs ( the carrier of V,REAL) by FUNCT_2:8;
for u being VECTOR of V st not u in C holds
f . u = 0 by A3;
then reconsider f = f as Linear_Combination of V by RLVECT_2:def 3;
A4: Carrier f c= C

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier f or x in C )
assume x in Carrier f ; :: thesis: x in C
then A5: ex u being VECTOR of V st
( x = u & f . u <> 0 ) ;
assume not x in C ; :: thesis: contradiction
hence contradiction by A3, A5; :: thesis: verum

end;

C c= A by XBOOLE_1:17;
then Carrier f c= A by A4;
then reconsider f = f as Linear_Combination of A by RLVECT_2:def 6;

now :: thesis: for x being set st x in the carrier of V holds
( ( x in (Carrier l) \ A implies l . x in REAL ) & ( not x in (Carrier l) \ A implies 0 in REAL ) )

let x be set ; :: thesis: ( x in the carrier of V implies ( ( x in (Carrier l) \ A implies l . x in REAL ) & ( not x in (Carrier l) \ A implies 0 in REAL ) ) )
assume x in the carrier of V ; :: thesis: ( ( x in (Carrier l) \ A implies l . x in REAL ) & ( not x in (Carrier l) \ A implies 0 in REAL ) )
then reconsider v = x as VECTOR of V ;
for g being Function of the carrier of V,REAL holds g . v in REAL ;
hence ( x in (Carrier l) \ A implies l . x in REAL ) ; :: thesis: ( not x in (Carrier l) \ A implies 0 in REAL )
assume not x in (Carrier l) \ A ; :: thesis: 0 in REAL
thus 0 in REAL by XREAL_0:def 1; :: thesis: verum

end;

then A6: for x being object st x in the carrier of V holds
( ( S₂[x] implies H₂(x) in REAL ) & ( not S₂[x] implies H₁(x) in REAL ) ) ;
consider g being Function of the carrier of V,REAL such that
A7: for x being object st x in the carrier of V holds
( ( S₂[x] implies g . x = H₂(x) ) & ( not S₂[x] implies g . x = H₁(x) ) ) from FUNCT_2:sch 5(A6);
reconsider D = (Carrier l) \ A as finite Subset of V ;
reconsider g = g as Element of Funcs ( the carrier of V,REAL) by FUNCT_2:8;
for u being VECTOR of V st not u in D holds
g . u = 0 by A7;
then reconsider g = g as Linear_Combination of V by RLVECT_2:def 3;
A8: D c= B

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in D or x in B )
assume x in D ; :: thesis: x in B
then A9: ( x in Carrier l & not x in A ) by XBOOLE_0:def 5;
Carrier l c= A \/ B by RLVECT_2:def 6;
hence x in B by A9, XBOOLE_0:def 3; :: thesis: verum

end;

Carrier g c= D

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier g or x in D )
assume x in Carrier g ; :: thesis: x in D
then A10: ex u being VECTOR of V st
( x = u & g . u <> 0 ) ;
assume not x in D ; :: thesis: contradiction
hence contradiction by A7, A10; :: thesis: verum

end;

then Carrier g c= B by A8;
then reconsider g = g as Linear_Combination of B by RLVECT_2:def 6;
l = f + g

proof

let v be VECTOR of V; :: according to RLVECT_2:def 9 :: thesis: l . v = (f + g) . v

now :: thesis: (f + g) . v = l . v

per cases ( v in C or not v in C ) ;

suppose A11: v in C ; :: thesis: (f + g) . v = l . v

A12: now :: thesis: not v in D

assume v in D ; :: thesis: contradiction
then not v in A by XBOOLE_0:def 5;
hence contradiction by A11, XBOOLE_0:def 4; :: thesis: verum

end;

thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 10
.= (l . v) + (g . v) by A3, A11
.= (l . v) + 0 by A7, A12
.= l . v ; :: thesis: verum

end;

suppose A13: not v in C ; :: thesis: l . v = (f + g) . v

now :: thesis: (f + g) . v = l . v

per cases ( v in Carrier l or not v in Carrier l ) ;

suppose A14: v in Carrier l ; :: thesis: (f + g) . v = l . v

A15: now :: thesis: v in D

assume not v in D ; :: thesis: contradiction
then ( not v in Carrier l or v in A ) by XBOOLE_0:def 5;
hence contradiction by A13, A14, XBOOLE_0:def 4; :: thesis: verum

end;

thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 10
.= 0 + (g . v) by A3, A13
.= l . v by A7, A15 ; :: thesis: verum

end;

suppose A16: not v in Carrier l ; :: thesis: (f + g) . v = l . v

then A17: not v in D by XBOOLE_0:def 5;
A18: not v in C by A16, XBOOLE_0:def 4;
thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 10
.= 0 + (g . v) by A3, A18
.= 0 + 0 by A7, A17
.= l . v by A16 ; :: thesis: verum

end;

end;

end;

hence l . v = (f + g) . v ; :: thesis: verum

end;

end;

end;

hence l . v = (f + g) . v ; :: thesis: verum

end;

then A19: v = (Sum f) + (Sum g) by A1, RLVECT_3:1;
( Sum f in Lin A & Sum g in Lin B ) by Th1;
hence v in (Lin A) + (Lin B) by A19, RUSUB_2:1; :: thesis: verum

end;

then A20: Lin (A \/ B) is Subspace of (Lin A) + (Lin B) by RUSUB_1:23;
( Lin A is Subspace of Lin (A \/ B) & Lin B is Subspace of Lin (A \/ B) ) by Th7, XBOOLE_1:7;
then (Lin A) + (Lin B) is Subspace of Lin (A \/ B) by Lm5;
hence Lin (A \/ B) = (Lin A) + (Lin B) by A20, RUSUB_1:20; :: thesis: verum