let Z be open Subset of REAL; :: thesis: ( Z c= dom cot implies ( cot is_differentiable_on Z & ( for x being Real st x in Z holds
(cot `| Z) . x = - (1 / ((sin . x) ^2)) ) ) )
assume A1: Z c= dom cot ; :: thesis: ( cot is_differentiable_on Z & ( for x being Real st x in Z holds
(cot `| Z) . x = - (1 / ((sin . x) ^2)) ) )
A2: for x being Real st x in Z holds
cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cot is_differentiable_in x )
assume x in Z ; :: thesis: cot is_differentiable_in x
then x in dom cot by A1;
then A3: sin . x <> 0 by FDIFF_8:2;
( sin is_differentiable_in x & cos is_differentiable_in x ) by SIN_COS:63, SIN_COS:64;
hence cot is_differentiable_in x by A3, FDIFF_2:14; :: thesis: verum

end;

then A4: cot is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
(cot `| Z) . x = - (1 / ((sin . x) ^2))

proof

let x be Real; :: thesis: ( x in Z implies (cot `| Z) . x = - (1 / ((sin . x) ^2)) )
A5: ( sin is_differentiable_in x & cos is_differentiable_in x ) by SIN_COS:63, SIN_COS:64;
assume A6: x in Z ; :: thesis: (cot `| Z) . x = - (1 / ((sin . x) ^2))
then x in dom cot by A1;
then sin . x <> 0 by FDIFF_8:2;
then diff (cot,x) = (((diff (cos,x)) * (sin . x)) - ((diff (sin,x)) * (cos . x))) / ((sin . x) ^2) by A5, FDIFF_2:14
.= (((- (sin . x)) * (sin . x)) - ((diff (sin,x)) * (cos . x))) / ((sin . x) ^2) by SIN_COS:63
.= ((- ((sin . x) * (sin . x))) - ((cos . x) * (cos . x))) / ((sin . x) ^2) by SIN_COS:64
.= (- (((sin . x) * (sin . x)) + ((cos . x) * (cos . x)))) / ((sin . x) ^2)
.= (- (((sin . x) * (sin . x)) + ((cos . x) ^2))) / ((sin . x) ^2)
.= (- (((sin . x) ^2) + ((cos . x) ^2))) / ((sin . x) ^2)
.= - ((((cos . x) ^2) + ((sin . x) ^2)) / ((sin . x) ^2)) by XCMPLX_1:187
.= - (1 / ((sin . x) ^2)) by SIN_COS:28 ;
hence (cot `| Z) . x = - (1 / ((sin . x) ^2)) by A4, A6, FDIFF_1:def 7; :: thesis: verum

end;

hence ( cot is_differentiable_on Z & ( for x being Real st x in Z holds
(cot `| Z) . x = - (1 / ((sin . x) ^2)) ) ) by A1, A2, FDIFF_1:9; :: thesis: verum