let X be RealNormSpace-Sequence; :: thesis: for Y being RealNormSpace
for f, g being Point of (R_NormSpace_of_BoundedMultilinearOperators (X,Y))
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let Y be RealNormSpace; :: thesis: for f, g being Point of (R_NormSpace_of_BoundedMultilinearOperators (X,Y))
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (R_NormSpace_of_BoundedMultilinearOperators (X,Y)); :: thesis: for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let a be Real; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
A2: now :: thesis: ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies ||.f.|| = 0 )
assume A3: f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum
proof
reconsider g = f as Lipschitzian MultilinearOperator of X,Y by Def9;
set z = the carrier of (product X) --> (0. Y);
reconsider z = the carrier of (product X) --> (0. Y) as Function of the carrier of (product X), the carrier of Y ;
consider r0 being object such that
A4: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A4;
A5: ( ( for s being Real st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
A6: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th27;
A7: z = g by A3, Th31;
A8: now :: thesis: for r being Real st r in PreNorms g holds
( 0 <= r & r <= 0 )
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being VECTOR of (product X) such that
A9: r = ||.(g . t).|| and
for i being Element of dom X holds ||.(t . i).|| <= 1 ;
||.(g . t).|| = ||.(0. Y).|| by A7, FUNCOP_1:7
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A9; :: thesis: verum
end;
then 0 <= r0 by A4;
then upper_bound (PreNorms g) = 0 by A4, A5, A6, A8, SEQ_4:def 1;
hence ||.f.|| = 0 by Th30; :: thesis: verum
end;
end;
A11: ||.(f + g).|| <= ||.f.|| + ||.g.||
proof
reconsider f1 = f, g1 = g, h1 = f + g as Lipschitzian MultilinearOperator of X,Y by Def9;
A12: ( ( for s being Real st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies upper_bound (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:45;
A13: now :: thesis: for t being VECTOR of (product X) st ( for i being Element of dom X holds ||.(t . i).|| <= 1 ) holds
||.(h1 . t).|| <= ||.f.|| + ||.g.||
let t be VECTOR of (product X); :: thesis: ( ( for i being Element of dom X holds ||.(t . i).|| <= 1 ) implies ||.(h1 . t).|| <= ||.f.|| + ||.g.|| )
assume A14: for i being Element of dom X holds ||.(t . i).|| <= 1 ; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
A15: ( 0 <= NrProduct t & NrProduct t <= 1 ) by A14, LM28;
0 <= ||.g.|| by Th33;
then A16: ||.g.|| * (NrProduct t) <= ||.g.|| * 1 by A15, XREAL_1:64;
0 <= ||.f.|| by Th33;
then ||.f.|| * (NrProduct t) <= ||.f.|| * 1 by A15, XREAL_1:64;
then A17: (||.f.|| * (NrProduct t)) + (||.g.|| * (NrProduct t)) <= (||.f.|| * 1) + (||.g.|| * 1) by A16, XREAL_1:7;
A18: ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| by NORMSP_1:def 1;
A19: ||.(g1 . t).|| <= ||.g.|| * (NrProduct t) by Th32;
||.(f1 . t).|| <= ||.f.|| * (NrProduct t) by Th32;
then ||.(f1 . t).|| + ||.(g1 . t).|| <= (||.f.|| * (NrProduct t)) + (||.g.|| * (NrProduct t)) by A19, XREAL_1:7;
then A20: ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by A17, XXREAL_0:2;
||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| by Th35;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A18, A20, XXREAL_0:2; :: thesis: verum
end;
now :: thesis: for r being Real st r in PreNorms h1 holds
r <= ||.f.|| + ||.g.||
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
then consider t being VECTOR of (product X) such that
A22: r = ||.(h1 . t).|| and
A23: for i being Element of dom X holds ||.(t . i).|| <= 1 ;
thus r <= ||.f.|| + ||.g.|| by A13, A22, A23; :: thesis: verum
end;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A12, Th30; :: thesis: verum
end;
reconsider f1 = f, h1 = a * f as Lipschitzian MultilinearOperator of X,Y by Def9;
A25: ( ( for s being Real st s in PreNorms h1 holds
s <= |.a.| * ||.f.|| ) implies upper_bound (PreNorms h1) <= |.a.| * ||.f.|| ) by SEQ_4:45;
A24: ||.(a * f).|| = |.a.| * ||.f.||
proof
A26: now :: thesis: for t being VECTOR of (product X) st ( for i being Element of dom X holds ||.(t . i).|| <= 1 ) holds
||.(h1 . t).|| <= |.a.| * ||.f.||
A27: 0 <= ||.f.|| by Th33;
let t be VECTOR of (product X); :: thesis: ( ( for i being Element of dom X holds ||.(t . i).|| <= 1 ) implies ||.(h1 . t).|| <= |.a.| * ||.f.|| )
assume A28: for i being Element of dom X holds ||.(t . i).|| <= 1 ; :: thesis: ||.(h1 . t).|| <= |.a.| * ||.f.||
NrProduct t <= 1 by A28, LM28;
then A29: ||.f.|| * (NrProduct t) <= ||.f.|| * 1 by A27, XREAL_1:64;
||.(f1 . t).|| <= ||.f.|| * (NrProduct t) by Th32;
then A30: ||.(f1 . t).|| <= ||.f.|| by A29, XXREAL_0:2;
A31: ||.(a * (f1 . t)).|| = |.a.| * ||.(f1 . t).|| by NORMSP_1:def 1;
A32: 0 <= |.a.| by COMPLEX1:46;
||.(h1 . t).|| = ||.(a * (f1 . t)).|| by Th36;
hence ||.(h1 . t).|| <= |.a.| * ||.f.|| by A30, A31, A32, XREAL_1:64; :: thesis: verum
end;
A33: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= |.a.| * ||.f.||
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= |.a.| * ||.f.|| )
assume r in PreNorms h1 ; :: thesis: r <= |.a.| * ||.f.||
then consider t being VECTOR of (product X) such that
A34: r = ||.(h1 . t).|| and
A35: for i being Element of dom X holds ||.(t . i).|| <= 1 ;
thus r <= |.a.| * ||.f.|| by A26, A34, A35; :: thesis: verum
end;
A36: now :: thesis: ( ( a <> 0 & |.a.| * ||.f.|| <= ||.(a * f).|| ) or ( a = 0 & |.a.| * ||.f.|| = ||.(a * f).|| ) )
per cases ( a <> 0 or a = 0 ) ;
case A37: a <> 0 ; :: thesis: |.a.| * ||.f.|| <= ||.(a * f).||
A38: now :: thesis: for t being VECTOR of (product X) st ( for i being Element of dom X holds ||.(t . i).|| <= 1 ) holds
||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).||
A39: 0 <= ||.(a * f).|| by Th33;
let t be VECTOR of (product X); :: thesis: ( ( for i being Element of dom X holds ||.(t . i).|| <= 1 ) implies ||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).|| )
assume for i being Element of dom X holds ||.(t . i).|| <= 1 ; :: thesis: ||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).||
then NrProduct t <= 1 by LM28;
then A41: ||.(a * f).|| * (NrProduct t) <= ||.(a * f).|| * 1 by A39, XREAL_1:64;
||.(h1 . t).|| <= ||.(a * f).|| * (NrProduct t) by Th32;
then A42: ||.(h1 . t).|| <= ||.(a * f).|| by A41, XXREAL_0:2;
h1 . t = a * (f1 . t) by Th36;
then A43: (a ") * (h1 . t) = ((a ") * a) * (f1 . t) by RLVECT_1:def 7
.= 1 * (f1 . t) by A37, XCMPLX_0:def 7
.= f1 . t by RLVECT_1:def 8 ;
A44: |.(a ").| = |.(1 * (a ")).|
.= |.(1 / a).| by XCMPLX_0:def 9
.= 1 / |.a.| by ABSVALUE:7
.= 1 * (|.a.| ") by XCMPLX_0:def 9
.= |.a.| " ;
A45: 0 <= |.(a ").| by COMPLEX1:46;
||.((a ") * (h1 . t)).|| = |.(a ").| * ||.(h1 . t).|| by NORMSP_1:def 1;
hence ||.(f1 . t).|| <= (|.a.| ") * ||.(a * f).|| by A42, A43, A44, A45, XREAL_1:64; :: thesis: verum
end;
A46: now :: thesis: for r being Real st r in PreNorms f1 holds
r <= (|.a.| ") * ||.(a * f).||
let r be Real; :: thesis: ( r in PreNorms f1 implies r <= (|.a.| ") * ||.(a * f).|| )
assume r in PreNorms f1 ; :: thesis: r <= (|.a.| ") * ||.(a * f).||
then consider t being VECTOR of (product X) such that
A47: r = ||.(f1 . t).|| and
A48: for i being Element of dom X holds ||.(t . i).|| <= 1 ;
thus r <= (|.a.| ") * ||.(a * f).|| by A38, A47, A48; :: thesis: verum
end;
A49: ( ( for s being Real st s in PreNorms f1 holds
s <= (|.a.| ") * ||.(a * f).|| ) implies upper_bound (PreNorms f1) <= (|.a.| ") * ||.(a * f).|| ) by SEQ_4:45;
A50: 0 <= |.a.| by COMPLEX1:46;
||.f.|| <= (|.a.| ") * ||.(a * f).|| by A46, A49, Th30;
then |.a.| * ||.f.|| <= |.a.| * ((|.a.| ") * ||.(a * f).||) by A50, XREAL_1:64;
then A51: |.a.| * ||.f.|| <= (|.a.| * (|.a.| ")) * ||.(a * f).|| ;
|.a.| <> 0 by A37, COMPLEX1:47;
then |.a.| * ||.f.|| <= 1 * ||.(a * f).|| by A51, XCMPLX_0:def 7;
hence |.a.| * ||.f.|| <= ||.(a * f).|| ; :: thesis: verum
end;
end;
end;
||.(a * f).|| <= |.a.| * ||.f.|| by A25, A33, Th30;
hence ||.(a * f).|| = |.a.| * ||.f.|| by A36, XXREAL_0:1; :: thesis: verum
end;
now :: thesis: ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) )
reconsider g = f as Lipschitzian MultilinearOperator of X,Y by Def9;
set z = the carrier of (product X) --> (0. Y);
reconsider z = the carrier of (product X) --> (0. Y) as Function of the carrier of (product X), the carrier of Y ;
assume A54: ||.f.|| = 0 ; :: thesis: f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y))
now :: thesis: for t being VECTOR of (product X) holds g . t = z . t
let t be VECTOR of (product X); :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| * (NrProduct t) by Th32;
then ||.(g . t).|| = 0 by A54;
hence g . t = 0. Y by NORMSP_0:def 5
.= z . t by FUNCOP_1:7 ;
:: thesis: verum
end;
then g = z by FUNCT_2:63;
hence f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) by Th31; :: thesis: verum
end;
hence ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = |.a.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A2, A11, A24; :: thesis: verum