let n be non zero Nat; :: thesis: for a being n -element FinSequence of REAL
for r being Real st 0 < r holds
ex D1 being non-empty n -element FinSequence st
for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[

let a be n -element FinSequence of REAL ; :: thesis: for r being Real st 0 < r holds
ex D1 being non-empty n -element FinSequence st
for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[

let r be Real; :: thesis: ( 0 < r implies ex D1 being non-empty n -element FinSequence st
for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[ )

assume A1: 0 < r ; :: thesis: ex D1 being non-empty n -element FinSequence st
for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[

defpred S1[ Nat, object ] means ex y being Real st
( y = a . $1 & $2 = ].(y - r),(y + r).[ );
A2: for k being Nat st k in Seg n holds
ex x being object st S1[k,x]
proof
let k be Nat; :: thesis: ( k in Seg n implies ex x being object st S1[k,x] )
assume k in Seg n ; :: thesis: ex x being object st S1[k,x]
reconsider y = a . k as Real ;
take x = ].(y - r),(y + r).[; :: thesis: S1[k,x]
thus S1[k,x] ; :: thesis: verum
end;
consider D1 being FinSequence such that
A3: ( dom D1 = Seg n & ( for k being Nat st k in Seg n holds
S1[k,D1 . k] ) ) from FINSEQ_1:sch 1(A2);
n is Element of NAT by ORDINAL1:def 12;
then len D1 = n by A3, FINSEQ_1:def 3;
then reconsider D1 = D1 as n -element FinSequence by CARD_1:def 7;
A4: for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[
proof
let i be Nat; :: thesis: ( i in Seg n implies D1 . i = ].((a . i) - r),((a . i) + r).[ )
assume i in Seg n ; :: thesis: D1 . i = ].((a . i) - r),((a . i) + r).[
then ex y being Real st
( y = a . i & D1 . i = ].(y - r),(y + r).[ ) by A3;
hence D1 . i = ].((a . i) - r),((a . i) + r).[ ; :: thesis: verum
end;
not {} in rng D1
proof
assume {} in rng D1 ; :: thesis: contradiction
then consider i being object such that
A5: ( i in dom D1 & {} = D1 . i ) by FUNCT_1:def 3;
reconsider i = i as Nat by A5;
A6: (a . i) - r < (a . i) - 0 by A1, XREAL_1:15;
(a . i) + 0 < (a . i) + r by A1, XREAL_1:8;
then a . i in ].((a . i) - r),((a . i) + r).[ by A6;
hence contradiction by A3, A4, A5; :: thesis: verum
end;
then reconsider D1 = D1 as non-empty n -element FinSequence by RELAT_1:def 9;
take D1 ; :: thesis: for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[

thus for i being Nat st i in Seg n holds
D1 . i = ].((a . i) - r),((a . i) + r).[ by A4; :: thesis: verum