let F be ExtREAL_sequence; :: thesis: for n being Nat
for a being R_eal st ( for k being Nat holds F . k = a ) holds
(Partial_Sums F) . n = a * (n + 1)
let n be Nat; :: thesis: for a being R_eal st ( for k being Nat holds F . k = a ) holds
(Partial_Sums F) . n = a * (n + 1)
let a be R_eal; :: thesis: ( ( for k being Nat holds F . k = a ) implies (Partial_Sums F) . n = a * (n + 1) )
assume A1: for k being Nat holds F . k = a ; :: thesis: (Partial_Sums F) . n = a * (n + 1)
defpred S₁[ Nat] means (Partial_Sums F) . $1 = a * ($1 + 1);
(Partial_Sums F) . 0 = F . 0 by MESFUNC9:def 1;
then (Partial_Sums F) . 0 = a by A1;
then A2: S₁[ 0 ] by XXREAL_3:81;
A3: for i being Nat st S₁[i] holds
S₁[i + 1]

proof

let i be Nat; :: thesis: ( S₁[i] implies S₁[i + 1] )
assume A4: S₁[i] ; :: thesis: S₁[i + 1]
( i + 1 in REAL & 1 in REAL ) by XREAL_0:def 1;
then reconsider i1 = i + 1, One = 1 as R_eal by XBOOLE_0:def 3, XXREAL_0:def 4;
(Partial_Sums F) . (i + 1) = ((Partial_Sums F) . i) + (F . (i + 1)) by MESFUNC9:def 1;
then (Partial_Sums F) . (i + 1) = (a * (i + 1)) + a by A1, A4;
then (Partial_Sums F) . (i + 1) = (a * (i + 1)) + (a * 1) by XXREAL_3:81;
then (Partial_Sums F) . (i + 1) = a * (i1 + One) by XXREAL_3:96;
hence S₁[i + 1] by XXREAL_3:def 2; :: thesis: verum

end;

for i being Nat holds S₁[i] from NAT_1:sch 2(A2, A3);
hence (Partial_Sums F) . n = a * (n + 1) ; :: thesis: verum