let R be Skew-Field; :: thesis: for V being LeftMod of R
for v1, v2 being Vector of V holds
( v1 <> v2 & {v1,v2} is linearly-independent iff ( v2 <> 0. V & ( for a being Scalar of R holds v1 <> a * v2 ) ) )
let V be LeftMod of R; :: thesis: for v1, v2 being Vector of V holds
( v1 <> v2 & {v1,v2} is linearly-independent iff ( v2 <> 0. V & ( for a being Scalar of R holds v1 <> a * v2 ) ) )
let v1, v2 be Vector of V; :: thesis: ( v1 <> v2 & {v1,v2} is linearly-independent iff ( v2 <> 0. V & ( for a being Scalar of R holds v1 <> a * v2 ) ) )
thus ( v1 <> v2 & {v1,v2} is linearly-independent implies ( v2 <> 0. V & ( for a being Scalar of R holds v1 <> a * v2 ) ) ) :: thesis: ( v2 <> 0. V & ( for a being Scalar of R holds v1 <> a * v2 ) implies ( v1 <> v2 & {v1,v2} is linearly-independent ) )

proof

deffunc H₁( Element of V) -> Element of the carrier of R = 0. R;
assume that
A2: v1 <> v2 and
A3: {v1,v2} is linearly-independent ; :: thesis: ( v2 <> 0. V & ( for a being Scalar of R holds v1 <> a * v2 ) )
thus v2 <> 0. V by A3, VECTSP_7:28; :: thesis: for a being Scalar of R holds v1 <> a * v2
let a be Scalar of R; :: thesis: v1 <> a * v2
consider f being Function of the carrier of V, the carrier of R such that
A4: ( f . v1 = - (1. R) & f . v2 = a ) and
A5: for v being Element of V st v <> v1 & v <> v2 holds
f . v = H₁(v) from FUNCT_2:sch 7(A2);
reconsider f = f as Element of Funcs ( the carrier of V, the carrier of R) by FUNCT_2:8;

now :: thesis: for v being Vector of V st not v in {v1,v2} holds
f . v = 0. R

let v be Vector of V; :: thesis: ( not v in {v1,v2} implies f . v = 0. R )
assume not v in {v1,v2} ; :: thesis: f . v = 0. R
then ( v <> v1 & v <> v2 ) by TARSKI:def 2;
hence f . v = 0. R by A5; :: thesis: verum

end;

then reconsider f = f as Linear_Combination of V by VECTSP_6:def 1;
Carrier f c= {v1,v2}

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier f or x in {v1,v2} )
assume x in Carrier f ; :: thesis: x in {v1,v2}
then A6: ex u being Vector of V st
( x = u & f . u <> 0. R ) ;
assume not x in {v1,v2} ; :: thesis: contradiction
then ( x <> v1 & x <> v2 ) by TARSKI:def 2;
hence contradiction by A5, A6; :: thesis: verum

end;

then reconsider f = f as Linear_Combination of {v1,v2} by VECTSP_6:def 4;

A7: now :: thesis: v1 in Carrier f

assume not v1 in Carrier f ; :: thesis: contradiction
then 0. R = - (1. R) by A4;
hence contradiction by Th1; :: thesis: verum

end;

set w = a * v2;
assume v1 = a * v2 ; :: thesis: contradiction
then Sum f = ((- (1. R)) * (a * v2)) + (a * v2) by A2, A4, VECTSP_6:18
.= (- (a * v2)) + (a * v2) by VECTSP_1:14
.= 0. V by RLVECT_1:5 ;
hence contradiction by A3, A7; :: thesis: verum

end;

assume A8: v2 <> 0. V ; :: thesis: ( ex a being Scalar of R st not v1 <> a * v2 or ( v1 <> v2 & {v1,v2} is linearly-independent ) )
assume A9: for a being Scalar of R holds v1 <> a * v2 ; :: thesis: ( v1 <> v2 & {v1,v2} is linearly-independent )
A10: (1. R) * v2 = v2 ;
hence v1 <> v2 by A9; :: thesis: {v1,v2} is linearly-independent
let l be Linear_Combination of {v1,v2}; :: according to VECTSP_7:def 1 :: thesis: ( not Sum l = 0. V or Carrier l = {} )
assume that
A11: Sum l = 0. V and
A12: Carrier l <> {} ; :: thesis: contradiction
A13: 0. V = ((l . v1) * v1) + ((l . v2) * v2) by A9, A10, A11, VECTSP_6:18;
set x = the Element of Carrier l;
Carrier l c= {v1,v2} by VECTSP_6:def 4;
then A14: the Element of Carrier l in {v1,v2} by A12;
the Element of Carrier l in Carrier l by A12;
then A15: ex u being Vector of V st
( the Element of Carrier l = u & l . u <> 0. R ) ;

now :: thesis: contradiction

per cases ( l . v1 <> 0. R or ( l . v2 <> 0. R & l . v1 = 0. R ) ) by A15, A14, TARSKI:def 2;

suppose A16: l . v1 <> 0. R ; :: thesis: contradiction

0. V = ((l . v1) ") * (((l . v1) * v1) + ((l . v2) * v2)) by A13, VECTSP_2:30
.= (((l . v1) ") * ((l . v1) * v1)) + (((l . v1) ") * ((l . v2) * v2)) by VECTSP_1:def 14
.= ((((l . v1) ") * (l . v1)) * v1) + (((l . v1) ") * ((l . v2) * v2)) by VECTSP_1:def 16
.= ((((l . v1) ") * (l . v1)) * v1) + ((((l . v1) ") * (l . v2)) * v2) by VECTSP_1:def 16
.= ((1. R) * v1) + ((((l . v1) ") * (l . v2)) * v2) by A16, Lm2
.= v1 + ((((l . v1) ") * (l . v2)) * v2) ;
then v1 = - ((((l . v1) ") * (l . v2)) * v2) by VECTSP_1:16
.= (- (1. R)) * ((((l . v1) ") * (l . v2)) * v2) by VECTSP_1:14
.= ((- (1. R)) * (((l . v1) ") * (l . v2))) * v2 by VECTSP_1:def 16 ;
hence contradiction by A9; :: thesis: verum

end;

suppose A17: ( l . v2 <> 0. R & l . v1 = 0. R ) ; :: thesis: contradiction

0. V = ((l . v2) ") * (((l . v1) * v1) + ((l . v2) * v2)) by A13, VECTSP_2:30
.= (((l . v2) ") * ((l . v1) * v1)) + (((l . v2) ") * ((l . v2) * v2)) by VECTSP_1:def 14
.= ((((l . v2) ") * (l . v1)) * v1) + (((l . v2) ") * ((l . v2) * v2)) by VECTSP_1:def 16
.= ((((l . v2) ") * (l . v1)) * v1) + ((1. R) * v2) by A17, Lm2
.= ((((l . v2) ") * (l . v1)) * v1) + v2
.= ((0. R) * v1) + v2 by A17
.= (0. V) + v2 by VECTSP_2:30
.= v2 by RLVECT_1:def 4 ;
hence contradiction by A8; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum