let f be PartFunc of REAL,REAL; :: thesis: ( f is divergent_in+infty_to+infty iff ( ( for r being Real ex g being Real st
( r < g & g in dom f ) ) & ( for g being Real ex r being Real st
for r1 being Real st r < r1 & r1 in dom f holds
g < f . r1 ) ) )
thus ( f is divergent_in+infty_to+infty implies ( ( for r being Real ex g being Real st
( r < g & g in dom f ) ) & ( for g being Real ex r being Real st
for r1 being Real st r < r1 & r1 in dom f holds
g < f . r1 ) ) ) :: thesis: ( ( for r being Real ex g being Real st
( r < g & g in dom f ) ) & ( for g being Real ex r being Real st
for r1 being Real st r < r1 & r1 in dom f holds
g < f . r1 ) implies f is divergent_in+infty_to+infty )

proof

assume A1: f is divergent_in+infty_to+infty ; :: thesis: ( ( for r being Real ex g being Real st
( r < g & g in dom f ) ) & ( for g being Real ex r being Real st
for r1 being Real st r < r1 & r1 in dom f holds
g < f . r1 ) )
assume ( ex r being Real st
for g being Real holds
( not r < g or not g in dom f ) or ex g being Real st
for r being Real ex r1 being Real st
( r < r1 & r1 in dom f & g >= f . r1 ) ) ; :: thesis: contradiction
then consider g being Real such that
A2: for r being Real ex r1 being Real st
( r < r1 & r1 in dom f & g >= f . r1 ) by A1;
defpred S₁[ Nat, Real] means ( $1 < $2 & $2 in dom f & g >= f . $2 );
A3: for n being Element of NAT ex r being Element of REAL st S₁[n,r]

proof

let n be Element of NAT ; :: thesis: ex r being Element of REAL st S₁[n,r]
consider r being Real such that
A4: S₁[n,r] by A2;
reconsider r = r as Real ;
S₁[n,r] by A4;
hence ex r being Element of REAL st S₁[n,r] ; :: thesis: verum

end;

consider s being Real_Sequence such that
A5: for n being Element of NAT holds S₁[n,s . n] from FUNCT_2:sch 3(A3);

now :: thesis: for x being object st x in rng s holds
x in dom f

let x be object ; :: thesis: ( x in rng s implies x in dom f )
assume x in rng s ; :: thesis: x in dom f
then ex n being Element of NAT st s . n = x by FUNCT_2:113;
hence x in dom f by A5; :: thesis: verum

end;

then A6: rng s c= dom f ;

now :: thesis: for n being Nat holds s1 . n <= s . n

let n be Nat; :: thesis: s1 . n <= s . n
A7: n in NAT by ORDINAL1:def 12;
n < s . n by A5, A7;
hence s1 . n <= s . n by FUNCT_1:18, A7; :: thesis: verum

end;

then s is divergent_to+infty by Lm5, Th20, Th42;
then f /* s is divergent_to+infty by A1, A6;
then consider n being Nat such that
A8: for m being Nat st n <= m holds
g < (f /* s) . m ;
A9: n in NAT by ORDINAL1:def 12;
g < (f /* s) . n by A8;
then g < f . (s . n) by A6, FUNCT_2:108, A9;
hence contradiction by A5, A9; :: thesis: verum

end;

assume that
A10: for r being Real ex g being Real st
( r < g & g in dom f ) and
A11: for g being Real ex r being Real st
for r1 being Real st r < r1 & r1 in dom f holds
g < f . r1 ; :: thesis: f is divergent_in+infty_to+infty

now :: thesis: for s being Real_Sequence st s is divergent_to+infty & rng s c= dom f holds
f /* s is divergent_to+infty

let s be Real_Sequence; :: thesis: ( s is divergent_to+infty & rng s c= dom f implies f /* s is divergent_to+infty )
assume that
A12: s is divergent_to+infty and
A13: rng s c= dom f ; :: thesis: f /* s is divergent_to+infty

now :: thesis: for g being Real ex n being Nat st
for m being Nat st n <= m holds
g < (f /* s) . m

let g be Real; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
g < (f /* s) . m
consider r being Real such that
A14: for r1 being Real st r < r1 & r1 in dom f holds
g < f . r1 by A11;
consider n being Nat such that
A15: for m being Nat st n <= m holds
r < s . m by A12;
take n = n; :: thesis: for m being Nat st n <= m holds
g < (f /* s) . m
let m be Nat; :: thesis: ( n <= m implies g < (f /* s) . m )
A16: s . m in rng s by VALUED_0:28;
A17: m in NAT by ORDINAL1:def 12;
assume n <= m ; :: thesis: g < (f /* s) . m
then g < f . (s . m) by A13, A14, A15, A16;
hence g < (f /* s) . m by A13, FUNCT_2:108, A17; :: thesis: verum

end;

hence f /* s is divergent_to+infty ; :: thesis: verum

end;

hence f is divergent_in+infty_to+infty by A10; :: thesis: verum