let k, n, m be Nat; :: thesis: for M1 being Matrix of n,k,REAL
for M2 being Matrix of m,k,REAL holds Sum (M1 ^ M2) = (Sum M1) ^ (Sum M2)
let M1 be Matrix of n,k,REAL; :: thesis: for M2 being Matrix of m,k,REAL holds Sum (M1 ^ M2) = (Sum M1) ^ (Sum M2)
let M2 be Matrix of m,k,REAL; :: thesis: Sum (M1 ^ M2) = (Sum M1) ^ (Sum M2)
A1: dom (Sum (M1 ^ M2)) = Seg (len (Sum (M1 ^ M2))) by FINSEQ_1:def 3;

A2: now :: thesis: for i being Nat st i in dom (Sum (M1 ^ M2)) holds
(Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i

let i be Nat; :: thesis: ( i in dom (Sum (M1 ^ M2)) implies (Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i )
assume A3: i in dom (Sum (M1 ^ M2)) ; :: thesis: (Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i
then i in Seg (len (M1 ^ M2)) by A1, Def1;
then A4: i in dom (M1 ^ M2) by FINSEQ_1:def 3;

now :: thesis: (Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i

per cases ( i in dom M1 or ex n being Nat st
( n in dom M2 & i = (len M1) + n ) ) by A4, FINSEQ_1:25;

suppose A5: i in dom M1 ; :: thesis: (Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i

len M1 = len (Sum M1) by Def1;
then A6: dom M1 = dom (Sum M1) by FINSEQ_3:29;
thus (Sum (M1 ^ M2)) . i = Sum ((M1 ^ M2) . i) by A3, Def1
.= Sum (M1 . i) by A5, FINSEQ_1:def 7
.= (Sum M1) . i by A5, A6, Def1
.= ((Sum M1) ^ (Sum M2)) . i by A5, A6, FINSEQ_1:def 7 ; :: thesis: verum

end;

suppose A7: ex n being Nat st
( n in dom M2 & i = (len M1) + n ) ; :: thesis: (Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i

A8: len M1 = len (Sum M1) by Def1;
len M2 = len (Sum M2) by Def1;
then A9: dom M2 = dom (Sum M2) by FINSEQ_3:29;
consider n being Nat such that
A10: n in dom M2 and
A11: i = (len M1) + n by A7;
thus (Sum (M1 ^ M2)) . i = Sum ((M1 ^ M2) . i) by A3, Def1
.= Sum (M2 . n) by A10, A11, FINSEQ_1:def 7
.= (Sum M2) . n by A10, A9, Def1
.= ((Sum M1) ^ (Sum M2)) . i by A10, A11, A8, A9, FINSEQ_1:def 7 ; :: thesis: verum

end;

end;

end;

hence (Sum (M1 ^ M2)) . i = ((Sum M1) ^ (Sum M2)) . i ; :: thesis: verum

end;

len (Sum (M1 ^ M2)) = len (M1 ^ M2) by Def1
.= (len M1) + (len M2) by FINSEQ_1:22
.= (len (Sum M1)) + (len M2) by Def1
.= (len (Sum M1)) + (len (Sum M2)) by Def1
.= len ((Sum M1) ^ (Sum M2)) by FINSEQ_1:22 ;
hence Sum (M1 ^ M2) = (Sum M1) ^ (Sum M2) by A2, FINSEQ_2:9; :: thesis: verum