let A be Element of LTLB_WFF ; :: thesis: for F being Subset of LTLB_WFF st F |- A holds
F |= A
let F be Subset of LTLB_WFF; :: thesis: ( F |- A implies F |= A )
assume F |- A ; :: thesis: F |= A
then consider f being FinSequence of LTLB_WFF such that
A1: f . (len f) = A and
A2: 1 <= len f and
A3: for i being Nat st 1 <= i & i <= len f holds
prc f,F,i ;
defpred S₁[ Nat] means ( 1 <= $1 & $1 <= len f implies F |= f /. $1 );
A4: for i being Nat st ( for j being Nat st j < i holds
S₁[j] ) holds
S₁[i]

proof

let i be Nat; :: thesis: ( ( for j being Nat st j < i holds
S₁[j] ) implies S₁[i] )
assume A5: for j being Nat st j < i holds
S₁[j] ; :: thesis: S₁[i]

per cases ( i = 0 or not i < 1 ) by NAT_1:14;

suppose i = 0 ; :: thesis: S₁[i]

hence S₁[i] ; :: thesis: verum

end;

suppose not i < 1 ; :: thesis: S₁[i]

assume that
A6: 1 <= i and
A7: i <= len f ; :: thesis: F |= f /. i

per cases ( f . i in LTL_axioms or f . i in F or ex j, k being Nat st
( 1 <= j & j < i & 1 <= k & k < i & ( f /. j,f /. k MP_rule f /. i or f /. j,f /. k IND_rule f /. i ) ) or ex j being Nat st
( 1 <= j & j < i & f /. j NEX_rule f /. i ) ) by A3, A6, A7, Def29;

suppose f . i in LTL_axioms ; :: thesis: F |= f /. i

then A8: f /. i in LTL_axioms by A6, A7, Lm1;

per cases ( f /. i is LTL_TAUT_OF_PL or f /. i is axltl1 or f /. i is axltl1a or f /. i is axltl2 or f /. i is axltl3 or f /. i is axltl4 or f /. i is axltl5 or f /. i is axltl6 ) by A8, Th36;

suppose f /. i is LTL_TAUT_OF_PL ; :: thesis: F |= f /. i

hence F |= f /. i by Th33; :: thesis: verum

end;

suppose ( f /. i is axltl1 or f /. i is axltl1a or f /. i is axltl2 or f /. i is axltl3 or f /. i is axltl4 or f /. i is axltl5 or f /. i is axltl6 ) ; :: thesis: F |= f /. i

hence F |= f /. i by Th37; :: thesis: verum

end;

end;

end;

suppose f . i in F ; :: thesis: F |= f /. i

then A9: f /. i in F by A6, A7, Lm1;
thus F |= f /. i :: thesis: verum

proof

let M be LTLModel; :: according to LTLAXIO1:def 14 :: thesis: ( M |= F implies M |= f /. i )
assume M |= F ; :: thesis: M |= f /. i
hence M |= f /. i by A9; :: thesis: verum

end;

end;

suppose ex j, k being Nat st
( 1 <= j & j < i & 1 <= k & k < i & ( f /. j,f /. k MP_rule f /. i or f /. j,f /. k IND_rule f /. i ) ) ; :: thesis: F |= f /. i

then consider j, k being Nat such that
A10: 1 <= j and
A11: j < i and
A12: 1 <= k and
A13: k < i and
A14: ( f /. j,f /. k MP_rule f /. i or f /. j,f /. k IND_rule f /. i ) ;
k <= len f by A7, A13, XXREAL_0:2;
then A15: F |= f /. k by A5, A12, A13;
A16: j <= len f by A7, A11, XXREAL_0:2;

per cases ( f /. j,f /. k MP_rule f /. i or f /. j,f /. k IND_rule f /. i ) by A14;

suppose f /. j,f /. k MP_rule f /. i ; :: thesis: F |= f /. i

then F |= (f /. j) => (f /. i) by A15;
hence F |= f /. i by A5, A10, A11, A16, Th24; :: thesis: verum

end;

suppose f /. j,f /. k IND_rule f /. i ; :: thesis: F |= f /. i

then consider A, B being Element of LTLB_WFF such that
A17: f /. j = A => B and
A18: ( f /. k = A => ('X' A) & f /. i = A => ('G' B) ) ;
F |= A => B by A5, A10, A11, A16, A17;
hence F |= f /. i by A15, A18, Th27; :: thesis: verum

end;

end;

end;

suppose ex j being Nat st
( 1 <= j & j < i & f /. j NEX_rule f /. i ) ; :: thesis: F |= f /. i

then consider j being Nat such that
A19: 1 <= j and
A20: j < i and
A21: f /. j NEX_rule f /. i ;
S₁[j] by A5, A20;
then F |= 'X' (f /. j) by A7, A19, A20, Th25, XXREAL_0:2;
hence F |= f /. i by A21; :: thesis: verum

end;

end;

end;

end;

end;

A22: for i being Nat holds S₁[i] from NAT_1:sch 4(A4);
f /. (len f) = A by A1, A2, Lm1;
hence F |= A by A2, A22; :: thesis: verum