let X be non empty set ; :: thesis: for Y being RealNormSpace
for f, g being Point of (R_NormSpace_of_BoundedFunctions (X,Y))
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let Y be RealNormSpace; :: thesis: for f, g being Point of (R_NormSpace_of_BoundedFunctions (X,Y))
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (R_NormSpace_of_BoundedFunctions (X,Y)); :: thesis: for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let a be Real; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )

A1: now :: thesis: ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 )

assume A2: f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum

proof

reconsider g = f as bounded Function of X, the carrier of Y by Def5;
set z = X --> (0. Y);
reconsider z = X --> (0. Y) as Function of X, the carrier of Y ;
consider r0 being object such that
A3: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A3;
A4: ( ( for s being Real st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
A5: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th11;
A6: z = g by A2, Th15;

A7: now :: thesis: for r being Real st r in PreNorms g holds
( 0 <= r & r <= 0 )

let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being Element of X such that
A8: r = ||.(g . t).|| ;
||.(g . t).|| = ||.(0. Y).|| by A6, FUNCOP_1:7
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A8; :: thesis: verum

end;

then 0 <= r0 by A3;
then upper_bound (PreNorms g) = 0 by A7, A5, A3, A4, SEQ_4:def 1;
hence ||.f.|| = 0 by Th14; :: thesis: verum

end;

end;

A9: ||.(f + g).|| <= ||.f.|| + ||.g.||

proof

reconsider f1 = f, g1 = g, h1 = f + g as bounded Function of X, the carrier of Y by Def5;

A10: now :: thesis: for t being Element of X holds ||.(h1 . t).|| <= ||.f.|| + ||.g.||

let t be Element of X; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
( ||.(f1 . t).|| <= ||.f.|| & ||.(g1 . t).|| <= ||.g.|| ) by Th16;
then A11: ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by XREAL_1:7;
( ||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| & ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| ) by Th19, NORMSP_1:def 1;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A11, XXREAL_0:2; :: thesis: verum

end;

A12: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= ||.f.|| + ||.g.||

let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= ||.f.|| + ||.g.|| by A10; :: thesis: verum

end;

( ( for s being Real st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies upper_bound (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:45;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A12, Th14; :: thesis: verum

end;

A13: ||.(a * f).|| = |.a.| * ||.f.||

proof

reconsider f1 = f, h1 = a * f as bounded Function of X, the carrier of Y by Def5;
A14: ( ( for s being Real st s in PreNorms h1 holds
s <= |.a.| * ||.f.|| ) implies upper_bound (PreNorms h1) <= |.a.| * ||.f.|| ) by SEQ_4:45;

A15: now :: thesis: for t being Element of X holds ||.(h1 . t).|| <= |.a.| * ||.f.||

let t be Element of X; :: thesis: ||.(h1 . t).|| <= |.a.| * ||.f.||
A16: 0 <= |.a.| by COMPLEX1:46;
( ||.(h1 . t).|| = ||.(a * (f1 . t)).|| & ||.(a * (f1 . t)).|| = |.a.| * ||.(f1 . t).|| ) by Th20, NORMSP_1:def 1;
hence ||.(h1 . t).|| <= |.a.| * ||.f.|| by A16, Th16, XREAL_1:64; :: thesis: verum

end;

A17: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= |.a.| * ||.f.||

let r be Real; :: thesis: ( r in PreNorms h1 implies r <= |.a.| * ||.f.|| )
assume r in PreNorms h1 ; :: thesis: r <= |.a.| * ||.f.||
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= |.a.| * ||.f.|| by A15; :: thesis: verum

end;

A18: now :: thesis: ( ( a <> 0 & |.a.| * ||.f.|| <= ||.(a * f).|| ) or ( a = 0 & |.a.| * ||.f.|| = ||.(a * f).|| ) )

per cases ( a <> 0 or a = 0 ) ;

case A19: a <> 0 ; :: thesis: |.a.| * ||.f.|| <= ||.(a * f).||

A20: now :: thesis: for t being Element of X holds ||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).||

let t be Element of X; :: thesis: ||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).||
A21: |.(a ").| = |.(1 * (a ")).|
.= |.(1 / a).| by XCMPLX_0:def 9
.= 1 / |.a.| by ABSVALUE:7
.= 1 * (|.a.| ") by XCMPLX_0:def 9
.= |.a.| " ;
h1 . t = a * (f1 . t) by Th20;
then A22: (a ") * (h1 . t) = ((a ") * a) * (f1 . t) by RLVECT_1:def 7
.= 1 * (f1 . t) by A19, XCMPLX_0:def 7
.= f1 . t by RLVECT_1:def 8 ;
( ||.((a ") * (h1 . t)).|| = |.(a ").| * ||.(h1 . t).|| & 0 <= |.(a ").| ) by COMPLEX1:46, NORMSP_1:def 1;
hence ||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).|| by A22, A21, Th16, XREAL_1:64; :: thesis: verum

end;

A23: now :: thesis: for r being Real st r in PreNorms f1 holds
r <= (|.a.| ") * ||.(a * f).||

let r be Real; :: thesis: ( r in PreNorms f1 implies r <= (|.a.| ") * ||.(a * f).|| )
assume r in PreNorms f1 ; :: thesis: r <= (|.a.| ") * ||.(a * f).||
then ex t being Element of X st r = ||.(f1 . t).|| ;
hence r <= (|.a.| ") * ||.(a * f).|| by A20; :: thesis: verum

end;

A24: ( ( for s being Real st s in PreNorms f1 holds
s <= (|.a.| ") * ||.(a * f).|| ) implies upper_bound (PreNorms f1) <= (|.a.| ") * ||.(a * f).|| ) by SEQ_4:45;
( (BoundedFunctionsNorm (X,Y)) . f = upper_bound (PreNorms f1) & 0 <= |.a.| ) by Th14, COMPLEX1:46;
then |.a.| * ||.f.|| <= |.a.| * ((|.a.| ") * ||.(a * f).||) by A23, A24, XREAL_1:64;
then A25: |.a.| * ||.f.|| <= (|.a.| * (|.a.| ")) * ||.(a * f).|| ;
|.a.| <> 0 by A19, COMPLEX1:47;
then |.a.| * ||.f.|| <= 1 * ||.(a * f).|| by A25, XCMPLX_0:def 7;
hence |.a.| * ||.f.|| <= ||.(a * f).|| ; :: thesis: verum

end;

case A26: a = 0 ; :: thesis: |.a.| * ||.f.|| = ||.(a * f).||

reconsider fz = f as VECTOR of (R_VectorSpace_of_BoundedFunctions (X,Y)) ;
A27: a * f = a * fz
.= 0. (R_VectorSpace_of_BoundedFunctions (X,Y)) by A26, RLVECT_1:10
.= 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ;
thus |.a.| * ||.f.|| = 0 * ||.f.|| by A26, ABSVALUE:2
.= ||.(a * f).|| by A27, Th18 ; :: thesis: verum

end;

end;

end;

(BoundedFunctionsNorm (X,Y)) . (a * f) = upper_bound (PreNorms h1) by Th14;
hence ||.(a * f).|| = |.a.| * ||.f.|| by A17, A14, A18, XXREAL_0:1; :: thesis: verum

end;

now :: thesis: ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) )

reconsider g = f as bounded Function of X, the carrier of Y by Def5;
set z = X --> (0. Y);
reconsider z = X --> (0. Y) as Function of X, the carrier of Y ;
assume A28: ||.f.|| = 0 ; :: thesis: f = 0. (R_NormSpace_of_BoundedFunctions (X,Y))

now :: thesis: for t being Element of X holds g . t = z . t

let t be Element of X; :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| by Th16;
then ||.(g . t).|| = 0 by A28;
hence g . t = 0. Y by NORMSP_0:def 5
.= z . t by FUNCOP_1:7 ;
:: thesis: verum

end;

then g = z by FUNCT_2:63;
hence f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) by Th15; :: thesis: verum

end;

hence ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A1, A13, A9; :: thesis: verum