let CNS be ComplexNormSpace; :: thesis: for RNS being RealNormSpace
for X being set
for f being PartFunc of CNS,RNS st f is_Lipschitzian_on X holds
( - f is_Lipschitzian_on X & ||.f.|| is_Lipschitzian_on X )
let RNS be RealNormSpace; :: thesis: for X being set
for f being PartFunc of CNS,RNS st f is_Lipschitzian_on X holds
( - f is_Lipschitzian_on X & ||.f.|| is_Lipschitzian_on X )
let X be set ; :: thesis: for f being PartFunc of CNS,RNS st f is_Lipschitzian_on X holds
( - f is_Lipschitzian_on X & ||.f.|| is_Lipschitzian_on X )
let f be PartFunc of CNS,RNS; :: thesis: ( f is_Lipschitzian_on X implies ( - f is_Lipschitzian_on X & ||.f.|| is_Lipschitzian_on X ) )
assume A1: f is_Lipschitzian_on X ; :: thesis: ( - f is_Lipschitzian_on X & ||.f.|| is_Lipschitzian_on X )
then consider s being Real such that
A2: 0 < s and
A3: for x1, x2 being Point of CNS st x1 in X & x2 in X holds
||.((f /. x1) - (f /. x2)).|| <= s * ||.(x1 - x2).|| ;
- f = (- 1) (#) f by VFUNCT_1:23;
hence - f is_Lipschitzian_on X by A1, Th107; :: thesis: ||.f.|| is_Lipschitzian_on X
X c= dom f by A1;
hence A4: X c= dom ||.f.|| by NORMSP_0:def 3; :: according to NCFCONT1:def 21 :: thesis: ex r being Real st
( 0 < r & ( for x1, x2 being Point of CNS st x1 in X & x2 in X holds
|.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= r * ||.(x1 - x2).|| ) )
take s ; :: thesis: ( 0 < s & ( for x1, x2 being Point of CNS st x1 in X & x2 in X holds
|.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= s * ||.(x1 - x2).|| ) )
thus 0 < s by A2; :: thesis: for x1, x2 being Point of CNS st x1 in X & x2 in X holds
|.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= s * ||.(x1 - x2).||
let x1, x2 be Point of CNS; :: thesis: ( x1 in X & x2 in X implies |.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= s * ||.(x1 - x2).|| )
assume that
A5: x1 in X and
A6: x2 in X ; :: thesis: |.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= s * ||.(x1 - x2).||
|.((||.f.|| /. x1) - (||.f.|| /. x2)).| = |.((||.f.|| . x1) - (||.f.|| /. x2)).| by A4, A5, PARTFUN1:def 6
.= |.((||.f.|| . x1) - (||.f.|| . x2)).| by A4, A6, PARTFUN1:def 6
.= |.(||.(f /. x1).|| - (||.f.|| . x2)).| by A4, A5, NORMSP_0:def 3
.= |.(||.(f /. x1).|| - ||.(f /. x2).||).| by A4, A6, NORMSP_0:def 3 ;
then A7: |.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= ||.((f /. x1) - (f /. x2)).|| by NORMSP_1:9;
||.((f /. x1) - (f /. x2)).|| <= s * ||.(x1 - x2).|| by A3, A5, A6;
hence |.((||.f.|| /. x1) - (||.f.|| /. x2)).| <= s * ||.(x1 - x2).|| by A7, XXREAL_0:2; :: thesis: verum