let X be non empty TopSpace; :: thesis: for f1 being Function of X,R^1
for a being Real st f1 is continuous holds
ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being Real st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous )
let f1 be Function of X,R^1; :: thesis: for a being Real st f1 is continuous holds
ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being Real st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous )
let a be Real; :: thesis: ( f1 is continuous implies ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being Real st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous ) )
defpred S₁[ set , set ] means for r1 being Real st f1 . $1 = r1 holds
$2 = r1 + a;
A1: for x being Element of X ex y being Element of REAL st S₁[x,y]

proof

reconsider r2 = a as Element of REAL by XREAL_0:def 1;
let x be Element of X; :: thesis: ex y being Element of REAL st S₁[x,y]
reconsider r1 = f1 . x as Element of REAL by TOPMETR:17;
set r3 = r1 + r2;
for r1 being Real st f1 . x = r1 holds
r1 + r2 = r1 + r2 ;
hence ex y being Element of REAL st
for r1 being Real st f1 . x = r1 holds
y = r1 + a ; :: thesis: verum

end;

ex f being Function of the carrier of X,REAL st
for x being Element of X holds S₁[x,f . x] from FUNCT_2:sch 3(A1);
then consider f being Function of the carrier of X,REAL such that
A2: for x being Element of X
for r1 being Real st f1 . x = r1 holds
f . x = r1 + a ;
reconsider g0 = f as Function of X,R^1 by TOPMETR:17;
assume A3: f1 is continuous ; :: thesis: ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being Real st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous )
for p being Point of X
for V being Subset of R^1 st g0 . p in V & V is open holds
ex W being Subset of X st
( p in W & W is open & g0 .: W c= V )

proof

let p be Point of X; :: thesis: for V being Subset of R^1 st g0 . p in V & V is open holds
ex W being Subset of X st
( p in W & W is open & g0 .: W c= V )
let V be Subset of R^1; :: thesis: ( g0 . p in V & V is open implies ex W being Subset of X st
( p in W & W is open & g0 .: W c= V ) )
reconsider r = g0 . p as Real ;
reconsider r1 = f1 . p as Real ;
assume ( g0 . p in V & V is open ) ; :: thesis: ex W being Subset of X st
( p in W & W is open & g0 .: W c= V )
then consider r0 being Real such that
A4: r0 > 0 and
A5: ].(r - r0),(r + r0).[ c= V by FRECHET:8;
set r4 = r0;
reconsider G1 = ].(r1 - r0),(r1 + r0).[ as Subset of R^1 by TOPMETR:17;
A6: r1 < r1 + r0 by A4, XREAL_1:29;
then r1 - r0 < r1 by XREAL_1:19;
then A7: f1 . p in G1 by A6, XXREAL_1:4;
G1 is open by JORDAN6:35;
then consider W1 being Subset of X such that
A8: ( p in W1 & W1 is open ) and
A9: f1 .: W1 c= G1 by A3, A7, Th10;
set W = W1;
g0 .: W1 c= ].(r - r0),(r + r0).[

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in g0 .: W1 or x in ].(r - r0),(r + r0).[ )
assume x in g0 .: W1 ; :: thesis: x in ].(r - r0),(r + r0).[
then consider z being object such that
A10: z in dom g0 and
A11: z in W1 and
A12: g0 . z = x by FUNCT_1:def 6;
reconsider pz = z as Point of X by A10;
reconsider aa1 = f1 . pz as Real ;
pz in the carrier of X ;
then pz in dom f1 by FUNCT_2:def 1;
then A13: f1 . pz in f1 .: W1 by A11, FUNCT_1:def 6;
then r1 - r0 < aa1 by A9, XXREAL_1:4;
then A14: (r1 - r0) + a < aa1 + a by XREAL_1:8;
A15: (r1 - r0) + a = (r1 + a) - r0
.= r - r0 by A2 ;
aa1 < r1 + r0 by A9, A13, XXREAL_1:4;
then A16: (r1 + r0) + a > aa1 + a by XREAL_1:8;
x = aa1 + a by A2, A12;
hence x in ].(r - r0),(r + r0).[ by A16, A14, A15, XXREAL_1:4; :: thesis: verum

end;

hence ex W being Subset of X st
( p in W & W is open & g0 .: W c= V ) by A5, A8, XBOOLE_1:1; :: thesis: verum

end;

then A17: g0 is continuous by Th10;
for p being Point of X
for r1 being Real st f1 . p = r1 holds
g0 . p = r1 + a by A2;
hence ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being Real st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous ) by A17; :: thesis: verum