let f be FinSequence of (TOP-REAL 2); :: thesis: ( f is special & f is weakly-one-to-one implies for p, q being Point of (TOP-REAL 2) st p in L~ f & q in L~ f holds
B_Cut (f,p,q) is special )
assume A1: ( f is special & f is weakly-one-to-one ) ; :: thesis: for p, q being Point of (TOP-REAL 2) st p in L~ f & q in L~ f holds
B_Cut (f,p,q) is special
let p, q be Point of (TOP-REAL 2); :: thesis: ( p in L~ f & q in L~ f implies B_Cut (f,p,q) is special )
assume that
A2: p in L~ f and
A3: q in L~ f ; :: thesis: B_Cut (f,p,q) is special
A4: Index (p,f) < len f by A2, JORDAN3:8;
A5: 1 <= Index (p,f) by A2, JORDAN3:8;
then A6: Index (p,f) in dom f by A4, FINSEQ_3:25;

per cases ( p <> q or p = q ) ;

suppose A7: p <> q ; :: thesis: B_Cut (f,p,q) is special

now :: thesis: B_Cut (f,p,q) is special

per cases ( ( p in L~ f & q in L~ f & Index (p,f) < Index (q,f) ) or ( Index (p,f) = Index (q,f) & LE p,q,f /. (Index (p,f)),f /. ((Index (p,f)) + 1) ) or ( not ( p in L~ f & q in L~ f & Index (p,f) < Index (q,f) ) & not ( Index (p,f) = Index (q,f) & LE p,q,f /. (Index (p,f)),f /. ((Index (p,f)) + 1) ) ) ) ;

suppose A8: ( p in L~ f & q in L~ f & Index (p,f) < Index (q,f) ) ; :: thesis: B_Cut (f,p,q) is special

then A9: q in L~ (L_Cut (f,p)) by JORDAN3:29;
L_Cut (f,p) is special by A1, A2, Th29;
then R_Cut ((L_Cut (f,p)),q) is special by A9, Th30;
hence B_Cut (f,p,q) is special by A8, JORDAN3:def 7; :: thesis: verum

end;

suppose A10: ( Index (p,f) = Index (q,f) & LE p,q,f /. (Index (p,f)),f /. ((Index (p,f)) + 1) ) ; :: thesis: B_Cut (f,p,q) is special

A11: L_Cut (f,p) is special by A1, A2, Th29;
q in L~ (L_Cut (f,p)) by A2, A3, A7, A10, JORDAN3:31;
then R_Cut ((L_Cut (f,p)),q) is special by A11, Th30;
hence B_Cut (f,p,q) is special by A10, JORDAN3:def 7; :: thesis: verum

end;

suppose A12: ( not ( p in L~ f & q in L~ f & Index (p,f) < Index (q,f) ) & not ( Index (p,f) = Index (q,f) & LE p,q,f /. (Index (p,f)),f /. ((Index (p,f)) + 1) ) ) ; :: thesis: B_Cut (f,p,q) is special

A13: now :: thesis: p in L~ (L_Cut (f,q))

per cases ( Index (q,f) < Index (p,f) or Index (q,f) = Index (p,f) ) by A2, A3, A12, XXREAL_0:1;

suppose Index (q,f) < Index (p,f) ; :: thesis: p in L~ (L_Cut (f,q))

hence p in L~ (L_Cut (f,q)) by A2, A3, JORDAN3:29; :: thesis: verum

end;

suppose A14: Index (q,f) = Index (p,f) ; :: thesis: p in L~ (L_Cut (f,q))

A15: (Index (p,f)) + 1 >= 1 by NAT_1:11;
(Index (p,f)) + 1 <= len f by A4, NAT_1:13;
then A16: (Index (p,f)) + 1 in dom f by A15, FINSEQ_3:25;
set Ls = LSeg ((f /. (Index (p,f))),(f /. ((Index (p,f)) + 1)));
A17: q in LSeg ((f /. (Index (p,f))),(f /. ((Index (p,f)) + 1))) by A3, A14, JORDAN5B:29;
A18: p in LSeg ((f /. (Index (p,f))),(f /. ((Index (p,f)) + 1))) by A2, JORDAN5B:29;
f . (Index (p,f)) <> f . ((Index (p,f)) + 1) by A1, A5, A4;
then f . (Index (p,f)) <> f /. ((Index (p,f)) + 1) by A16, PARTFUN1:def 6;
then A19: f /. (Index (p,f)) <> f /. ((Index (p,f)) + 1) by A6, PARTFUN1:def 6;
then A20: LSeg ((f /. (Index (p,f))),(f /. ((Index (p,f)) + 1))) is_an_arc_of f /. (Index (p,f)),f /. ((Index (p,f)) + 1) by TOPREAL1:9;
not LE p,q, LSeg ((f /. (Index (p,f))),(f /. ((Index (p,f)) + 1))),f /. (Index (p,f)),f /. ((Index (p,f)) + 1) by A12, A14, A19, JORDAN5C:17;
then LE q,p, LSeg ((f /. (Index (p,f))),(f /. ((Index (p,f)) + 1))),f /. (Index (p,f)),f /. ((Index (p,f)) + 1) by A7, A20, A18, A17, JORDAN5C:14;
hence p in L~ (L_Cut (f,q)) by A2, A3, A7, A14, A19, JORDAN3:31, JORDAN5C:17; :: thesis: verum

end;

end;

end;

A21: B_Cut (f,p,q) = Rev (R_Cut ((L_Cut (f,q)),p)) by A12, JORDAN3:def 7;
L_Cut (f,q) is special by A1, A3, Th29;
then R_Cut ((L_Cut (f,q)),p) is special by A13, Th30;
hence B_Cut (f,p,q) is special by A21, SPPOL_2:40; :: thesis: verum

end;

end;

end;

hence B_Cut (f,p,q) is special ; :: thesis: verum

end;

suppose p = q ; :: thesis: B_Cut (f,p,q) is special

then B_Cut (f,p,q) = <*p*> by A1, A2, Th15;
hence B_Cut (f,p,q) is special ; :: thesis: verum

end;

end;