let a, b, s, t be Real; :: thesis: ( 0 < a implies (AffineMap (a,b)) .: [.s,t.] = [.((a * s) + b),((a * t) + b).] )
assume A1: 0 < a ; :: thesis: (AffineMap (a,b)) .: [.s,t.] = [.((a * s) + b),((a * t) + b).]
A2: now :: thesis: for z being Real st z in (AffineMap (a,b)) .: [.s,t.] holds
z in [.((a * s) + b),((a * t) + b).]
let z be Real; :: thesis: ( z in (AffineMap (a,b)) .: [.s,t.] implies z in [.((a * s) + b),((a * t) + b).] )
assume z in (AffineMap (a,b)) .: [.s,t.] ; :: thesis: z in [.((a * s) + b),((a * t) + b).]
then consider x being Element of REAL such that
A3: ( x in [.s,t.] & z = (AffineMap (a,b)) . x ) by FUNCT_2:65;
( s <= x & x <= t ) by A3, XXREAL_1:1;
then ( a * s <= a * x & a * x <= a * t ) by A1, XREAL_1:64;
then ( (a * s) + b <= (a * x) + b & (a * x) + b <= (a * t) + b ) by XREAL_1:6;
then ( (a * s) + b <= z & z <= (a * t) + b ) by A3, FCONT_1:def 4;
hence z in [.((a * s) + b),((a * t) + b).] ; :: thesis: verum
end;
now :: thesis: for x being Real st x in [.((a * s) + b),((a * t) + b).] holds
x in (AffineMap (a,b)) .: [.s,t.]
let x be Real; :: thesis: ( x in [.((a * s) + b),((a * t) + b).] implies x in (AffineMap (a,b)) .: [.s,t.] )
assume x in [.((a * s) + b),((a * t) + b).] ; :: thesis: x in (AffineMap (a,b)) .: [.s,t.]
then ( (a * s) + b <= x & x <= (a * t) + b ) by XXREAL_1:1;
then ( a * s <= x - b & x - b <= a * t ) by XREAL_1:19, XREAL_1:20;
then ( s <= (x - b) / a & (x - b) / a <= t ) by A1, XREAL_1:77, XREAL_1:79;
then A4: (x - b) / a in [.s,t.] ;
dom (AffineMap (a,b)) = REAL by FUNCT_2:def 1;
then A5: (x - b) / a in dom (AffineMap (a,b)) by XREAL_0:def 1;
(AffineMap (a,b)) . ((x - b) / a) = (a * ((x - b) / a)) + b by FCONT_1:def 4;
then (AffineMap (a,b)) . ((x - b) / a) = (x - b) + b by A1, XCMPLX_1:87;
hence x in (AffineMap (a,b)) .: [.s,t.] by A4, A5, FUNCT_1:def 6; :: thesis: verum
end;
hence (AffineMap (a,b)) .: [.s,t.] = [.((a * s) + b),((a * t) + b).] by A2; :: thesis: verum