let r be Real; :: thesis: for X being non empty Subset of REAL st X is bounded_above & r <= 0 holds
lower_bound (r ** X) = r * (upper_bound X)
let X be non empty Subset of REAL; :: thesis: ( X is bounded_above & r <= 0 implies lower_bound (r ** X) = r * (upper_bound X) )
assume that
A1: X is bounded_above and
A2: r <= 0 ; :: thesis: lower_bound (r ** X) = r * (upper_bound X)
A3: for a being Real st a in r ** X holds
r * (upper_bound X) <= a

proof

let a be Real; :: thesis: ( a in r ** X implies r * (upper_bound X) <= a )
assume a in r ** X ; :: thesis: r * (upper_bound X) <= a
then a in { (r * x) where x is Real : x in X } by Th8;
then consider x being Real such that
A4: a = r * x and
A5: x in X ;
x <= upper_bound X by A1, A5, SEQ_4:def 1;
hence r * (upper_bound X) <= a by A2, A4, XREAL_1:65; :: thesis: verum

end;

for b being Real st ( for a being Real st a in r ** X holds
a >= b ) holds
r * (upper_bound X) >= b

proof

consider x being Element of REAL such that
A6: x in X by SUBSET_1:4;
let b be Real; :: thesis: ( ( for a being Real st a in r ** X holds
a >= b ) implies r * (upper_bound X) >= b )
assume A7: for a being Real st a in r ** X holds
a >= b ; :: thesis: r * (upper_bound X) >= b
reconsider x = x as Real ;
r * x in { (r * y) where y is Real : y in X } by A6;
then A8: r * x in r ** X by Th8;

now :: thesis: r * (upper_bound X) >= b

per cases ( r = 0 or r < 0 ) by A2;

suppose r = 0 ; :: thesis: r * (upper_bound X) >= b

hence r * (upper_bound X) >= b by A7, A8; :: thesis: verum

end;

suppose A9: r < 0 ; :: thesis: r * (upper_bound X) >= b

for z being Real st z in X holds
z <= b / r

proof

let z be Real; :: thesis: ( z in X implies z <= b / r )
assume z in X ; :: thesis: z <= b / r
then r * z in { (r * y) where y is Real : y in X } ;
then r * z in r ** X by Th8;
hence z <= b / r by A7, A9, XREAL_1:80; :: thesis: verum

end;

then upper_bound X <= b / r by SEQ_4:45;
then r * (upper_bound X) >= (b / r) * r by A9, XREAL_1:65;
hence r * (upper_bound X) >= b by A9, XCMPLX_1:87; :: thesis: verum

end;

end;

end;

hence r * (upper_bound X) >= b ; :: thesis: verum

end;

hence lower_bound (r ** X) = r * (upper_bound X) by A3, SEQ_4:44; :: thesis: verum