let p be Real; :: thesis: ( p >= 1 implies for rseq being Real_Sequence st ( for n being Nat holds rseq . n = 0 ) holds
( rseq rto_power p is summable & (Sum (rseq rto_power p)) to_power (1 / p) = 0 ) )
assume A1: p >= 1 ; :: thesis: for rseq being Real_Sequence st ( for n being Nat holds rseq . n = 0 ) holds
( rseq rto_power p is summable & (Sum (rseq rto_power p)) to_power (1 / p) = 0 )
A2: 1 / p > 0 by A1, XREAL_1:139;
let rseq be Real_Sequence; :: thesis: ( ( for n being Nat holds rseq . n = 0 ) implies ( rseq rto_power p is summable & (Sum (rseq rto_power p)) to_power (1 / p) = 0 ) )
assume A3: for n being Nat holds rseq . n = 0 ; :: thesis: ( rseq rto_power p is summable & (Sum (rseq rto_power p)) to_power (1 / p) = 0 )
A4: for n being Nat holds (rseq rto_power p) . n = 0

proof

let n be Nat; :: thesis: (rseq rto_power p) . n = 0
rseq . n = 0 by A3;
then |.(rseq . n).| = 0 by ABSVALUE:2;
then |.(rseq . n).| to_power p = 0 by A1, POWER:def 2;
hence (rseq rto_power p) . n = 0 by Def1; :: thesis: verum

end;

A5: for m being Nat holds (Partial_Sums (rseq rto_power p)) . m = 0

proof

defpred S₁[ Nat] means (rseq rto_power p) . $1 = (Partial_Sums (rseq rto_power p)) . $1;
let m be Nat; :: thesis: (Partial_Sums (rseq rto_power p)) . m = 0
A6: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A7: (rseq rto_power p) . k = (Partial_Sums (rseq rto_power p)) . k ; :: thesis: S₁[k + 1]
thus (rseq rto_power p) . (k + 1) = 0 + ((rseq rto_power p) . (k + 1))
.= ((rseq rto_power p) . k) + ((rseq rto_power p) . (k + 1)) by A4
.= (Partial_Sums (rseq rto_power p)) . (k + 1) by A7, SERIES_1:def 1 ; :: thesis: verum

end;

A8: S₁[ 0 ] by SERIES_1:def 1;
for n being Nat holds S₁[n] from NAT_1:sch 2(A8, A6);
hence (Partial_Sums (rseq rto_power p)) . m = (rseq rto_power p) . m
.= 0 by A4 ;
:: thesis: verum

end;

A9: for e being Real st 0 < e holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e

proof

let e be Real; :: thesis: ( 0 < e implies ex n being Nat st
for m being Nat st n <= m holds
|.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e )
assume A10: 0 < e ; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
|.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e
take 0 ; :: thesis: for m being Nat st 0 <= m holds
|.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e
let m be Nat; :: thesis: ( 0 <= m implies |.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e )
assume 0 <= m ; :: thesis: |.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e
|.(((Partial_Sums (rseq rto_power p)) . m) - 0).| = |.(0 - 0).| by A5
.= 0 by ABSVALUE:def 1 ;
hence |.(((Partial_Sums (rseq rto_power p)) . m) - 0).| < e by A10; :: thesis: verum

end;

then A11: Partial_Sums (rseq rto_power p) is convergent by SEQ_2:def 6;
then lim (Partial_Sums (rseq rto_power p)) = 0 by A9, SEQ_2:def 7;
then Sum (rseq rto_power p) = 0 by SERIES_1:def 3;
hence ( rseq rto_power p is summable & (Sum (rseq rto_power p)) to_power (1 / p) = 0 ) by A2, A11, POWER:def 2, SERIES_1:def 2; :: thesis: verum