let a be Real; :: thesis: for RNS being RealNormSpace
for S being sequence of RNS st S is convergent holds
lim (a * S) = a * (lim S)
let RNS be RealNormSpace; :: thesis: for S being sequence of RNS st S is convergent holds
lim (a * S) = a * (lim S)
let S be sequence of RNS; :: thesis: ( S is convergent implies lim (a * S) = a * (lim S) )
set g = lim S;
set h = a * (lim S);
assume A1: S is convergent ; :: thesis: lim (a * S) = a * (lim S)

A2: now :: thesis: ( a = 0 implies for r being Real st 0 < r holds
ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r )

assume A3: a = 0 ; :: thesis: for r being Real st 0 < r holds
ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r
let r be Real; :: thesis: ( 0 < r implies ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r )
assume 0 < r ; :: thesis: ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r
then consider m1 being Nat such that
A4: for n being Nat st m1 <= n holds
||.((S . n) - (lim S)).|| < r by A1, Def7;
take k = m1; :: thesis: for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r
let n be Nat; :: thesis: ( k <= n implies ||.(((a * S) . n) - (a * (lim S))).|| < r )
assume k <= n ; :: thesis: ||.(((a * S) . n) - (a * (lim S))).|| < r
then A5: ||.((S . n) - (lim S)).|| < r by A4;
||.((a * (S . n)) - (a * (lim S))).|| = ||.((0 * (S . n)) - H₁(RNS)).|| by A3, RLVECT_1:10
.= ||.(H₁(RNS) - H₁(RNS)).|| by RLVECT_1:10
.= ||.H₁(RNS).||
.= 0 ;
then ||.((a * (S . n)) - (a * (lim S))).|| < r by A5;
hence ||.(((a * S) . n) - (a * (lim S))).|| < r by Def5; :: thesis: verum

end;

A6: now :: thesis: ( a <> 0 implies for r being Real st 0 < r holds
ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r )

assume A7: a <> 0 ; :: thesis: for r being Real st 0 < r holds
ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r
then A8: 0 < |.a.| by COMPLEX1:47;
let r be Real; :: thesis: ( 0 < r implies ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r )
assume 0 < r ; :: thesis: ex k being Nat st
for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r
then 0 < r / |.a.| by A8;
then consider m1 being Nat such that
A9: for n being Nat st m1 <= n holds
||.((S . n) - (lim S)).|| < r / |.a.| by A1, Def7;
take k = m1; :: thesis: for n being Nat st k <= n holds
||.(((a * S) . n) - (a * (lim S))).|| < r
let n be Nat; :: thesis: ( k <= n implies ||.(((a * S) . n) - (a * (lim S))).|| < r )
assume k <= n ; :: thesis: ||.(((a * S) . n) - (a * (lim S))).|| < r
then A10: ||.((S . n) - (lim S)).|| < r / |.a.| by A9;
A11: 0 <> |.a.| by A7, COMPLEX1:47;
A12: |.a.| * (r / |.a.|) = |.a.| * ((|.a.| ") * r) by XCMPLX_0:def 9
.= (|.a.| * (|.a.| ")) * r
.= 1 * r by A11, XCMPLX_0:def 7
.= r ;
||.((a * (S . n)) - (a * (lim S))).|| = ||.(a * ((S . n) - (lim S))).|| by RLVECT_1:34
.= |.a.| * ||.((S . n) - (lim S)).|| by Def1 ;
then ||.((a * (S . n)) - (a * (lim S))).|| < r by A8, A10, A12, XREAL_1:68;
hence ||.(((a * S) . n) - (a * (lim S))).|| < r by Def5; :: thesis: verum

end;

a * S is convergent by A1, Th22;
hence lim (a * S) = a * (lim S) by A2, A6, Def7; :: thesis: verum