let X be non empty set ; :: thesis: for S being SigmaField of X
for M being sigma_Measure of S
for f being PartFunc of X,ExtREAL
for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )
let S be SigmaField of X; :: thesis: for M being sigma_Measure of S
for f being PartFunc of X,ExtREAL
for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )
let M be sigma_Measure of S; :: thesis: for f being PartFunc of X,ExtREAL
for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )
let f be PartFunc of X,ExtREAL; :: thesis: for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )
let c be Real; :: thesis: ( f is_integrable_on M implies ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) ) )
assume A1: f is_integrable_on M ; :: thesis: ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )
A2: integral+ (M,(max+ f)) <> +infty by A1;
consider A being Element of S such that
A3: A = dom f and
A4: f is A -measurable by A1;
A5: c (#) f is A -measurable by A3, A4, Th49;
A6: dom (max- f) = A by A3, MESFUNC2:def 3;
A7: integral+ (M,(max- f)) <> +infty by A1;
0 <= integral+ (M,(max- f)) by A1, Th96;
then reconsider I2 = integral+ (M,(max- f)) as Element of REAL by A7, XXREAL_0:14;
A8: max- f is nonnegative by Lm1;
0 <= integral+ (M,(max+ f)) by A1, Th96;
then reconsider I1 = integral+ (M,(max+ f)) as Element of REAL by A2, XXREAL_0:14;
A9: max+ f is nonnegative by Lm1;
A10: dom (c (#) f) = A by A3, MESFUNC1:def 6;
A11: dom (max+ f) = A by A3, MESFUNC2:def 2;

per cases ( 0 <= c or c < 0 ) ;

suppose A12: 0 <= c ; :: thesis: ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )

c * I1 in REAL by XREAL_0:def 1;
then A13: c * (integral+ (M,(max+ f))) in REAL ;
A14: max+ (c (#) f) = c (#) (max+ f) by A12, Th26;
integral+ (M,(c (#) (max+ f))) = c * (integral+ (M,(max+ f))) by A4, A9, A11, A12, Th86, MESFUNC2:25;
then A15: integral+ (M,(max+ (c (#) f))) < +infty by A14, A13, XXREAL_0:9;
c * I2 in REAL by XREAL_0:def 1;
then c * (integral+ (M,(max- f))) is Element of REAL ;
then A16: c * (integral+ (M,(max- f))) < +infty by XXREAL_0:9;
A17: max- (c (#) f) = c (#) (max- f) by A12, Th26;
integral+ (M,(c (#) (max- f))) = c * (integral+ (M,(max- f))) by A3, A4, A8, A6, A12, Th86, MESFUNC2:26;
hence c (#) f is_integrable_on M by A5, A10, A17, A15, A16; :: thesis: Integral (M,(c (#) f)) = c * (Integral (M,f))
thus Integral (M,(c (#) f)) = (integral+ (M,(c (#) (max+ f)))) - (integral+ (M,(max- (c (#) f)))) by A12, Th26
.= (integral+ (M,(c (#) (max+ f)))) - (integral+ (M,(c (#) (max- f)))) by A12, Th26
.= (c * (integral+ (M,(max+ f)))) - (integral+ (M,(c (#) (max- f)))) by A4, A9, A11, A12, Th86, MESFUNC2:25
.= (c * (integral+ (M,(max+ f)))) - (c * (integral+ (M,(max- f)))) by A3, A4, A8, A6, A12, Th86, MESFUNC2:26
.= c * (Integral (M,f)) by XXREAL_3:100 ; :: thesis: verum

end;

suppose A18: c < 0 ; :: thesis: ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = c * (Integral (M,f)) )

- (- c) = c ;
then consider a being Real such that
A19: c = - a and
A20: a > 0 by A18;
A21: max+ (c (#) f) = a (#) (max- f) by A19, A20, Th27;
A22: max- (c (#) f) = a (#) (max+ f) by A19, A20, Th27;
a * I2 in REAL by XREAL_0:def 1;
then A23: a * (integral+ (M,(max- f))) in REAL ;
integral+ (M,(a (#) (max- f))) = a * (integral+ (M,(max- f))) by A3, A4, A8, A6, A20, Th86, MESFUNC2:26;
then A24: integral+ (M,(max+ (c (#) f))) < +infty by A21, A23, XXREAL_0:9;
a * I1 in REAL by XREAL_0:def 1;
then a * (integral+ (M,(max+ f))) is Element of REAL ;
then A25: a * (integral+ (M,(max+ f))) < +infty by XXREAL_0:9;
integral+ (M,(a (#) (max+ f))) = a * (integral+ (M,(max+ f))) by A4, A9, A11, A20, Th86, MESFUNC2:25;
hence c (#) f is_integrable_on M by A5, A10, A22, A24, A25; :: thesis: Integral (M,(c (#) f)) = c * (Integral (M,f))
thus Integral (M,(c (#) f)) = (a * (integral+ (M,(max- f)))) - (integral+ (M,(a (#) (max+ f)))) by A3, A4, A8, A6, A20, A21, A22, Th86, MESFUNC2:26
.= (a * (integral+ (M,(max- f)))) - (a * (integral+ (M,(max+ f)))) by A4, A9, A11, A20, Th86, MESFUNC2:25
.= a * ((integral+ (M,(max- f))) - (integral+ (M,(max+ f)))) by XXREAL_3:100
.= a * (- ((integral+ (M,(max+ f))) - (integral+ (M,(max- f))))) by XXREAL_3:26
.= - (a * ((integral+ (M,(max+ f))) - (integral+ (M,(max- f))))) by XXREAL_3:92
.= c * (Integral (M,f)) by A19, XXREAL_3:92 ; :: thesis: verum

end;

end;