let n be non zero Nat; :: thesis: for x being Point of (CarProduct ((Seg n) --> RNS_Real))
for px being n -element FinSequence of REAL
for r being Real st 0 <= r & x = PtCarProduct px & ( for i being Nat st i in Seg n holds
|.(px . i).| <= r / n ) holds
||.x.|| <= r

let x be Point of (CarProduct ((Seg n) --> RNS_Real)); :: thesis: for px being n -element FinSequence of REAL
for r being Real st 0 <= r & x = PtCarProduct px & ( for i being Nat st i in Seg n holds
|.(px . i).| <= r / n ) holds
||.x.|| <= r

let px be n -element FinSequence of REAL ; :: thesis: for r being Real st 0 <= r & x = PtCarProduct px & ( for i being Nat st i in Seg n holds
|.(px . i).| <= r / n ) holds
||.x.|| <= r

let r1 be Real; :: thesis: ( 0 <= r1 & x = PtCarProduct px & ( for i being Nat st i in Seg n holds
|.(px . i).| <= r1 / n ) implies ||.x.|| <= r1 )

assume A1: ( 0 <= r1 & x = PtCarProduct px & ( for i being Nat st i in Seg n holds
|.(px . i).| <= r1 / n ) ) ; :: thesis: ||.x.|| <= r1
then consider nrx being Element of REAL n such that
A2: ( ( for i being Nat st i in Seg n holds
nrx . i = |.(px . i).| ) & ||.x.|| = |.nrx.| ) by Th58;
set r2 = r1 / n;
(((r1 / n) * (r1 / n)) * n) * 1 <= (((r1 / n) * (r1 / n)) * n) * n by A1, XREAL_1:64, NAT_1:14;
then ((r1 / n) * (r1 / n)) * n <= ((r1 / n) * n) * ((r1 / n) * n) ;
then ((r1 / n) * (r1 / n)) * n <= r1 * ((r1 / n) * n) by XCMPLX_1:87;
then ((r1 / n) * (r1 / n)) * n <= r1 * r1 by XCMPLX_1:87;
then sqrt (((r1 / n) * (r1 / n)) * n) <= sqrt (r1 ^2) by A1, SQUARE_1:26;
then A3: sqrt (((r1 / n) * (r1 / n)) * n) <= r1 by A1, SQUARE_1:22;
for i being Nat st i in dom nrx holds
( 0 <= nrx . i & nrx . i <= r1 / n )
proof
let i be Nat; :: thesis: ( i in dom nrx implies ( 0 <= nrx . i & nrx . i <= r1 / n ) )
assume i in dom nrx ; :: thesis: ( 0 <= nrx . i & nrx . i <= r1 / n )
then i in Seg (len nrx) by FINSEQ_1:def 3;
then A4: i in Seg n by CARD_1:def 7;
then nrx . i = |.(px . i).| by A2;
hence ( 0 <= nrx . i & nrx . i <= r1 / n ) by A4, A1; :: thesis: verum
end;
then |.nrx.| <= sqrt (((r1 / n) * (r1 / n)) * (len nrx)) by LOPBAN11:10;
then |.nrx.| <= sqrt (((r1 / n) * (r1 / n)) * n) by CARD_1:def 7;
hence ||.x.|| <= r1 by A2, A3, XXREAL_0:2; :: thesis: verum