let a be prime Nat; :: thesis: for n, m being non zero Nat holds (n + m) -root (a |^ m) is irrational
let n, m be non zero Nat; :: thesis: (n + m) -root (a |^ m) is irrational
reconsider x = (n + m) - 1 as non zero Nat ;
assume not (n + m) -root (a |^ m) is irrational ; :: thesis: contradiction
then consider p being Integer, q being Nat such that
A1: ( q <> 0 & p / q = (n + m) -root (a |^ m) & ( for u being Integer
for w being Nat st w <> 0 & (n + m) -root (a |^ m) = u / w holds
q <= w ) ) by RAT_1:9;
A2: q >= 0 + 1 by A1, INT_1:7;
A3: not a is trivial ;
( (n + m) -root (a |^ m) is heavy & (n + m) -root (a |^ m) is positive ) ;
then (p / q) * q > 1 * q by A1, XREAL_1:68;
then p > q by A1, XCMPLX_1:87;
then ( p > 1 & p in NAT ) by A2, XXREAL_0:2, INT_1:3;
then reconsider p = p as heavy Nat by COMPLEX3:1;
(p / q) |^ (n + m) = ((n + m) -root (a |^ m)) |^ (n + m) by A1;
then A4: ((p |^ (n + m)) / (q |^ (n + m))) * (q |^ (n + m)) = (a |^ m) * (q |^ (n + m)) by PREPOWER:8;
then p |^ (n + m) = (a |^ m) * (q |^ (n + m)) by A1, XCMPLX_1:87;
then a divides p |^ (n + m) by NAT_3:3, INT_2:2;
then consider k being Nat such that
A5: p = a * k by NAT_3:5, NAT_D:def 3;
(a |^ m) * (q |^ (n + m)) = (k * a) |^ (n + m) by A4, A1, XCMPLX_1:87, A5
.= (k |^ (n + m)) * (a |^ (n + m)) by NEWTON:7 ;
then a |^ (n + m) divides (a |^ m) * (q |^ (n + m)) ;
then (a |^ m) * (a |^ n) divides (a |^ m) * (q |^ (n + m)) by NEWTON:8;
then ( a divides a |^ n & a |^ n divides q |^ (n + m) ) by INT_4:7, NAT_3:3;
then a divides q |^ (n + m) by INT_2:9;
then consider l being Nat such that
A6: q = a * l by NAT_3:5, NAT_D:def 3;
A7: l > 0 by A1, A6;
then A8: a * l > 1 * l by A3, XREAL_1:68;
(n + m) -root (a |^ m) = k / l by A1, A5, A6, XCMPLX_1:91;
hence contradiction by A1, A7, A6, A8; :: thesis: verum