let x0 be Real; :: thesis: for f being PartFunc of REAL,REAL st f is_right_convergent_in x0 & f " {0} = {} & lim_right (f,x0) <> 0 holds
( f ^ is_right_convergent_in x0 & lim_right ((f ^),x0) = (lim_right (f,x0)) " )
let f be PartFunc of REAL,REAL; :: thesis: ( f is_right_convergent_in x0 & f " {0} = {} & lim_right (f,x0) <> 0 implies ( f ^ is_right_convergent_in x0 & lim_right ((f ^),x0) = (lim_right (f,x0)) " ) )
assume that
A1: f is_right_convergent_in x0 and
A2: f " {0} = {} and
A3: lim_right (f,x0) <> 0 ; :: thesis: ( f ^ is_right_convergent_in x0 & lim_right ((f ^),x0) = (lim_right (f,x0)) " )
A4: dom f = (dom f) \ (f " {0}) by A2
.= dom (f ^) by RFUNCT_1:def 2 ;

A5: now :: thesis: for seq being Real_Sequence st seq is convergent & lim seq = x0 & rng seq c= (dom (f ^)) /\ (right_open_halfline x0) holds
( (f ^) /* seq is convergent & lim ((f ^) /* seq) = (lim_right (f,x0)) " )

let seq be Real_Sequence; :: thesis: ( seq is convergent & lim seq = x0 & rng seq c= (dom (f ^)) /\ (right_open_halfline x0) implies ( (f ^) /* seq is convergent & lim ((f ^) /* seq) = (lim_right (f,x0)) " ) )
assume that
A6: seq is convergent and
A7: lim seq = x0 and
A8: rng seq c= (dom (f ^)) /\ (right_open_halfline x0) ; :: thesis: ( (f ^) /* seq is convergent & lim ((f ^) /* seq) = (lim_right (f,x0)) " )
A9: lim (f /* seq) = lim_right (f,x0) by A1, A4, A6, A7, A8, Def8;
A10: (dom f) /\ (right_open_halfline x0) c= dom f by XBOOLE_1:17;
then A11: rng seq c= dom f by A4, A8, XBOOLE_1:1;
A12: f /* seq is convergent by A1, A4, A6, A7, A8;
A13: (f /* seq) " = (f ^) /* seq by A4, A8, A10, RFUNCT_2:12, XBOOLE_1:1;
hence (f ^) /* seq is convergent by A3, A4, A12, A9, A11, RFUNCT_2:11, SEQ_2:21; :: thesis: lim ((f ^) /* seq) = (lim_right (f,x0)) "
thus lim ((f ^) /* seq) = (lim_right (f,x0)) " by A3, A4, A12, A9, A11, A13, RFUNCT_2:11, SEQ_2:22; :: thesis: verum

end;

for r being Real st x0 < r holds
ex g being Real st
( g < r & x0 < g & g in dom (f ^) ) by A1, A4;
hence f ^ is_right_convergent_in x0 by A5; :: thesis: lim_right ((f ^),x0) = (lim_right (f,x0)) "
hence lim_right ((f ^),x0) = (lim_right (f,x0)) " by A5, Def8; :: thesis: verum