let a, b, s be Real; :: thesis: for t being R_eal st a < 0 holds
(AffineMap (a,b)) .: [.s,t.[ = ].((a * t) + b),((a * s) + b).]

let t be R_eal; :: thesis: ( a < 0 implies (AffineMap (a,b)) .: [.s,t.[ = ].((a * t) + b),((a * s) + b).] )
assume A1: a < 0 ; :: thesis: (AffineMap (a,b)) .: [.s,t.[ = ].((a * t) + b),((a * s) + b).]
A2: ( a in REAL & b in REAL ) by XREAL_0:def 1;
A3: now :: thesis: for z being Real st z in (AffineMap (a,b)) .: [.s,t.[ holds
z in ].((a * t) + b),((a * s) + b).]
let z be Real; :: thesis: ( z in (AffineMap (a,b)) .: [.s,t.[ implies z in ].((a * t) + b),((a * s) + b).] )
assume z in (AffineMap (a,b)) .: [.s,t.[ ; :: thesis: z in ].((a * t) + b),((a * s) + b).]
then consider x being Element of REAL such that
A4: ( x in [.s,t.[ & z = (AffineMap (a,b)) . x ) by FUNCT_2:65;
( s <= x & x < t ) by A4, XXREAL_1:3;
then ( a * t < a * x & a * x <= a * s ) by A1, XXREAL_3:102, XREAL_1:65;
then ( (a * t) + b < (a * x) + b & (a * x) + b <= (a * s) + b ) by A2, XXREAL_3:43, XREAL_1:6;
then ( (a * t) + b < z & z <= (a * s) + b ) by A4, FCONT_1:def 4;
hence z in ].((a * t) + b),((a * s) + b).] ; :: thesis: verum
end;
now :: thesis: for x being Real st x in ].((a * t) + b),((a * s) + b).] holds
x in (AffineMap (a,b)) .: [.s,t.[
let x be Real; :: thesis: ( x in ].((a * t) + b),((a * s) + b).] implies x in (AffineMap (a,b)) .: [.s,t.[ )
assume x in ].((a * t) + b),((a * s) + b).] ; :: thesis: x in (AffineMap (a,b)) .: [.s,t.[
then ( (a * t) + b < x & x <= (a * s) + b ) by XXREAL_1:2;
then ( ((a * t) + b) - b < x - b & x - b <= ((a * s) + b) - b ) by A2, XXREAL_3:43, XREAL_1:9;
then ( a * t < x - b & x - b <= a * s ) by XXREAL_3:24;
then ( (a * s) / a <= (x - b) / a & (x - b) / a < (a * t) / a ) by A1, XXREAL_3:102, XREAL_1:65;
then ( s <= (x - b) / a & (x - b) / a < t ) by A1, XXREAL_3:88;
then A5: (x - b) / a in [.s,t.[ ;
dom (AffineMap (a,b)) = REAL by FUNCT_2:def 1;
then A6: (x - b) / a in dom (AffineMap (a,b)) by XREAL_0:def 1;
(AffineMap (a,b)) . ((x - b) / a) = (a * ((x - b) / a)) + b by FCONT_1:def 4;
then (AffineMap (a,b)) . ((x - b) / a) = (x - b) + b by A1, XCMPLX_1:87;
hence x in (AffineMap (a,b)) .: [.s,t.[ by A5, A6, FUNCT_1:def 6; :: thesis: verum
end;
hence (AffineMap (a,b)) .: [.s,t.[ = ].((a * t) + b),((a * s) + b).] by A3; :: thesis: verum