let X, Y be RealNormSpace; :: thesis: ex I being Function of [:X,Y:],[:X,(product <*Y*>):] st
( I is one-to-one & I is onto & ( for x being Point of X
for y being Point of Y holds I . (x,y) = [x,<*y*>] ) & ( for v, w being Point of [:X,Y:] holds I . (v + w) = (I . v) + (I . w) ) & ( for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) ) & I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )
consider J being Function of Y,(product <*Y*>) such that
A1: ( J is one-to-one & J is onto & ( for y being Point of Y holds J . y = <*y*> ) & ( for v, w being Point of Y holds J . (v + w) = (J . v) + (J . w) ) & ( for v being Point of Y
for r being Element of REAL holds J . (r * v) = r * (J . v) ) & J . (0. Y) = 0. (product <*Y*>) & ( for v being Point of Y holds ||.(J . v).|| = ||.v.|| ) ) by Th16;
defpred S₁[ object , object , object ] means $3 = [$1,<*$2*>];
A2: for x, y being object st x in the carrier of X & y in the carrier of Y holds
ex z being object st
( z in the carrier of [:X,(product <*Y*>):] & S₁[x,y,z] )

proof

let x, y be object ; :: thesis: ( x in the carrier of X & y in the carrier of Y implies ex z being object st
( z in the carrier of [:X,(product <*Y*>):] & S₁[x,y,z] ) )
assume A3: ( x in the carrier of X & y in the carrier of Y ) ; :: thesis: ex z being object st
( z in the carrier of [:X,(product <*Y*>):] & S₁[x,y,z] )
then reconsider y0 = y as Point of Y ;
J . y0 = <*y0*> by A1;
then [x,<*y*>] in [: the carrier of X, the carrier of (product <*Y*>):] by A3, ZFMISC_1:87;
hence ex z being object st
( z in the carrier of [:X,(product <*Y*>):] & S₁[x,y,z] ) ; :: thesis: verum

end;

consider I being Function of [: the carrier of X, the carrier of Y:], the carrier of [:X,(product <*Y*>):] such that
A4: for x, y being object st x in the carrier of X & y in the carrier of Y holds
S₁[x,y,I . (x,y)] from BINOP_1:sch 1(A2);
reconsider I = I as Function of [:X,Y:],[:X,(product <*Y*>):] ;
take I ; :: thesis: ( I is one-to-one & I is onto & ( for x being Point of X
for y being Point of Y holds I . (x,y) = [x,<*y*>] ) & ( for v, w being Point of [:X,Y:] holds I . (v + w) = (I . v) + (I . w) ) & ( for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) ) & I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )
thus I is one-to-one :: thesis: ( I is onto & ( for x being Point of X
for y being Point of Y holds I . (x,y) = [x,<*y*>] ) & ( for v, w being Point of [:X,Y:] holds I . (v + w) = (I . v) + (I . w) ) & ( for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) ) & I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )

proof

now :: thesis: for z1, z2 being object st z1 in the carrier of [:X,Y:] & z2 in the carrier of [:X,Y:] & I . z1 = I . z2 holds
z1 = z2

let z1, z2 be object ; :: thesis: ( z1 in the carrier of [:X,Y:] & z2 in the carrier of [:X,Y:] & I . z1 = I . z2 implies z1 = z2 )
assume A5: ( z1 in the carrier of [:X,Y:] & z2 in the carrier of [:X,Y:] & I . z1 = I . z2 ) ; :: thesis: z1 = z2
then consider x1, y1 being object such that
A6: ( x1 in the carrier of X & y1 in the carrier of Y & z1 = [x1,y1] ) by ZFMISC_1:def 2;
consider x2, y2 being object such that
A7: ( x2 in the carrier of X & y2 in the carrier of Y & z2 = [x2,y2] ) by A5, ZFMISC_1:def 2;
A8: [x1,<*y1*>] = I . (x1,y1) by A4, A6
.= I . (x2,y2) by A5, A6, A7
.= [x2,<*y2*>] by A4, A7 ;
then <*y1*> = <*y2*> by XTUPLE_0:1;
then y1 = y2 by FINSEQ_1:76;
hence z1 = z2 by A6, A7, A8, XTUPLE_0:1; :: thesis: verum

end;

hence I is one-to-one by FUNCT_2:19; :: thesis: verum

end;

thus I is onto :: thesis: ( ( for x being Point of X
for y being Point of Y holds I . (x,y) = [x,<*y*>] ) & ( for v, w being Point of [:X,Y:] holds I . (v + w) = (I . v) + (I . w) ) & ( for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) ) & I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )

proof

now :: thesis: for w being object st w in the carrier of [:X,(product <*Y*>):] holds
w in rng I

let w be object ; :: thesis: ( w in the carrier of [:X,(product <*Y*>):] implies w in rng I )
assume w in the carrier of [:X,(product <*Y*>):] ; :: thesis: w in rng I
then consider x, y1 being object such that
A9: ( x in the carrier of X & y1 in the carrier of (product <*Y*>) & w = [x,y1] ) by ZFMISC_1:def 2;
y1 in rng J by A1, A9, FUNCT_2:def 3;
then consider y being object such that
A10: ( y in the carrier of Y & y1 = J . y ) by FUNCT_2:11;
A11: J . y = <*y*> by A10, A1;
reconsider z = [x,y] as Element of [: the carrier of X, the carrier of Y:] by A9, A10, ZFMISC_1:87;
w = I . (x,y) by A4, A9, A10, A11
.= I . z ;
hence w in rng I by FUNCT_2:4; :: thesis: verum

end;

then the carrier of [:X,(product <*Y*>):] c= rng I by TARSKI:def 3;
then the carrier of [:X,(product <*Y*>):] = rng I by XBOOLE_0:def 10;
hence I is onto by FUNCT_2:def 3; :: thesis: verum

end;

thus for x being Point of X
for y being Point of Y holds I . (x,y) = [x,<*y*>] by A4; :: thesis: ( ( for v, w being Point of [:X,Y:] holds I . (v + w) = (I . v) + (I . w) ) & ( for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) ) & I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )
thus for v, w being Point of [:X,Y:] holds I . (v + w) = (I . v) + (I . w) :: thesis: ( ( for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) ) & I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )

proof

let v, w be Point of [:X,Y:]; :: thesis: I . (v + w) = (I . v) + (I . w)
consider x1 being Point of X, x2 being Point of Y such that
A12: v = [x1,x2] by Lm1;
consider y1 being Point of X, y2 being Point of Y such that
A13: w = [y1,y2] by Lm1;
A14: I . (v + w) = I . ((x1 + y1),(x2 + y2)) by A12, A13, Def1
.= [(x1 + y1),<*(x2 + y2)*>] by A4 ;
( I . v = I . (x1,x2) & I . w = I . (y1,y2) ) by A12, A13;
then A15: ( I . v = [x1,<*x2*>] & I . w = [y1,<*y2*>] ) by A4;
A16: ( J . x2 = <*x2*> & J . y2 = <*y2*> ) by A1;
then reconsider xx2 = <*x2*> as Point of (product <*Y*>) ;
reconsider yy2 = <*y2*> as Point of (product <*Y*>) by A16;
<*(x2 + y2)*> = J . (x2 + y2) by A1
.= xx2 + yy2 by A16, A1 ;
hence (I . v) + (I . w) = I . (v + w) by A14, A15, Def1; :: thesis: verum

end;

thus for v being Point of [:X,Y:]
for r being Element of REAL holds I . (r * v) = r * (I . v) :: thesis: ( I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] & ( for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| ) )

proof

let v be Point of [:X,Y:]; :: thesis: for r being Element of REAL holds I . (r * v) = r * (I . v)
let r be Element of REAL ; :: thesis: I . (r * v) = r * (I . v)
consider x1 being Point of X, x2 being Point of Y such that
A17: v = [x1,x2] by Lm1;
A18: I . (r * v) = I . ((r * x1),(r * x2)) by A17, Th18
.= [(r * x1),<*(r * x2)*>] by A4 ;
A19: I . v = I . (x1,x2) by A17
.= [x1,<*x2*>] by A4 ;
A20: J . x2 = <*x2*> by A1;
then reconsider xx2 = <*x2*> as Point of (product <*Y*>) ;
<*(r * x2)*> = J . (r * x2) by A1
.= r * xx2 by A20, A1 ;
hence r * (I . v) = I . (r * v) by A18, A19, Th18; :: thesis: verum

end;

A21: <*(0. Y)*> = 0. (product <*Y*>) by A1;
I . (0. [:X,Y:]) = I . ((0. X),(0. Y)) ;
hence I . (0. [:X,Y:]) = 0. [:X,(product <*Y*>):] by A21, A4; :: thesis: for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.||
thus for v being Point of [:X,Y:] holds ||.(I . v).|| = ||.v.|| :: thesis: verum

proof

let v be Point of [:X,Y:]; :: thesis: ||.(I . v).|| = ||.v.||
consider x1 being Point of X, x2 being Point of Y such that
A22: v = [x1,x2] by Lm1;
A23: J . x2 = <*x2*> by A1;
then reconsider xx2 = <*x2*> as Point of (product <*Y*>) ;
A24: ex w being Element of REAL 2 st
( w = <*||.x1.||,||.x2.||*> & ||.v.|| = |.w.| ) by A22, Th18;
I . v = I . (x1,x2) by A22
.= [x1,<*x2*>] by A4 ;
then ex s being Element of REAL 2 st
( s = <*||.x1.||,||.xx2.||*> & ||.(I . v).|| = |.s.| ) by Th18;
hence ||.(I . v).|| = ||.v.|| by A23, A1, A24; :: thesis: verum

end;