let g, x0 be Real; :: thesis: for f being PartFunc of REAL,REAL st f is_left_convergent_in x0 holds
( lim_left (f,x0) = g iff for g1 being Real st 0 < g1 holds
ex r being Real st
( r < x0 & ( for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 ) ) )
let f be PartFunc of REAL,REAL; :: thesis: ( f is_left_convergent_in x0 implies ( lim_left (f,x0) = g iff for g1 being Real st 0 < g1 holds
ex r being Real st
( r < x0 & ( for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 ) ) ) )
assume A1: f is_left_convergent_in x0 ; :: thesis: ( lim_left (f,x0) = g iff for g1 being Real st 0 < g1 holds
ex r being Real st
( r < x0 & ( for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 ) ) )
thus ( lim_left (f,x0) = g implies for g1 being Real st 0 < g1 holds
ex r being Real st
( r < x0 & ( for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 ) ) ) :: thesis: ( ( for g1 being Real st 0 < g1 holds
ex r being Real st
( r < x0 & ( for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 ) ) ) implies lim_left (f,x0) = g )

proof

assume that
A2: lim_left (f,x0) = g and
A3: ex g1 being Real st
( 0 < g1 & ( for r being Real st r < x0 holds
ex r1 being Real st
( r < r1 & r1 < x0 & r1 in dom f & |.((f . r1) - g).| >= g1 ) ) ) ; :: thesis: contradiction
consider g1 being Real such that
A4: 0 < g1 and
A5: for r being Real st r < x0 holds
ex r1 being Real st
( r < r1 & r1 < x0 & r1 in dom f & |.((f . r1) - g).| >= g1 ) by A3;
defpred S₁[ Nat, Real] means ( x0 - (1 / ($1 + 1)) < $2 & $2 < x0 & $2 in dom f & |.((f . $2) - g).| >= g1 );

A6: now :: thesis: for n being Element of NAT ex g2 being Element of REAL st S₁[n,g2]

let n be Element of NAT ; :: thesis: ex g2 being Element of REAL st S₁[n,g2]
x0 - (1 / (n + 1)) < x0 by Lm3;
then consider g2 being Real such that
A7: x0 - (1 / (n + 1)) < g2 and
A8: g2 < x0 and
A9: g2 in dom f and
A10: |.((f . g2) - g).| >= g1 by A5;
reconsider g2 = g2 as Element of REAL by XREAL_0:def 1;
take g2 = g2; :: thesis: S₁[n,g2]
thus S₁[n,g2] by A7, A8, A9, A10; :: thesis: verum

end;

consider s being Real_Sequence such that
A11: for n being Element of NAT holds S₁[n,s . n] from FUNCT_2:sch 3(A6);
A12: for n being Nat holds S₁[n,s . n]

proof

let n be Nat; :: thesis: S₁[n,s . n]
n in NAT by ORDINAL1:def 12;
hence S₁[n,s . n] by A11; :: thesis: verum

end;

A13: rng s c= (dom f) /\ (left_open_halfline x0) by A12, Th5;
A14: lim s = x0 by A12, Th5;
A15: s is convergent by A12, Th5;
then A16: lim (f /* s) = g by A1, A2, A14, A13, Def7;
f /* s is convergent by A1, A15, A14, A13;
then consider n being Nat such that
A17: for k being Nat st n <= k holds
|.(((f /* s) . k) - g).| < g1 by A4, A16, SEQ_2:def 7;
A18: |.(((f /* s) . n) - g).| < g1 by A17;
A19: n in NAT by ORDINAL1:def 12;
rng s c= dom f by A12, Th5;
then |.((f . (s . n)) - g).| < g1 by A18, FUNCT_2:108, A19;
hence contradiction by A12; :: thesis: verum

end;

assume A20: for g1 being Real st 0 < g1 holds
ex r being Real st
( r < x0 & ( for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 ) ) ; :: thesis: lim_left (f,x0) = g
reconsider g = g as Real ;

now :: thesis: for s being Real_Sequence st s is convergent & lim s = x0 & rng s c= (dom f) /\ (left_open_halfline x0) holds
( f /* s is convergent & lim (f /* s) = g )

let s be Real_Sequence; :: thesis: ( s is convergent & lim s = x0 & rng s c= (dom f) /\ (left_open_halfline x0) implies ( f /* s is convergent & lim (f /* s) = g ) )
assume that
A21: s is convergent and
A22: lim s = x0 and
A23: rng s c= (dom f) /\ (left_open_halfline x0) ; :: thesis: ( f /* s is convergent & lim (f /* s) = g )
A24: (dom f) /\ (left_open_halfline x0) c= dom f by XBOOLE_1:17;

A25: now :: thesis: for g1 being Real st 0 < g1 holds
ex n being Nat st
for k being Nat st n <= k holds
|.(((f /* s) . k) - g).| < g1

let g1 be Real; :: thesis: ( 0 < g1 implies ex n being Nat st
for k being Nat st n <= k holds
|.(((f /* s) . k) - g).| < g1 )
assume A26: 0 < g1 ; :: thesis: ex n being Nat st
for k being Nat st n <= k holds
|.(((f /* s) . k) - g).| < g1
consider r being Real such that
A27: r < x0 and
A28: for r1 being Real st r < r1 & r1 < x0 & r1 in dom f holds
|.((f . r1) - g).| < g1 by A20, A26;
consider n being Nat such that
A29: for k being Nat st n <= k holds
r < s . k by A21, A22, A27, Th1;
take n = n; :: thesis: for k being Nat st n <= k holds
|.(((f /* s) . k) - g).| < g1
let k be Nat; :: thesis: ( n <= k implies |.(((f /* s) . k) - g).| < g1 )
assume A30: n <= k ; :: thesis: |.(((f /* s) . k) - g).| < g1
A31: s . k in rng s by VALUED_0:28;
then s . k in left_open_halfline x0 by A23, XBOOLE_0:def 4;
then s . k in { g2 where g2 is Real : g2 < x0 } by XXREAL_1:229;
then A32: ex g2 being Real st
( g2 = s . k & g2 < x0 ) ;
A33: k in NAT by ORDINAL1:def 12;
s . k in dom f by A23, A31, XBOOLE_0:def 4;
then |.((f . (s . k)) - g).| < g1 by A28, A29, A30, A32;
hence |.(((f /* s) . k) - g).| < g1 by A23, A24, FUNCT_2:108, XBOOLE_1:1, A33; :: thesis: verum

end;

hence f /* s is convergent by SEQ_2:def 6; :: thesis: lim (f /* s) = g
hence lim (f /* s) = g by A25, SEQ_2:def 7; :: thesis: verum

end;

hence lim_left (f,x0) = g by A1, Def7; :: thesis: verum