defpred S1[ non zero Nat] means for X being $1 -element RealNormSpace-Sequence
for x being Point of (CarProduct X) ex px being $1 -element FinSequence st
( x = PtCarProduct px & (CarProd X) . x = px );
A1: S1[1]
proof
let X be 1 -element RealNormSpace-Sequence; :: thesis: for x being Point of (CarProduct X) ex px being 1 -element FinSequence st
( x = PtCarProduct px & (CarProd X) . x = px )

let x be Point of (CarProduct X); :: thesis: ex px being 1 -element FinSequence st
( x = PtCarProduct px & (CarProd X) . x = px )

set X1 = ElmFin (X,1);
consider px being 1 -element FinSequence such that
A2: ( x = PtCarProduct px & ( for i being non zero Nat st i <= 1 holds
ex pxi being Point of (ElmFin (X,i)) st pxi = px . i ) ) by Th16;
ex pxi being Point of (ElmFin (X,1)) st pxi = px . 1 by A2;
then reconsider px1 = px . 1 as Point of (ElmFin (X,1)) ;
A3: PtCarProduct px = px . 1 by Def1;
A4: len px = 1 by CARD_1:def 7;
take px ; :: thesis: ( x = PtCarProduct px & (CarProd X) . x = px )
consider CX being non-empty 1 -element FinSequence such that
A5: ( CX = carr X & CarProduct CX = the carrier of (CarProduct X) & CarProd X = CarProd CX & CarProd X is bijective ) by Def7;
consider id1 being Function of (CarProduct (SubFin (CX,1))),(product (SubFin (CX,1))) such that
A6: ( (Pt2FinSeq CX) . 1 = id1 & id1 is bijective & ( for x being object st x in CarProduct (SubFin (CX,1)) holds
id1 . x = <*x*> ) ) by MEASUR14:def 5;
A7: CarProd CX = id1 by A6, MEASUR14:def 6;
A8: len CX = 1 by FINSEQ_3:153;
SubFin (CX,1) = CX | 1 by MEASUR13:def 5;
then SubFin (CX,1) = CX by A8, FINSEQ_1:58;
then (CarProd X) . x = <*x*> by A5, A7, A6;
hence ( x = PtCarProduct px & (CarProd X) . x = px ) by A4, A2, A3, FINSEQ_1:40; :: thesis: verum
end;
A9: for n being non zero Nat st S1[n] holds
S1[n + 1]
proof
let n be non zero Nat; :: thesis: ( S1[n] implies S1[n + 1] )
assume A10: S1[n] ; :: thesis: S1[n + 1]
let X be n + 1 -element RealNormSpace-Sequence; :: thesis: for x being Point of (CarProduct X) ex px being n + 1 -element FinSequence st
( x = PtCarProduct px & (CarProd X) . x = px )

set Xn1 = SubFin (X,n);
set Xn11 = ElmFin (X,(n + 1));
n < n + 1 by NAT_1:13;
then A11: SubFin (X,n) = X | n by Def6;
A12: ElmFin (X,(n + 1)) = X . (n + 1) by Def3;
let x be Point of (CarProduct X); :: thesis: ex px being n + 1 -element FinSequence st
( x = PtCarProduct px & (CarProd X) . x = px )

consider px being n + 1 -element FinSequence such that
A13: ( x = PtCarProduct px & ( for i being non zero Nat st i <= n + 1 holds
ex pxi being Point of (ElmFin (X,i)) st pxi = px . i ) ) by Th16;
take px ; :: thesis: ( x = PtCarProduct px & (CarProd X) . x = px )
consider CX being non-empty n + 1 -element FinSequence such that
A14: ( CX = carr X & CarProduct CX = the carrier of (CarProduct X) & CarProd X = CarProd CX & CarProd X is bijective ) by Def7;
consider CXn1 being non-empty n -element FinSequence such that
A15: ( CXn1 = carr (SubFin (X,n)) & CarProduct CXn1 = the carrier of (CarProduct (SubFin (X,n))) & CarProd (SubFin (X,n)) = CarProd CXn1 & CarProd (SubFin (X,n)) is bijective ) by Def7;
A16: ( len X = n + 1 & len (SubFin (X,n)) = n ) by CARD_1:def 7;
A17: n <= n + 1 by NAT_1:13;
then A18: CXn1 = CX | n by A11, A15, A14, A16, Th27;
reconsider px1 = px | n as n -element FinSequence ;
for i being non zero Nat st i <= n holds
ex px1i being Point of (ElmFin ((SubFin (X,n)),i)) st px1i = px1 . i
proof
let i be non zero Nat; :: thesis: ( i <= n implies ex px1i being Point of (ElmFin ((SubFin (X,n)),i)) st px1i = px1 . i )
assume A19: i <= n ; :: thesis: ex px1i being Point of (ElmFin ((SubFin (X,n)),i)) st px1i = px1 . i
1 <= i by NAT_1:14;
then i in Seg n by A19;
then A20: ( (SubFin (X,n)) . i = X . i & px1 . i = px . i ) by A11, FUNCT_1:49;
( ElmFin (X,i) = X . i & ElmFin ((SubFin (X,n)),i) = (SubFin (X,n)) . i ) by A17, A19, XXREAL_0:2, Def3;
hence ex px1i being Point of (ElmFin ((SubFin (X,n)),i)) st px1i = px1 . i by A13, A20, A17, A19, XXREAL_0:2; :: thesis: verum
end;
then reconsider x1 = PtCarProduct px1 as Point of (CarProduct (SubFin (X,n))) by Th16;
ex prx1 being n -element FinSequence st
( x1 = PtCarProduct prx1 & (CarProd (SubFin (X,n))) . x1 = prx1 ) by A10;
then A21: (CarProd CXn1) . x1 = px1 by A15, Th5;
ex pxi being Point of (ElmFin (X,(n + 1))) st pxi = px . (n + 1) by A13;
then reconsider pxn = px . (n + 1) as Point of (ElmFin (X,(n + 1))) ;
len px = n + 1 by CARD_1:def 7;
then A22: px = px1 ^ <*(px . (n + 1))*> by FINSEQ_3:55;
A23: n + 1 in Seg (n + 1) by FINSEQ_1:4;
len X = n + 1 by CARD_1:def 7;
then reconsider n1 = n + 1 as Element of dom X by A23, FINSEQ_1:def 3;
CX . n1 = the carrier of (X . n1) by A14, PRVECT_1:def 11;
then pxn in CX . (n + 1) by A12;
then A24: pxn in ElmFin (CX,(n + 1)) by MEASUR13:def 1;
A25: CXn1 = SubFin (CX,n) by A17, A18, MEASUR13:def 5;
then ex s, t being FinSequence st
( (CarProd (SubFin (CX,n))) . x1 = s & <*pxn*> = t & (CarProd CX) . (x1,pxn) = s ^ t ) by A15, A24, MEASUR14:13;
hence ( x = PtCarProduct px & (CarProd X) . x = px ) by A13, A14, A25, A21, A22, Th4; :: thesis: verum
end;
for n being non zero Nat holds S1[n] from NAT_1:sch 10(A1, A9);
hence for n being non zero Nat
for X being b1 -element RealNormSpace-Sequence
for x being Point of (CarProduct X) ex px being b1 -element FinSequence st
( x = PtCarProduct px & (CarProd X) . x = px ) ; :: thesis: verum