let Z be open Subset of REAL; :: thesis: ( (id Z) (#) cos is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) (#) cos) `| Z) . x = (cos . x) - (x * (sin . x)) ) )
A1: cos is_differentiable_on Z by FDIFF_1:26, SIN_COS:67;
A2: dom ((id Z) (#) cos) = (dom (id Z)) /\ REAL by SIN_COS:24, VALUED_1:def 4
.= dom (id Z) by XBOOLE_1:28
.= Z by RELAT_1:45 ;
then Z c= (dom (id Z)) /\ (dom cos) by VALUED_1:def 4;
then A3: Z c= dom (id Z) by XBOOLE_1:18;
for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:18;
then A4: id Z is_differentiable_on Z by A3, FDIFF_1:23;
A5: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:18;

now :: thesis: for x being Real st x in Z holds
(((id Z) (#) cos) `| Z) . x = (cos . x) - (x * (sin . x))

let x be Real; :: thesis: ( x in Z implies (((id Z) (#) cos) `| Z) . x = (cos . x) - (x * (sin . x)) )
assume A6: x in Z ; :: thesis: (((id Z) (#) cos) `| Z) . x = (cos . x) - (x * (sin . x))
hence (((id Z) (#) cos) `| Z) . x = ((cos . x) * (diff ((id Z),x))) + (((id Z) . x) * (diff (cos,x))) by A2, A4, A1, FDIFF_1:21
.= ((cos . x) * (((id Z) `| Z) . x)) + (((id Z) . x) * (diff (cos,x))) by A4, A6, FDIFF_1:def 7
.= ((cos . x) * 1) + (((id Z) . x) * (diff (cos,x))) by A3, A5, A6, FDIFF_1:23
.= ((cos . x) * 1) + (((id Z) . x) * (- (sin . x))) by SIN_COS:63
.= (cos . x) + (x * (- (sin . x))) by A6, FUNCT_1:18
.= (cos . x) - (x * (sin . x)) ;
:: thesis: verum

end;

hence ( (id Z) (#) cos is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) (#) cos) `| Z) . x = (cos . x) - (x * (sin . x)) ) ) by A2, A4, A1, FDIFF_1:21; :: thesis: verum