let R be Ring; :: thesis: for V being RightMod of R
for v being Vector of V
for W being Submodule of V holds
( v in W iff v + W = the carrier of W )
let V be RightMod of R; :: thesis: for v being Vector of V
for W being Submodule of V holds
( v in W iff v + W = the carrier of W )
let v be Vector of V; :: thesis: for W being Submodule of V holds
( v in W iff v + W = the carrier of W )
let W be Submodule of V; :: thesis: ( v in W iff v + W = the carrier of W )
( 0. V in W & v + (0. V) = v ) by Th17, RLVECT_1:def 4;
then A1: v in { (v + u) where u is Vector of V : u in W } ;
thus ( v in W implies v + W = the carrier of W ) :: thesis: ( v + W = the carrier of W implies v in W )

proof

assume A2: v in W ; :: thesis: v + W = the carrier of W
thus v + W c= the carrier of W :: according to XBOOLE_0:def 10 :: thesis: the carrier of W c= v + W

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in v + W or x in the carrier of W )
assume x in v + W ; :: thesis: x in the carrier of W
then consider u being Vector of V such that
A3: x = v + u and
A4: u in W ;
v + u in W by A2, A4, Th20;
hence x in the carrier of W by A3; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in the carrier of W or x in v + W )
assume x in the carrier of W ; :: thesis: x in v + W
then reconsider y = x, z = v as Element of W by A2;
reconsider y1 = y, z1 = z as Vector of V by Th10;
A5: z + (y - z) = y + (z + (- z)) by RLVECT_1:def 3
.= y + (0. W) by VECTSP_1:19
.= x by RLVECT_1:def 4 ;
y - z in W ;
then A6: y1 - z1 in W by Th16;
y - z = y1 - z1 by Th16;
then z1 + (y1 - z1) = x by A5, Th13;
hence x in v + W by A6; :: thesis: verum

end;

assume A7: v + W = the carrier of W ; :: thesis: v in W
assume not v in W ; :: thesis: contradiction
hence contradiction by A7, A1; :: thesis: verum