let X be non empty set ; :: thesis:
let Y be RealNormSpace; :: thesis:
assume A1: Y is complete ; :: thesis:
let vseq be sequence of (R_NormSpace_of_BoundedFunctions (X,Y)); :: thesis:
assume A2: vseq is Cauchy_sequence_by_Norm ; :: thesis:
defpred S₁[ set , set ] means ex xseq being sequence of Y st
( ( for n being Nat holds xseq . n = (modetrans ((vseq . n),X,Y)) . $1 ) & xseq is convergent & $2 = lim xseq );
A3: for x being Element of X ex y being Element of Y st S₁[x,y]

proof

let x be Element of X; :: thesis:
deffunc H₁( Nat) -> Element of the carrier of Y = (modetrans ((vseq . $1),X,Y)) . x;
consider xseq being sequence of Y such that
A4: for n being Element of NAT holds xseq . n = H₁(n) from FUNCT_2:sch 4();
A5: for n being Nat holds xseq . n = H₁(n)

proof

let n be Nat; :: thesis:
n in NAT by ORDINAL1:def 12;
hence xseq . n = H₁(n) by A4; :: thesis:

end;

take lim xseq ; :: thesis:
A6: for m, k being Nat holds ||.((xseq . m) - (xseq . k)).|| <= ||.((vseq . m) - (vseq . k)).||

proof

let m, k be Nat; :: thesis:
vseq . k is bounded Function of X, the carrier of Y by Def5;
then A7: modetrans ((vseq . k),X,Y) = vseq . k by Th13;
reconsider h1 = (vseq . m) - (vseq . k) as bounded Function of X, the carrier of Y by Def5;
vseq . m is bounded Function of X, the carrier of Y by Def5;
then A8: modetrans ((vseq . m),X,Y) = vseq . m by Th13;
( m in NAT & k in NAT ) by ORDINAL1:def 12;
then ( xseq . m = (modetrans ((vseq . m),X,Y)) . x & xseq . k = (modetrans ((vseq . k),X,Y)) . x ) by A4;
then (xseq . m) - (xseq . k) = h1 . x by A8, A7, Th24;
hence ||.((xseq . m) - (xseq . k)).|| <= ||.((vseq . m) - (vseq . k)).|| by Th16; :: thesis:

end;

now :: thesis:

let e be Real; :: thesis:
assume A9: e > 0 ; :: thesis:
thus ex k being Nat st
for n, m being Nat st n >= k & m >= k holds
||.((xseq . n) - (xseq . m)).|| < e :: thesis:

proof

consider k being Nat such that
A10: for n, m being Nat st n >= k & m >= k holds
||.((vseq . n) - (vseq . m)).|| < e by A2, A9, RSSPACE3:8;
take k ; :: thesis:
thus for n, m being Nat st n >= k & m >= k holds
||.((xseq . n) - (xseq . m)).|| < e :: thesis:

proof

let n, m be Nat; :: thesis:
assume ( n >= k & m >= k ) ; :: thesis:
then A11: ||.((vseq . n) - (vseq . m)).|| < e by A10;
||.((xseq . n) - (xseq . m)).|| <= ||.((vseq . n) - (vseq . m)).|| by A6;
hence ||.((xseq . n) - (xseq . m)).|| < e by A11, XXREAL_0:2; :: thesis:

end;

then xseq is Cauchy_sequence_by_Norm by RSSPACE3:8;
then xseq is convergent by A1, LOPBAN_1:def 15;
hence S₁[x, lim xseq] by A5; :: thesis:

end;

consider f being Function of X, the carrier of Y such that
A12: for x being Element of X holds S₁[x,f . x] from FUNCT_2:sch 3(A3);
reconsider tseq = f as Function of X, the carrier of Y ;

now :: thesis:

let e1 be Real; :: thesis:
assume A13: e1 > 0 ; :: thesis:
reconsider e = e1 as Real ;
consider k being Nat such that
A14: for n, m being Nat st n >= k & m >= k holds
||.((vseq . n) - (vseq . m)).|| < e by A2, A13, RSSPACE3:8;
take k = k; :: thesis:

now :: thesis:

let m be Nat; :: thesis:
assume m >= k ; :: thesis:
then A15: ( ||.(vseq . m).|| = ||.vseq.|| . m & ||.((vseq . m) - (vseq . k)).|| < e ) by A14, NORMSP_0:def 4;
( |.(||.(vseq . m).|| - ||.(vseq . k).||).| <= ||.((vseq . m) - (vseq . k)).|| & ||.(vseq . k).|| = ||.vseq.|| . k ) by NORMSP_0:def 4, NORMSP_1:9;
hence |.((||.vseq.|| . m) - (||.vseq.|| . k)).| < e1 by A15, XXREAL_0:2; :: thesis:

end;

hence for m being Nat st m >= k holds
|.((||.vseq.|| . m) - (||.vseq.|| . k)).| < e1 ; :: thesis:

end;

then A16: ||.vseq.|| is convergent by SEQ_4:41;
A17: tseq is bounded

proof

reconsider lv = lim ||.vseq.|| as Real ;
take lv ; :: according to RSSPACE4:def 4 :: thesis:

A18: now :: thesis:

let x be Element of X; :: thesis:
consider xseq being sequence of Y such that
A19: for n being Nat holds xseq . n = (modetrans ((vseq . n),X,Y)) . x and
A20: ( xseq is convergent & tseq . x = lim xseq ) by A12;
A21: for m being Nat holds ||.(xseq . m).|| <= ||.(vseq . m).||

proof

let m be Nat; :: thesis:
( vseq . m is bounded Function of X, the carrier of Y & xseq . m = (modetrans ((vseq . m),X,Y)) . x ) by A19, Def5;
hence ||.(xseq . m).|| <= ||.(vseq . m).|| by Th13, Th16; :: thesis:

end;

A22: for n being Nat holds ||.xseq.|| . n <= ||.vseq.|| . n

proof

let n be Nat; :: thesis:
( ||.xseq.|| . n = ||.(xseq . n).|| & ||.(xseq . n).|| <= ||.(vseq . n).|| ) by A21, NORMSP_0:def 4;
hence ||.xseq.|| . n <= ||.vseq.|| . n by NORMSP_0:def 4; :: thesis:

end;

( ||.xseq.|| is convergent & ||.(tseq . x).|| = lim ||.xseq.|| ) by A20, LOPBAN_1:41;
hence ||.(tseq . x).|| <= lim ||.vseq.|| by A16, A22, SEQ_2:18; :: thesis:

end;

now :: thesis:

let n be Nat; :: thesis:
||.(vseq . n).|| >= 0 ;
hence ||.vseq.|| . n >= 0 by NORMSP_0:def 4; :: thesis:

end;

hence ( 0 <= lv & ( for x being Element of X holds ||.(tseq . x).|| <= lv ) ) by A16, A18, SEQ_2:17; :: thesis:

end;

A23: for e being Real st e > 0 holds
ex k being Nat st
for n being Nat st n >= k holds
for x being Element of X holds ||.(((modetrans ((vseq . n),X,Y)) . x) - (tseq . x)).|| <= e

proof

let e be Real; :: thesis:
assume e > 0 ; :: thesis:
then consider k being Nat such that
A24: for n, m being Nat st n >= k & m >= k holds
||.((vseq . n) - (vseq . m)).|| < e by A2, RSSPACE3:8;
take k ; :: thesis:

now :: thesis:

let n be Nat; :: thesis:
assume A25: n >= k ; :: thesis:

now :: thesis:

let x be Element of X; :: thesis:
consider xseq being sequence of Y such that
A26: for n being Nat holds xseq . n = (modetrans ((vseq . n),X,Y)) . x and
A27: ( xseq is convergent & tseq . x = lim xseq ) by A12;
A28: for m, k being Nat holds ||.((xseq . m) - (xseq . k)).|| <= ||.((vseq . m) - (vseq . k)).||

proof

let m, k be Nat; :: thesis:
vseq . k is bounded Function of X, the carrier of Y by Def5;
then A29: modetrans ((vseq . k),X,Y) = vseq . k by Th13;
reconsider h1 = (vseq . m) - (vseq . k) as bounded Function of X, the carrier of Y by Def5;
vseq . m is bounded Function of X, the carrier of Y by Def5;
then A30: modetrans ((vseq . m),X,Y) = vseq . m by Th13;
( xseq . m = (modetrans ((vseq . m),X,Y)) . x & xseq . k = (modetrans ((vseq . k),X,Y)) . x ) by A26;
then (xseq . m) - (xseq . k) = h1 . x by A30, A29, Th24;
hence ||.((xseq . m) - (xseq . k)).|| <= ||.((vseq . m) - (vseq . k)).|| by Th16; :: thesis:

end;

A31: for m being Nat st m >= k holds
||.((xseq . n) - (xseq . m)).|| <= e

proof

let m be Nat; :: thesis:
assume m >= k ; :: thesis:
then A32: ||.((vseq . n) - (vseq . m)).|| < e by A24, A25;
||.((xseq . n) - (xseq . m)).|| <= ||.((vseq . n) - (vseq . m)).|| by A28;
hence ||.((xseq . n) - (xseq . m)).|| <= e by A32, XXREAL_0:2; :: thesis:

end;

||.((xseq . n) - (tseq . x)).|| <= e

proof

deffunc H₁( Nat) -> object = ||.((xseq . $1) - (xseq . n)).||;
consider rseq being Real_Sequence such that
A33: for m being Nat holds rseq . m = H₁(m) from SEQ_1:sch 1();

now :: thesis:

let x be object ; :: thesis:
assume x in NAT ; :: thesis:
then reconsider k = x as Nat ;
thus rseq . x = ||.((xseq . k) - (xseq . n)).|| by A33
.= ||.((xseq - (xseq . n)) . k).|| by NORMSP_1:def 4
.= ||.(xseq - (xseq . n)).|| . x by NORMSP_0:def 4 ; :: thesis:

end;

then A34: rseq = ||.(xseq - (xseq . n)).|| by FUNCT_2:12;
A35: ( xseq - (xseq . n) is convergent & lim (xseq - (xseq . n)) = (tseq . x) - (xseq . n) ) by A27, NORMSP_1:21, NORMSP_1:27;
then A36: lim rseq = ||.((tseq . x) - (xseq . n)).|| by A34, LOPBAN_1:20;
for m being Nat st m >= k holds
rseq . m <= e

proof

let m be Nat; :: thesis:
assume A37: m >= k ; :: thesis:
rseq . m = ||.((xseq . m) - (xseq . n)).|| by A33
.= ||.((xseq . n) - (xseq . m)).|| by NORMSP_1:7 ;
hence rseq . m <= e by A31, A37; :: thesis:

end;

then lim rseq <= e by A35, A34, Lm7, LOPBAN_1:20;
hence ||.((xseq . n) - (tseq . x)).|| <= e by A36, NORMSP_1:7; :: thesis:

end;

hence ||.(((modetrans ((vseq . n),X,Y)) . x) - (tseq . x)).|| <= e by A26; :: thesis:

end;

hence for x being Element of X holds ||.(((modetrans ((vseq . n),X,Y)) . x) - (tseq . x)).|| <= e ; :: thesis:

end;

hence for n being Nat st n >= k holds
for x being Element of X holds ||.(((modetrans ((vseq . n),X,Y)) . x) - (tseq . x)).|| <= e ; :: thesis:

end;

reconsider tseq = tseq as bounded Function of X, the carrier of Y by A17;
reconsider tv = tseq as Point of (R_NormSpace_of_BoundedFunctions (X,Y)) by Def5;
A38: for e being Real st e > 0 holds
ex k being Nat st
for n being Nat st n >= k holds
||.((vseq . n) - tv).|| <= e

proof

let e be Real; :: thesis:
assume e > 0 ; :: thesis:
then consider k being Nat such that
A39: for n being Nat st n >= k holds
for x being Element of X holds ||.(((modetrans ((vseq . n),X,Y)) . x) - (tseq . x)).|| <= e by A23;

now :: thesis:

set g1 = tseq;
let n be Nat; :: thesis:
assume A40: n >= k ; :: thesis:
reconsider h1 = (vseq . n) - tv as bounded Function of X, the carrier of Y by Def5;
set f1 = modetrans ((vseq . n),X,Y);

A41: now :: thesis:

let t be Element of X; :: thesis:
vseq . n is bounded Function of X, the carrier of Y by Def5;
then modetrans ((vseq . n),X,Y) = vseq . n by Th13;
then ||.(h1 . t).|| = ||.(((modetrans ((vseq . n),X,Y)) . t) - (tseq . t)).|| by Th24;
hence ||.(h1 . t).|| <= e by A39, A40; :: thesis:

end;

A42: now :: thesis:

let r be Real; :: thesis:
assume r in PreNorms h1 ; :: thesis:
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= e by A41; :: thesis:

end;

( ( for s being Real st s in PreNorms h1 holds
s <= e ) implies upper_bound (PreNorms h1) <= e ) by SEQ_4:45;
hence ||.((vseq . n) - tv).|| <= e by A42, Th14; :: thesis:

end;

hence ex k being Nat st
for n being Nat st n >= k holds
||.((vseq . n) - tv).|| <= e ; :: thesis:

end;

for e being Real st e > 0 holds
ex m being Nat st
for n being Nat st n >= m holds
||.((vseq . n) - tv).|| < e

proof

let e be Real; :: thesis:
assume A43: e > 0 ; :: thesis:
reconsider ee = e as Real ;
consider m being Nat such that
A44: for n being Nat st n >= m holds
||.((vseq . n) - tv).|| <= ee / 2 by A38, A43, XREAL_1:215;
A45: e / 2 < e by A43, XREAL_1:216;

now :: thesis:

let n be Nat; :: thesis:
assume n >= m ; :: thesis:
then ||.((vseq . n) - tv).|| <= e / 2 by A44;
hence ||.((vseq . n) - tv).|| < e by A45, XXREAL_0:2; :: thesis:

end;

hence ex m being Nat st
for n being Nat st n >= m holds
||.((vseq . n) - tv).|| < e ; :: thesis:

end;

hence vseq is convergent ; :: thesis: