let A be non empty closed_interval Subset of REAL; :: thesis: for r being Real
for rho, rho1 being Function of A,REAL
for u being PartFunc of REAL,REAL st rho is bounded_variation & rho1 is bounded_variation & dom u = A & rho = r (#) rho1 & u is_RiemannStieltjes_integrable_with rho1 holds
( u is_RiemannStieltjes_integrable_with rho & integral (u,rho) = r * (integral (u,rho1)) )
let r be Real; :: thesis: for rho, rho1 being Function of A,REAL
for u being PartFunc of REAL,REAL st rho is bounded_variation & rho1 is bounded_variation & dom u = A & rho = r (#) rho1 & u is_RiemannStieltjes_integrable_with rho1 holds
( u is_RiemannStieltjes_integrable_with rho & integral (u,rho) = r * (integral (u,rho1)) )
let rho, rho1 be Function of A,REAL; :: thesis: for u being PartFunc of REAL,REAL st rho is bounded_variation & rho1 is bounded_variation & dom u = A & rho = r (#) rho1 & u is_RiemannStieltjes_integrable_with rho1 holds
( u is_RiemannStieltjes_integrable_with rho & integral (u,rho) = r * (integral (u,rho1)) )
let u be PartFunc of REAL,REAL; :: thesis: ( rho is bounded_variation & rho1 is bounded_variation & dom u = A & rho = r (#) rho1 & u is_RiemannStieltjes_integrable_with rho1 implies ( u is_RiemannStieltjes_integrable_with rho & integral (u,rho) = r * (integral (u,rho1)) ) )
assume A1: ( rho is bounded_variation & rho1 is bounded_variation & dom u = A & rho = r (#) rho1 & u is_RiemannStieltjes_integrable_with rho1 ) ; :: thesis: ( u is_RiemannStieltjes_integrable_with rho & integral (u,rho) = r * (integral (u,rho1)) )
A3: now :: thesis: for T being DivSequence of A
for S being middle_volume_Sequence of rho,u,T st delta T is convergent & lim (delta T) = 0 holds
( middle_sum S is convergent & lim (middle_sum S) = r * (integral (u,rho1)) )
let T be DivSequence of A; :: thesis: for S being middle_volume_Sequence of rho,u,T st delta T is convergent & lim (delta T) = 0 holds
( middle_sum S is convergent & lim (middle_sum S) = r * (integral (u,rho1)) )
let S be middle_volume_Sequence of rho,u,T; :: thesis: ( delta T is convergent & lim (delta T) = 0 implies ( middle_sum S is convergent & lim (middle_sum S) = r * (integral (u,rho1)) ) )
assume A4: ( delta T is convergent & lim (delta T) = 0 ) ; :: thesis: ( middle_sum S is convergent & lim (middle_sum S) = r * (integral (u,rho1)) )
defpred S1[ Element of NAT , set ] means ex p being FinSequence of REAL st
( p = $2 & len p = len (T . $1) & ( for i being Nat st i in dom (T . $1) holds
( p . i in dom (u | (divset ((T . $1),i))) & ex z being Real st
( z = (u | (divset ((T . $1),i))) . (p . i) & (S . $1) . i = z * (vol ((divset ((T . $1),i)),rho)) ) ) ) );
A5: for k being Element of NAT ex p being Element of REAL * st S1[k,p]
proof
let k be Element of NAT ; :: thesis: ex p being Element of REAL * st S1[k,p]
defpred S2[ Nat, set ] means ( $2 in dom (u | (divset ((T . k),$1))) & ex c being Real st
( c = (u | (divset ((T . k),$1))) . $2 & (S . k) . $1 = c * (vol ((divset ((T . k),$1)),rho)) ) );
A6: Seg (len (T . k)) = dom (T . k) by FINSEQ_1:def 3;
A7: for i being Nat st i in Seg (len (T . k)) holds
ex x being Element of REAL st S2[i,x]
proof
let i be Nat; :: thesis: ( i in Seg (len (T . k)) implies ex x being Element of REAL st S2[i,x] )
assume i in Seg (len (T . k)) ; :: thesis: ex x being Element of REAL st S2[i,x]
then i in dom (T . k) by FINSEQ_1:def 3;
then consider c being Real such that
A8: ( c in rng (u | (divset ((T . k),i))) & (S . k) . i = c * (vol ((divset ((T . k),i)),rho)) ) by Def1, A1;
consider x being object such that
A9: ( x in dom (u | (divset ((T . k),i))) & c = (u | (divset ((T . k),i))) . x ) by A8, FUNCT_1:def 3;
reconsider x = x as Element of REAL by A9;
take x ; :: thesis: S2[i,x]
thus S2[i,x] by A8, A9; :: thesis: verum
end;
consider p being FinSequence of REAL such that
A10: ( dom p = Seg (len (T . k)) & ( for i being Nat st i in Seg (len (T . k)) holds
S2[i,p . i] ) ) from FINSEQ_1:sch 5(A7);
 take p ; :: thesis: ( p is Element of REAL * & S1[k,p] )
len p = len (T . k) by A10, FINSEQ_1:def 3;
hence ( p is Element of REAL * & S1[k,p] ) by A10, A6, FINSEQ_1:def 11; :: thesis: verum
end;
consider F being sequence of (REAL *) such that
A11: for x being Element of NAT holds S1[x,F . x] from FUNCT_2:sch 3(A5);
defpred S2[ Element of NAT , set ] means ex q being middle_volume of rho1,u,T . $1 st
( q = $2 & ( for i being Nat st i in dom (T . $1) holds
ex z being Real st
( (F . $1) . i in dom (u | (divset ((T . $1),i))) & z = (u | (divset ((T . $1),i))) . ((F . $1) . i) & q . i = z * (vol ((divset ((T . $1),i)),rho1)) ) ) );
A12: for k being Element of NAT ex y being Element of REAL * st S2[k,y]
proof
let k be Element of NAT ; :: thesis: ex y being Element of REAL * st S2[k,y]
defpred S3[ Nat, set ] means ex c being Real st
( (F . k) . $1 in dom (u | (divset ((T . k),$1))) & c = (u | (divset ((T . k),$1))) . ((F . k) . $1) & $2 = c * (vol ((divset ((T . k),$1)),rho1)) );
A13: Seg (len (T . k)) = dom (T . k) by FINSEQ_1:def 3;
A14: for i being Nat st i in Seg (len (T . k)) holds
ex x being Element of REAL st S3[i,x]
proof
let i be Nat; :: thesis: ( i in Seg (len (T . k)) implies ex x being Element of REAL st S3[i,x] )
assume i in Seg (len (T . k)) ; :: thesis: ex x being Element of REAL st S3[i,x]
then A15: i in dom (T . k) by FINSEQ_1:def 3;
consider p being FinSequence of REAL such that
A16: ( p = F . k & len p = len (T . k) & ( for i being Nat st i in dom (T . k) holds
( p . i in dom (u | (divset ((T . k),i))) & ex z being Real st
( z = (u | (divset ((T . k),i))) . (p . i) & (S . k) . i = z * (vol ((divset ((T . k),i)),rho)) ) ) ) ) by A11;
p . i in dom (u | (divset ((T . k),i))) by A15, A16;
then (u | (divset ((T . k),i))) . (p . i) in rng (u | (divset ((T . k),i))) by FUNCT_1:3;
then reconsider x = (u | (divset ((T . k),i))) . (p . i) as Element of REAL ;
x * (vol ((divset ((T . k),i)),rho1)) is Element of REAL by XREAL_0:def 1;
hence ex x being Element of REAL st S3[i,x] by A16, A15; :: thesis: verum
end;
consider q being FinSequence of REAL such that
A19: ( dom q = Seg (len (T . k)) & ( for i being Nat st i in Seg (len (T . k)) holds
S3[i,q . i] ) ) from FINSEQ_1:sch 5(A14);
 A20: len q = len (T . k) by A19, FINSEQ_1:def 3;
now :: thesis: for i being Nat st i in dom (T . k) holds
ex c being Real st
( c in rng (u | (divset ((T . k),i))) & q . i = c * (vol ((divset ((T . k),i)),rho1)) )
let i be Nat; :: thesis: ( i in dom (T . k) implies ex c being Real st
( c in rng (u | (divset ((T . k),i))) & q . i = c * (vol ((divset ((T . k),i)),rho1)) ) )
assume i in dom (T . k) ; :: thesis: ex c being Real st
( c in rng (u | (divset ((T . k),i))) & q . i = c * (vol ((divset ((T . k),i)),rho1)) )
then i in Seg (len (T . k)) by FINSEQ_1:def 3;
then consider c being Real such that
A21: ( (F . k) . i in dom (u | (divset ((T . k),i))) & c = (u | (divset ((T . k),i))) . ((F . k) . i) & q . i = c * (vol ((divset ((T . k),i)),rho1)) ) by A19;
thus ex c being Real st
( c in rng (u | (divset ((T . k),i))) & q . i = c * (vol ((divset ((T . k),i)),rho1)) ) by A21, FUNCT_1:3; :: thesis: verum
end;
then reconsider q = q as middle_volume of rho1,u,T . k by A20, Def1, A1;
q is Element of REAL * by FINSEQ_1:def 11;
hence ex y being Element of REAL * st S2[k,y] by A13, A19; :: thesis: verum
end;
consider Sf being sequence of (REAL *) such that
A22: for x being Element of NAT holds S2[x,Sf . x] from FUNCT_2:sch 3(A12);
now :: thesis: for k being Element of NAT holds Sf . k is middle_volume of rho1,u,T . k
let k be Element of NAT ; :: thesis: Sf . k is middle_volume of rho1,u,T . k
ex q being middle_volume of rho1,u,T . k st
( q = Sf . k & ( for i being Nat st i in dom (T . k) holds
ex z being Real st
( (F . k) . i in dom (u | (divset ((T . k),i))) & z = (u | (divset ((T . k),i))) . ((F . k) . i) & q . i = z * (vol ((divset ((T . k),i)),rho1)) ) ) ) by A22;
hence Sf . k is middle_volume of rho1,u,T . k ; :: thesis: verum
end;
then reconsider Sf = Sf as middle_volume_Sequence of rho1,u,T by Def3;
A23: ( middle_sum Sf is convergent & lim (middle_sum Sf) = integral (u,rho1) ) by A1, A4, Def6;
A24: r (#) (middle_sum Sf) = middle_sum S
proof
now :: thesis: for n being Nat holds r * ((middle_sum Sf) . n) = (middle_sum S) . n
let n be Nat; :: thesis: r * ((middle_sum Sf) . n) = (middle_sum S) . n
A25: n in NAT by ORDINAL1:def 12;
consider p being FinSequence of REAL such that
A26: ( p = F . n & len p = len (T . n) & ( for i being Nat st i in dom (T . n) holds
( p . i in dom (u | (divset ((T . n),i))) & ex z being Real st
( z = (u | (divset ((T . n),i))) . (p . i) & (S . n) . i = z * (vol ((divset ((T . n),i)),rho)) ) ) ) ) by A11, A25;
consider q being middle_volume of rho1,u,T . n such that
A27: ( q = Sf . n & ( for i being Nat st i in dom (T . n) holds
ex z being Real st
( (F . n) . i in dom (u | (divset ((T . n),i))) & z = (u | (divset ((T . n),i))) . ((F . n) . i) & q . i = z * (vol ((divset ((T . n),i)),rho1)) ) ) ) by A22, A25;
B28: ( len (Sf . n) = len (T . n) & len (S . n) = len (T . n) ) by A1, Def1;
then A28: ( dom (Sf . n) = dom (T . n) & dom (S . n) = dom (T . n) ) by FINSEQ_3:29;
now :: thesis: for x being object st x in dom (S . n) holds
(S . n) . x = r * ((Sf . n) . x)
let x be object ; :: thesis: ( x in dom (S . n) implies (S . n) . x = r * ((Sf . n) . x) )
assume A29: x in dom (S . n) ; :: thesis: (S . n) . x = r * ((Sf . n) . x)
then reconsider i = x as Nat ;
consider t being Real such that
A30: ( t = (u | (divset ((T . n),i))) . ((F . n) . i) & (S . n) . i = t * (vol ((divset ((T . n),i)),rho)) ) by A29, A28, A26;
consider z being Real such that
A31: ( (F . n) . i in dom (u | (divset ((T . n),i))) & z = (u | (divset ((T . n),i))) . ((F . n) . i) & q . i = z * (vol ((divset ((T . n),i)),rho1)) ) by A27, A29, A28;
i in dom (T . n) by A29, FINSEQ_3:29, B28;
then vol ((divset ((T . n),i)),rho) = r * (vol ((divset ((T . n),i)),rho1)) by A1, Lm4A, INTEGRA1:8;
hence (S . n) . x = r * ((Sf . n) . x) by A31, A27, A30; :: thesis: verum
end;
then A38: r (#) (Sf . n) = S . n by A28, VALUED_1:def 5;
thus r * ((middle_sum Sf) . n) = r * (Sum (Sf . n)) by Def4
.= Sum (S . n) by A38, RVSUM_1:87
.= (middle_sum S) . n by Def4 ; :: thesis: verum
end;
hence r (#) (middle_sum Sf) = middle_sum S by SEQ_1:9; :: thesis: verum
end;
thus middle_sum S is convergent by A23, A24; :: thesis: lim (middle_sum S) = r * (integral (u,rho1))
thus lim (middle_sum S) = r * (integral (u,rho1)) by A24, A23, SEQ_2:8; :: thesis: verum
end;
hence u is_RiemannStieltjes_integrable_with rho ; :: thesis: integral (u,rho) = r * (integral (u,rho1))
hence integral (u,rho) = r * (integral (u,rho1)) by Def6, A3, A1; :: thesis: verum