set X = south_halfline a;
reconsider XX = (south_halfline a) ` as Subset of (TOP-REAL 2) ;
reconsider OO = XX as Subset of (TopSpaceMetr (Euclid 2)) by Lm3;
for p being Point of (Euclid 2) st p in (south_halfline a) ` holds
ex r being Real st
( r > 0 & Ball (p,r) c= (south_halfline a) ` )

proof

let p be Point of (Euclid 2); :: thesis: ( p in (south_halfline a) ` implies ex r being Real st
( r > 0 & Ball (p,r) c= (south_halfline a) ` ) )
reconsider x = p as Point of (TOP-REAL 2) by EUCLID:67;
assume p in (south_halfline a) ` ; :: thesis: ex r being Real st
( r > 0 & Ball (p,r) c= (south_halfline a) ` )
then A17: not p in south_halfline a by XBOOLE_0:def 5;

per cases ( x `1 <> a `1 or x `2 > a `2 ) by A17, TOPREAL1:def 12;

suppose A18: x `1 <> a `1 ; :: thesis: ex r being Real st
( r > 0 & Ball (p,r) c= (south_halfline a) ` )

take r = |.((x `1) - (a `1)).|; :: thesis: ( r > 0 & Ball (p,r) c= (south_halfline a) ` )
(x `1) - (a `1) <> 0 by A18;
hence r > 0 by COMPLEX1:47; :: thesis: Ball (p,r) c= (south_halfline a) `
let b be object ; :: according to TARSKI:def 3 :: thesis: ( not b in Ball (p,r) or b in (south_halfline a) ` )
assume A19: b in Ball (p,r) ; :: thesis: b in (south_halfline a) `
then reconsider b = b as Point of (Euclid 2) ;
reconsider c = b as Point of (TOP-REAL 2) by EUCLID:67;
dist (p,b) < r by A19, METRIC_1:11;
then A20: dist (x,c) < r by TOPREAL6:def 1;

now :: thesis: not c `1 = a `1

assume c `1 = a `1 ; :: thesis: contradiction
then A21: sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2)) < |.((x `1) - (c `1)).| by A20, TOPREAL6:92;
A22: 0 <= ((x `1) - (c `1)) ^2 by XREAL_1:63;
A23: 0 <= ((x `2) - (c `2)) ^2 by XREAL_1:63;
then 0 <= sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2)) by A22, SQUARE_1:def 2;
then (sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2))) ^2 < |.((x `1) - (c `1)).| ^2 by A21, SQUARE_1:16;
then (sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2))) ^2 < ((x `1) - (c `1)) ^2 by COMPLEX1:75;
then (((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2) < (((x `1) - (c `1)) ^2) + 0 by A22, SQUARE_1:def 2;
hence contradiction by A23, XREAL_1:7; :: thesis: verum

end;

then not c in south_halfline a by TOPREAL1:def 12;
hence b in (south_halfline a) ` by XBOOLE_0:def 5; :: thesis: verum

end;

suppose A24: x `2 > a `2 ; :: thesis: ex r being Real st
( r > 0 & Ball (p,r) c= (south_halfline a) ` )

take r = (x `2) - (a `2); :: thesis: ( r > 0 & Ball (p,r) c= (south_halfline a) ` )
thus r > 0 by A24, XREAL_1:50; :: thesis: Ball (p,r) c= (south_halfline a) `
let b be object ; :: according to TARSKI:def 3 :: thesis: ( not b in Ball (p,r) or b in (south_halfline a) ` )
assume A25: b in Ball (p,r) ; :: thesis: b in (south_halfline a) `
then reconsider b = b as Point of (Euclid 2) ;
reconsider c = b as Point of (TOP-REAL 2) by EUCLID:67;
dist (p,b) < r by A25, METRIC_1:11;
then A26: dist (x,c) < r by TOPREAL6:def 1;

now :: thesis: not c `2 <= a `2

assume c `2 <= a `2 ; :: thesis: contradiction
then A27: (x `2) - (c `2) >= (x `2) - (a `2) by XREAL_1:13;
0 <= (x `2) - (a `2) by A24, XREAL_1:50;
then A28: ((x `2) - (a `2)) ^2 <= ((x `2) - (c `2)) ^2 by A27, SQUARE_1:15;
A29: 0 <= ((x `1) - (c `1)) ^2 by XREAL_1:63;
A30: sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2)) < (x `2) - (a `2) by A26, TOPREAL6:92;
A31: 0 <= ((x `2) - (c `2)) ^2 by XREAL_1:63;
then 0 <= sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2)) by A29, SQUARE_1:def 2;
then (sqrt ((((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2))) ^2 < ((x `2) - (a `2)) ^2 by A30, SQUARE_1:16;
then A32: (((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2) < ((x `2) - (a `2)) ^2 by A29, A31, SQUARE_1:def 2;
0 + (((x `2) - (c `2)) ^2) <= (((x `1) - (c `1)) ^2) + (((x `2) - (c `2)) ^2) by A29, XREAL_1:7;
hence contradiction by A32, A28, XXREAL_0:2; :: thesis: verum

end;

then not c in south_halfline a by TOPREAL1:def 12;
hence b in (south_halfline a) ` by XBOOLE_0:def 5; :: thesis: verum

end;

end;

end;

then OO is open by TOPMETR:15;
then XX is open by Lm3, PRE_TOPC:30;
then XX ` is closed ;
hence south_halfline a is closed ; :: thesis: verum